bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use v5.12;
   4
   5 use strict;
   6 use warnings;
   7
   8 use IO::File;
   9 use Math::Trig qw(deg2rad pip2 great_circle_distance);
  10 use JSON::XS;
  11 use LWP::UserAgent;
  12 use YAML;
  13
  14 my $originfile = shift @ARGV;
  15 my $clusterfile = shift @ARGV;
  16 my $zone = shift @ARGV;
  17 my $jszone = shift @ARGV;
  18 my $targetoriginfile = shift @ARGV;
  19 my $origins = YAML::LoadFile($originfile);
  20 my $clusters = YAML::LoadFile($clusterfile);
  21 my $gdnsname = shift @ARGV;
  22 my @servers;
  23
  24 # Initialise cluster details
  25 while (my($name,$cluster) = each %$clusters)
  26 {
  27     if ($cluster->{servers})
  28     {
  29         $cluster->{bandwidth} = 0;
  30
  31         foreach my $server (@{$cluster->{servers}})
  32         {
  33             $server->{cluster} = $cluster;
  34             $cluster->{bandwidth} = $cluster->{bandwidth} + $server->{bandwidth};
  35
  36             push @servers, $server;
  37         }
  38     }
  39     else
  40     {
  41         my $server = {
  42             cluster => $cluster,
  43             statuscake => $cluster->{statuscake},
  44             bandwidth => $cluster->{bandwidth},
  45             ipv4 => $cluster->{ipv4},
  46             ipv6 => $cluster->{ipv6}
  47         };
  48
  49         $cluster->{servers} = [ $server ];
  50
  51         push @servers, $server;
  52     }
  53
  54     $cluster->{name} = $name;
  55     $cluster->{status} = "down";
  56 }
  57
  58 # Initialise server details
  59 foreach my $server (@servers)
  60 {
  61     $server->{status} = "up";
  62 }
  63
  64 # If statuscake support is enabled then check which servers are up
  65 if ($ENV{STATUSCAKE_USERNAME} && $ENV{STATUSCAKE_APIKEY})
  66 {
  67     my $ua = LWP::UserAgent->new;
  68     my $cache;
  69
  70     $ua->agent("mkgeo/1.0");
  71     $ua->default_header("Username", $ENV{STATUSCAKE_USERNAME});
  72     $ua->default_header("API", $ENV{STATUSCAKE_APIKEY});
  73
  74     if (-f "statuscake.yml")
  75     {
  76         $cache = YAML::LoadFile("statuscake.yml");
  77     }
  78     else
  79     {
  80         $cache = {};
  81     }
  82
  83     my $response = $ua->get("https://app.statuscake.com/API/Tests/");
  84
  85     if ($response->is_success)
  86     {
  87         my $tests = decode_json($response->content);
  88
  89         foreach my $test (@$tests)
  90         {
  91             my $testid = $test->{TestID};
  92
  93             if ($test->{Status} eq "Up" && !$test->{Paused})
  94             {
  95                 $cache->{$testid} = "up";
  96             }
  97             else
  98             {
  99                 $cache->{$testid} = "down";
 100             }
 101         }
 102     }
 103
 104     foreach my $server (@servers)
 105     {
 106         if (my $testids = $server->{statuscake})
 107         {
 108             $server->{status} = "up";
 109
 110             for my $testid (@$testids)
 111             {
 112                 my $testresult = $cache->{$testid} || "down";
 113
 114                 $server->{status} = "down" if $testresult eq "down";
 115             }
 116         }
 117         else
 118         {
 119             $server->{status} = "down";
 120         }
 121     }
 122
 123     YAML::DumpFile("statuscake.yml", $cache);
 124 }
 125
 126 # Mark a cluster as up if any servers are up
 127 foreach my $server (@servers)
 128 {
 129     if ($server->{status} eq "up")
 130     {
 131         $server->{cluster}->{status} = "up";
 132     }
 133     else
 134     {
 135         $server->{cluster}->{bandwidth} = $server->{cluster}->{bandwidth} - $server->{bandwidth};
 136     }
 137 }
 138
 139 # Create target origins object
 140 my $targetorigins = {};
 141
 142 # Initialise cluster details
 143 while (my($name,$cluster) = each %$clusters)
 144 {
 145     $cluster->{bandwidth_limit} = $cluster->{bandwidth} * 1024 * 1024;
 146     $cluster->{bandwidth_used} = 0;
 147
 148     $targetorigins->{$cluster->{name}} = {
 149         code => $cluster->{name},
 150         name => $cluster->{name},
 151         lat => $cluster->{lat},
 152         lon => $cluster->{lon},
 153         bandwidth => 0
 154     };
 155 }
 156
 157 my @mappings = ();
 158
 159 # Scan origins and work out which clusters each can use
 160 foreach my $origin (values %$origins)
 161 {
 162     foreach my $cluster (values %$clusters)
 163     {
 164         my $match = match_origin($cluster, $origin);
 165
 166         if ($cluster->{status} eq "up" && $match ne "denied")
 167         {
 168             my $priority = $match eq "preferred" ? 20 : 10;
 169             my $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 170
 171             push @mappings, {
 172                 origin => $origin, cluster => $cluster,
 173                 priority => $priority, distance => $distance
 174             };
 175         }
 176     }
 177 }
 178
 179 # Allocate each country to a cluster
 180 allocate_clusters(@mappings);
 181
 182 # If we failed to allocate every origin then loop, increasing
 183 # the bandwidth for each cluster by a little and retrying until
 184 # we manage to allocate everything
 185 while (grep { !exists($_->{cluster}) } values %$origins)
 186 {
 187     # Clear any existing mappings of countries to clusters
 188     foreach my $origin (values %$origins)
 189     {
 190         delete $origin->{cluster};
 191     }
 192
 193     # Reset bandwidth usage for clusters and increase limits by 10%
 194     foreach my $cluster (values %$clusters)
 195     {
 196         $cluster->{bandwidth_used} = 0;
 197         $cluster->{bandwidth_limit} = $cluster->{bandwidth_limit} * 1.1;
 198     }
 199
 200     # Try the allocate again
 201     allocate_clusters(@mappings);
 202 }
 203
 204 # Create JSON collection object
 205 my @json;
 206
 207 # Open output files
 208 my $zonefile = IO::File->new("> data/${zone}") || die "$!";
 209 my $jszonefile = IO::File->new("> include/${jszone}.js") || die "$!";
 210 my $jsonfile = IO::File->new("> json/${zone}.json") || die "$!";
 211
 212 # Output headers
 213 $jszonefile->print("var \U${jszone}\E_RECORDS = [\n");
 214
 215 # Skip outputting server map if gdnsd is doing that
 216 if (!defined($gdnsname))
 217 {
 218     # Output details for each country
 219     foreach my $origin (sort { $a->{name} cmp $b->{name} } values %$origins)
 220     {
 221         my $cluster = $origin->{cluster};
 222         my $clon = $origin->{lon};
 223         my $clat = $origin->{lat};
 224         my $slon = $cluster->{lon};
 225         my $slat = $cluster->{lat};
 226
 227         if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 228         {
 229             $slon = $slon + 360;
 230         }
 231         elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 232         {
 233             $clon = $clon + 360;
 234         }
 235
 236         $zonefile->print("# $origin->{name}\n");
 237         $zonefile->print("C\L$origin->{code}\E.${zone}:$cluster->{name}.${zone}:600\n");
 238
 239         $jszonefile->print("  CNAME(\"\L$origin->{code}\E.${jszone}\", \"$cluster->{name}.${zone}.\", TTL(\"10m\")),\n");
 240
 241         push @json, {
 242             type => "Feature",
 243             geometry => {
 244                 type => "LineString",
 245                 coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 246             },
 247             properties => {
 248                 origin => $origin->{name},
 249                 server => $cluster->{name},
 250                 colour => $cluster->{colour}
 251             }
 252         };
 253
 254         $targetorigins->{$cluster->{name}}->{bandwidth} += $origin->{bandwidth};
 255     }
 256
 257     # Header for default records
 258     $zonefile->print("# Unknown origins\n");
 259
 260     # Output default records for IPs that can't be mapped to a country
 261     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 262     {
 263         my $name = $cluster->{name};
 264
 265         if (my $default = $cluster->{default})
 266         {
 267             output_server($zonefile, $jszonefile, "${default}.${zone}", "${default}.${jszone}", $cluster);
 268         }
 269         elsif (exists($cluster->{default}))
 270         {
 271             output_server($zonefile, $jszonefile, "${zone}", "${jszone}", $cluster);
 272         }
 273     }
 274 }
 275
 276 # Header for underlying servers
 277 $zonefile->print("# Servers\n");
 278
 279 # Output A records for each cluster
 280 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 281 {
 282     my $name = $cluster->{name};
 283
 284     output_server($zonefile, $jszonefile, "${name}.${zone}", "${name}.${jszone}", $cluster);
 285
 286     if (@{$cluster->{servers}} > 1)
 287     {
 288         output_server($zonefile, $jszonefile, "${name}-%02d.${zone}", "${name}-%02d.${jszone}", $cluster);
 289     }
 290 }
 291
 292 # Output the GeoJSON text
 293 $jsonfile->print(encode_json(\@json));
 294
 295 # Output footers
 296 $jszonefile->print("];\n");
 297
 298 # Close the output files
 299 $jsonfile->close();
 300 $jszonefile->close();
 301 $zonefile->close();
 302
 303 # Output gdnsd configuration
 304 if (defined($gdnsname))
 305 {
 306     my $gdnsmapfile = IO::File->new("> gdns/${gdnsname}.map") || die "$!";
 307     my $gdnsresourcefile = IO::File->new("> gdns/${gdnsname}.resource") || die "$!";
 308     my $gdnsweightedfile = IO::File->new("> gdns/${gdnsname}.weighted") || die "$!";
 309     my $continent = "";
 310
 311     $gdnsmapfile->print("${gdnsname} => {\n");
 312     $gdnsmapfile->print("  geoip2_db => /usr/share/GeoIP/GeoLite2-Country.mmdb\n");
 313     $gdnsmapfile->print("  datacenters => [" . join(",", sort(keys(%$clusters))) . "]\n");
 314     $gdnsmapfile->print("  map => {\n");
 315     $gdnsmapfile->print("    default => [" . join(",", sort(map { $_->{name} } grep { $_->{default} } values(%$clusters))) . "]\n");
 316
 317     foreach my $origin (sort { $a->{continent} cmp $b->{continent} || $a->{code} cmp $b->{code} } values %$origins)
 318     {
 319         my $code = $origin->{code};
 320         my $cluster = $origin->{cluster}->{name};
 321
 322         next if $code eq "XK";
 323
 324         if ($continent ne $origin->{continent})
 325         {
 326             $gdnsmapfile->print("    }\n") if $continent;
 327
 328             $continent = $origin->{continent};
 329
 330             $gdnsmapfile->print("    ${continent} => {\n");
 331         }
 332
 333         $gdnsmapfile->print("      ${code} => [${cluster}]\n");
 334     }
 335
 336     $gdnsmapfile->print("    }\n") if $continent;
 337
 338     $gdnsmapfile->print("  }\n");
 339     $gdnsmapfile->print("}\n");
 340
 341     $gdnsresourcefile->print("${gdnsname} => {\n");
 342     $gdnsresourcefile->print("  map => ${gdnsname}\n");
 343     $gdnsresourcefile->print("  dcmap => {\n");
 344
 345     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 346     {
 347         my $name = $cluster->{name};
 348
 349         if (@{$cluster->{servers}} > 1)
 350         {
 351             $gdnsweightedfile->print("${name} => {\n");
 352
 353             while (my($index,$server) = each @{$cluster->{servers}})
 354             {
 355                 if ($server->{status} eq "up")
 356                 {
 357                     my $number = sprintf("%02d", $index + 1);
 358                     my $bandwidth = $server->{bandwidth};
 359
 360                     $gdnsweightedfile->print("  ${name}-${number} = [ ${name}-${number}.${zone}., ${bandwidth} ]\n");
 361                 }
 362             }
 363
 364             $gdnsweightedfile->print("}\n");
 365
 366             $gdnsresourcefile->print("    ${name} => %weighted!${name}\n");
 367         }
 368         else
 369         {
 370             $gdnsresourcefile->print("    ${name} => ${name}.${zone}.\n");
 371         }
 372     }
 373
 374     $gdnsresourcefile->print("  }\n");
 375     $gdnsresourcefile->print("}\n");
 376
 377     $gdnsweightedfile->close();
 378     $gdnsresourcefile->close();
 379     $gdnsmapfile->close();
 380 }
 381
 382 # Output the target details in origin format if required
 383 YAML::DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 384
 385 exit 0;
 386
 387 #
 388 # Match an origin against a cluster
 389 #
 390 sub match_origin
 391 {
 392     my $cluster = shift;
 393     my $origin = shift;
 394     my $match;
 395
 396     if ($cluster->{preferred} &&
 397         $cluster->{preferred}->{origins} &&
 398         grep { $_ eq $origin->{name} } @{$cluster->{preferred}->{origins}})
 399     {
 400         $match = "preferred";
 401     }
 402     elsif ($cluster->{allowed} &&
 403            $cluster->{allowed}->{origins} &&
 404            grep { $_ eq $origin->{name} } @{$cluster->{allowed}->{origins}})
 405     {
 406         $match = "allowed";
 407     }
 408     elsif ($cluster->{preferred} &&
 409            $cluster->{preferred}->{countries} &&
 410            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 411     {
 412         $match = "preferred";
 413     }
 414     elsif ($cluster->{allowed} &&
 415            $cluster->{allowed}->{countries} &&
 416            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 417     {
 418         $match = "allowed";
 419     }
 420     elsif ($cluster->{denied} &&
 421            $cluster->{denied}->{countries} &&
 422            grep { $_ eq $origin->{country} } @{$cluster->{denied}->{countries}})
 423     {
 424         $match = "denied";
 425     }
 426     elsif ($cluster->{preferred} &&
 427            $cluster->{preferred}->{continents} &&
 428            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 429     {
 430         $match = "preferred";
 431     }
 432     elsif ($cluster->{allowed} &&
 433            $cluster->{allowed}->{continents} &&
 434            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 435     {
 436         $match = "allowed";
 437     }
 438     elsif ($cluster->{denied} &&
 439            $cluster->{denied}->{continents} &&
 440            grep { $_ eq $origin->{continent} } @{$cluster->{denied}->{continents}})
 441     {
 442         $match = "denied";
 443     }
 444     elsif ($cluster->{allowed})
 445     {
 446         $match = "denied";
 447     }
 448     else
 449     {
 450         $match = "allowed";
 451     }
 452
 453     return $match;
 454 }
 455
 456 #
 457 # Compute the great circle distance between two points
 458 #
 459 sub distance
 460 {
 461     my $lat1 = deg2rad(shift);
 462     my $lon1 = deg2rad(shift);
 463     my $lat2 = deg2rad(shift);
 464     my $lon2 = deg2rad(shift);
 465
 466     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 467 }
 468
 469 #
 470 # Allocate each origin to a cluster
 471 #
 472 sub allocate_clusters
 473 {
 474     my @mappings = sort { compare_mappings($a, $b) } @_;
 475
 476     # Loop over the mappings, trying to assign each origin to the
 477     # nearest cluster, but subject to the bandwidth limits
 478     while (my $mapping = shift @mappings)
 479     {
 480         my @group;
 481
 482         push @group, $mapping;
 483
 484         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 485         {
 486             push @group, shift @mappings;
 487         }
 488
 489         for my $mapping (sort compare_bandwidth @group)
 490         {
 491             my $origin = $mapping->{origin};
 492             my $cluster = $mapping->{cluster};
 493
 494             if (!exists($origin->{cluster}) &&
 495                 $cluster->{bandwidth_used} + $origin->{bandwidth} <= $cluster->{bandwidth_limit})
 496             {
 497                 $origin->{cluster} = $cluster;
 498                 $cluster->{bandwidth_used} = $cluster->{bandwidth_used} + $origin->{bandwidth};
 499             }
 500         }
 501     }
 502
 503     return;
 504 }
 505
 506 #
 507 # Compare two mappings to decide which to use
 508 #
 509 sub compare_mappings
 510 {
 511     my $a = shift;
 512     my $b = shift;
 513
 514     return $b->{priority} <=> $a->{priority} ||
 515            $a->{distance} <=> $b->{distance};
 516 }
 517
 518 #
 519 # Compare two mappings to decide which to try first
 520 #
 521 sub compare_bandwidth
 522 {
 523     my $a_used = ( $a->{cluster}->{bandwidth_used} * 100.0 ) / ( $a->{cluster}->{bandwidth_limit} * 1.0 );
 524     my $b_used = ( $b->{cluster}->{bandwidth_used} * 100.0 ) / ( $b->{cluster}->{bandwidth_limit} * 1.0 );
 525
 526     return $a_used <=> $b_used;
 527 }
 528
 529 #
 530 # Output DNS records for a server
 531 #
 532 sub output_server
 533 {
 534     my $zonefile = shift;
 535     my $jszonefile = shift;
 536     my $name = shift;
 537     my $jsname = shift;
 538     my $cluster = shift;
 539
 540     while (my($index,$server) = each @{$cluster->{servers}})
 541     {
 542         if ($server->{status} eq "up")
 543         {
 544             $zonefile->printf("+${name}:$server->{ipv4}:600\n", $index + 1);
 545             $jszonefile->printf("  A(\"${jsname}\", \"$server->{ipv4}\", TTL(\"10m\")),\n", $index + 1);
 546
 547             if ($server->{ipv6})
 548             {
 549                 my $ipv6 = $server->{ipv6};
 550
 551                 $ipv6 =~ s/([0-9a-f]{4})(?=.)/$1:/ig;
 552
 553                 $zonefile->printf("3${name}:$server->{ipv6}:600\n", $index + 1);
 554                 $jszonefile->printf("  AAAA(\"${jsname}\", \"${ipv6}\", TTL(\"10m\")),\n", $index + 1);
 555             }
 556         }
 557     }
 558
 559     return;
 560 }