sql/functions/placex_triggers.sql

   1 -- Trigger functions for the placex table.
   2
   3 CREATE OR REPLACE FUNCTION get_rel_node_members(members TEXT[], memberLabels TEXT[])
   4   RETURNS SETOF BIGINT
   5   AS $$
   6 DECLARE
   7   i INTEGER;
   8 BEGIN
   9   FOR i IN 1..ARRAY_UPPER(members,1) BY 2 LOOP
  10     IF members[i+1] = ANY(memberLabels)
  11        AND upper(substring(members[i], 1, 1))::char(1) = 'N'
  12     THEN
  13       RETURN NEXT substring(members[i], 2)::bigint;
  14     END IF;
  15   END LOOP;
  16
  17   RETURN;
  18 END;
  19 $$
  20 LANGUAGE plpgsql IMMUTABLE;
  21
  22
  23 -- Try to find a linked place for the given object.
  24 CREATE OR REPLACE FUNCTION find_linked_place(bnd placex)
  25   RETURNS placex
  26   AS $$
  27 DECLARE
  28   relation_members TEXT[];
  29   rel_member RECORD;
  30   linked_placex placex%ROWTYPE;
  31   bnd_name TEXT;
  32 BEGIN
  33   IF bnd.rank_search >= 26 or bnd.rank_address = 0
  34      or ST_GeometryType(bnd.geometry) NOT IN ('ST_Polygon','ST_MultiPolygon')
  35   THEN
  36     RETURN NULL;
  37   END IF;
  38
  39   IF bnd.osm_type = 'R' THEN
  40     -- see if we have any special relation members
  41     SELECT members FROM planet_osm_rels WHERE id = bnd.osm_id INTO relation_members;
  42     --DEBUG: RAISE WARNING 'Got relation members';
  43
  44     -- Search for relation members with role 'lable'.
  45     IF relation_members IS NOT NULL THEN
  46       FOR rel_member IN
  47         SELECT get_rel_node_members(relation_members, ARRAY['label']) as member
  48       LOOP
  49         --DEBUG: RAISE WARNING 'Found label member %', rel_member.member;
  50
  51         FOR linked_placex IN
  52           SELECT * from placex
  53           WHERE osm_type = 'N' and osm_id = rel_member.member
  54             and class = 'place'
  55         LOOP
  56           --DEBUG: RAISE WARNING 'Linked label member';
  57           RETURN linked_placex;
  58         END LOOP;
  59
  60       END LOOP;
  61     END IF;
  62   END IF;
  63
  64   IF bnd.name ? 'name' THEN
  65     bnd_name := make_standard_name(bnd.name->'name');
  66     IF bnd_name = '' THEN
  67       bnd_name := NULL;
  68     END IF;
  69   END IF;
  70
  71   -- Search for relation members with role admin_center.
  72   IF bnd.osm_type = 'R' and bnd_name is not null
  73      and relation_members is not null THEN
  74     FOR rel_member IN
  75       SELECT get_rel_node_members(relation_members,
  76                                 ARRAY['admin_center','admin_centre']) as member
  77     LOOP
  78     --DEBUG: RAISE WARNING 'Found admin_center member %', rel_member.member;
  79       FOR linked_placex IN
  80         SELECT * from placex
  81         WHERE osm_type = 'N' and osm_id = rel_member.member
  82           and class = 'place'
  83       LOOP
  84         -- For an admin centre we also want a name match - still not perfect,
  85         -- for example 'new york, new york'
  86         -- But that can be fixed by explicitly setting the label in the data
  87         IF bnd_name = make_standard_name(linked_placex.name->'name')
  88            AND bnd.rank_address = linked_placex.rank_address
  89         THEN
  90           RETURN linked_placex;
  91         END IF;
  92           --DEBUG: RAISE WARNING 'Linked admin_center';
  93       END LOOP;
  94     END LOOP;
  95   END IF;
  96
  97   -- Name searches can be done for ways as well as relations
  98   IF bnd.osm_type in ('W','R') and bnd_name is not null THEN
  99     --DEBUG: RAISE WARNING 'Looking for nodes with matching names';
 100     FOR linked_placex IN
 101       SELECT placex.* from placex
 102       WHERE make_standard_name(name->'name') = bnd_name
 103         AND placex.rank_address = bnd.rank_address
 104         AND placex.osm_type = 'N'
 105         AND st_covers(geometry, placex.geometry)
 106     LOOP
 107       --DEBUG: RAISE WARNING 'Found matching place node %', linkedPlacex.osm_id;
 108       RETURN linked_placex;
 109     END LOOP;
 110   END IF;
 111
 112   RETURN NULL;
 113 END;
 114 $$
 115 LANGUAGE plpgsql;
 116
 117 CREATE OR REPLACE FUNCTION placex_insert()
 118   RETURNS TRIGGER
 119   AS $$
 120 DECLARE
 121   i INTEGER;
 122   postcode TEXT;
 123   result BOOLEAN;
 124   is_area BOOLEAN;
 125   country_code VARCHAR(2);
 126   default_language VARCHAR(10);
 127   diameter FLOAT;
 128   classtable TEXT;
 129   classtype TEXT;
 130 BEGIN
 131   --DEBUG: RAISE WARNING '% % % %',NEW.osm_type,NEW.osm_id,NEW.class,NEW.type;
 132
 133   NEW.place_id := nextval('seq_place');
 134   NEW.indexed_status := 1; --STATUS_NEW
 135
 136   NEW.country_code := lower(get_country_code(NEW.geometry));
 137
 138   NEW.partition := get_partition(NEW.country_code);
 139   NEW.geometry_sector := geometry_sector(NEW.partition, NEW.geometry);
 140
 141   -- copy 'name' to or from the default language (if there is a default language)
 142   IF NEW.name is not null AND array_upper(akeys(NEW.name),1) > 1 THEN
 143     default_language := get_country_language_code(NEW.country_code);
 144     IF default_language IS NOT NULL THEN
 145       IF NEW.name ? 'name' AND NOT NEW.name ? ('name:'||default_language) THEN
 146         NEW.name := NEW.name || hstore(('name:'||default_language), (NEW.name -> 'name'));
 147       ELSEIF NEW.name ? ('name:'||default_language) AND NOT NEW.name ? 'name' THEN
 148         NEW.name := NEW.name || hstore('name', (NEW.name -> ('name:'||default_language)));
 149       END IF;
 150     END IF;
 151   END IF;
 152
 153   IF NEW.osm_type = 'X' THEN
 154     -- E'X'ternal records should already be in the right format so do nothing
 155   ELSE
 156     is_area := ST_GeometryType(NEW.geometry) IN ('ST_Polygon','ST_MultiPolygon');
 157
 158     IF NEW.class in ('place','boundary')
 159        AND NEW.type in ('postcode','postal_code') THEN
 160
 161       IF NEW.address IS NULL OR NOT NEW.address ? 'postcode' THEN
 162           -- most likely just a part of a multipolygon postcode boundary, throw it away
 163           RETURN NULL;
 164       END IF;
 165
 166       NEW.name := hstore('ref', NEW.address->'postcode');
 167
 168       SELECT * FROM get_postcode_rank(NEW.country_code, NEW.address->'postcode')
 169         INTO NEW.rank_search, NEW.rank_address;
 170
 171       IF NOT is_area THEN
 172           NEW.rank_address := 0;
 173       END IF;
 174     ELSEIF NEW.class = 'boundary' AND NOT is_area THEN
 175         return NULL;
 176     ELSEIF NEW.class = 'boundary' AND NEW.type = 'administrative'
 177            AND NEW.admin_level <= 4 AND NEW.osm_type = 'W' THEN
 178         return NULL;
 179     ELSEIF NEW.osm_type = 'N' AND NEW.class = 'highway' THEN
 180         NEW.rank_search = 30;
 181         NEW.rank_address = 0;
 182     ELSEIF NEW.class = 'landuse' AND NOT is_area THEN
 183         NEW.rank_search = 30;
 184         NEW.rank_address = 0;
 185     ELSE
 186       -- do table lookup stuff
 187       IF NEW.class = 'boundary' and NEW.type = 'administrative' THEN
 188         classtype = NEW.type || NEW.admin_level::TEXT;
 189       ELSE
 190         classtype = NEW.type;
 191       END IF;
 192       SELECT l.rank_search, l.rank_address FROM address_levels l
 193        WHERE (l.country_code = NEW.country_code or l.country_code is NULL)
 194              AND l.class = NEW.class AND (l.type = classtype or l.type is NULL)
 195        ORDER BY l.country_code, l.class, l.type LIMIT 1
 196         INTO NEW.rank_search, NEW.rank_address;
 197
 198       IF NEW.rank_search is NULL THEN
 199         NEW.rank_search := 30;
 200       END IF;
 201
 202       IF NEW.rank_address is NULL THEN
 203         NEW.rank_address := 30;
 204       END IF;
 205     END IF;
 206
 207     -- some postcorrections
 208     IF NEW.class = 'waterway' AND NEW.osm_type = 'R' THEN
 209         -- Slightly promote waterway relations so that they are processed
 210         -- before their members.
 211         NEW.rank_search := NEW.rank_search - 1;
 212     END IF;
 213
 214     IF (NEW.extratags -> 'capital') = 'yes' THEN
 215       NEW.rank_search := NEW.rank_search - 1;
 216     END IF;
 217
 218   END IF;
 219
 220   -- a country code make no sense below rank 4 (country)
 221   IF NEW.rank_search < 4 THEN
 222     NEW.country_code := NULL;
 223   END IF;
 224
 225   --DEBUG: RAISE WARNING 'placex_insert:END: % % % %',NEW.osm_type,NEW.osm_id,NEW.class,NEW.type;
 226
 227   RETURN NEW; -- %DIFFUPDATES% The following is not needed until doing diff updates, and slows the main index process down
 228
 229   IF NEW.osm_type = 'N' and NEW.rank_search > 28 THEN
 230       -- might be part of an interpolation
 231       result := osmline_reinsert(NEW.osm_id, NEW.geometry);
 232   ELSEIF NEW.rank_address > 0 THEN
 233     IF (ST_GeometryType(NEW.geometry) in ('ST_Polygon','ST_MultiPolygon') AND ST_IsValid(NEW.geometry)) THEN
 234       -- Performance: We just can't handle re-indexing for country level changes
 235       IF st_area(NEW.geometry) < 1 THEN
 236         -- mark items within the geometry for re-indexing
 237   --    RAISE WARNING 'placex poly insert: % % % %',NEW.osm_type,NEW.osm_id,NEW.class,NEW.type;
 238
 239         -- work around bug in postgis, this may have been fixed in 2.0.0 (see http://trac.osgeo.org/postgis/ticket/547)
 240         update placex set indexed_status = 2 where (st_covers(NEW.geometry, placex.geometry) OR ST_Intersects(NEW.geometry, placex.geometry))
 241          AND rank_search > NEW.rank_search and indexed_status = 0 and ST_geometrytype(placex.geometry) = 'ST_Point' and (rank_search < 28 or name is not null or (NEW.rank_search >= 16 and address ? 'place'));
 242         update placex set indexed_status = 2 where (st_covers(NEW.geometry, placex.geometry) OR ST_Intersects(NEW.geometry, placex.geometry))
 243          AND rank_search > NEW.rank_search and indexed_status = 0 and ST_geometrytype(placex.geometry) != 'ST_Point' and (rank_search < 28 or name is not null or (NEW.rank_search >= 16 and address ? 'place'));
 244       END IF;
 245     ELSE
 246       -- mark nearby items for re-indexing, where 'nearby' depends on the features rank_search and is a complete guess :(
 247       diameter := 0;
 248       -- 16 = city, anything higher than city is effectively ignored (polygon required!)
 249       IF NEW.type='postcode' THEN
 250         diameter := 0.05;
 251       ELSEIF NEW.rank_search < 16 THEN
 252         diameter := 0;
 253       ELSEIF NEW.rank_search < 18 THEN
 254         diameter := 0.1;
 255       ELSEIF NEW.rank_search < 20 THEN
 256         diameter := 0.05;
 257       ELSEIF NEW.rank_search = 21 THEN
 258         diameter := 0.001;
 259       ELSEIF NEW.rank_search < 24 THEN
 260         diameter := 0.02;
 261       ELSEIF NEW.rank_search < 26 THEN
 262         diameter := 0.002; -- 100 to 200 meters
 263       ELSEIF NEW.rank_search < 28 THEN
 264         diameter := 0.001; -- 50 to 100 meters
 265       END IF;
 266       IF diameter > 0 THEN
 267   --      RAISE WARNING 'placex point insert: % % % % %',NEW.osm_type,NEW.osm_id,NEW.class,NEW.type,diameter;
 268         IF NEW.rank_search >= 26 THEN
 269           -- roads may cause reparenting for >27 rank places
 270           update placex set indexed_status = 2 where indexed_status = 0 and rank_search > NEW.rank_search and ST_DWithin(placex.geometry, NEW.geometry, diameter);
 271           -- reparenting also for OSM Interpolation Lines (and for Tiger?)
 272           update location_property_osmline set indexed_status = 2 where indexed_status = 0 and ST_DWithin(location_property_osmline.linegeo, NEW.geometry, diameter);
 273         ELSEIF NEW.rank_search >= 16 THEN
 274           -- up to rank 16, street-less addresses may need reparenting
 275           update placex set indexed_status = 2 where indexed_status = 0 and rank_search > NEW.rank_search and ST_DWithin(placex.geometry, NEW.geometry, diameter) and (rank_search < 28 or name is not null or address ? 'place');
 276         ELSE
 277           -- for all other places the search terms may change as well
 278           update placex set indexed_status = 2 where indexed_status = 0 and rank_search > NEW.rank_search and ST_DWithin(placex.geometry, NEW.geometry, diameter) and (rank_search < 28 or name is not null);
 279         END IF;
 280       END IF;
 281     END IF;
 282   END IF;
 283
 284
 285    -- add to tables for special search
 286    -- Note: won't work on initial import because the classtype tables
 287    -- do not yet exist. It won't hurt either.
 288   classtable := 'place_classtype_' || NEW.class || '_' || NEW.type;
 289   SELECT count(*)>0 FROM pg_tables WHERE tablename = classtable and schemaname = current_schema() INTO result;
 290   IF result THEN
 291     EXECUTE 'INSERT INTO ' || classtable::regclass || ' (place_id, centroid) VALUES ($1,$2)'
 292     USING NEW.place_id, ST_Centroid(NEW.geometry);
 293   END IF;
 294
 295   RETURN NEW;
 296
 297 END;
 298 $$
 299 LANGUAGE plpgsql;
 300
 301
 302 CREATE OR REPLACE FUNCTION placex_update()
 303   RETURNS TRIGGER
 304   AS $$
 305 DECLARE
 306
 307   place_centroid GEOMETRY;
 308   near_centroid GEOMETRY;
 309
 310   search_maxdistance FLOAT[];
 311   search_mindistance FLOAT[];
 312   address_havelevel BOOLEAN[];
 313
 314   i INTEGER;
 315   iMax FLOAT;
 316   location RECORD;
 317   way RECORD;
 318   relation RECORD;
 319   relation_members TEXT[];
 320   linkedplacex RECORD;
 321   addr_item RECORD;
 322   search_diameter FLOAT;
 323   search_prevdiameter FLOAT;
 324   search_maxrank INTEGER;
 325   address_maxrank INTEGER;
 326   address_street_word_id INTEGER;
 327   address_street_word_ids INTEGER[];
 328   parent_place_id_rank BIGINT;
 329
 330   addr_street TEXT;
 331   addr_place TEXT;
 332
 333   isin TEXT[];
 334   isin_tokens INT[];
 335
 336   location_rank_search INTEGER;
 337   location_distance FLOAT;
 338   location_parent GEOMETRY;
 339   location_isaddress BOOLEAN;
 340   location_keywords INTEGER[];
 341
 342   default_language TEXT;
 343   name_vector INTEGER[];
 344   nameaddress_vector INTEGER[];
 345
 346   linked_node_id BIGINT;
 347   linked_importance FLOAT;
 348   linked_wikipedia TEXT;
 349
 350   result BOOLEAN;
 351 BEGIN
 352   -- deferred delete
 353   IF OLD.indexed_status = 100 THEN
 354     --DEBUG: RAISE WARNING 'placex_update delete % %',NEW.osm_type,NEW.osm_id;
 355     delete from placex where place_id = OLD.place_id;
 356     RETURN NULL;
 357   END IF;
 358
 359   IF NEW.indexed_status != 0 OR OLD.indexed_status = 0 THEN
 360     RETURN NEW;
 361   END IF;
 362
 363   --DEBUG: RAISE WARNING 'placex_update % % (%)',NEW.osm_type,NEW.osm_id,NEW.place_id;
 364
 365   NEW.indexed_date = now();
 366
 367   IF NOT %REVERSE-ONLY% THEN
 368     DELETE from search_name WHERE place_id = NEW.place_id;
 369   END IF;
 370   result := deleteSearchName(NEW.partition, NEW.place_id);
 371   DELETE FROM place_addressline WHERE place_id = NEW.place_id;
 372   result := deleteRoad(NEW.partition, NEW.place_id);
 373   result := deleteLocationArea(NEW.partition, NEW.place_id, NEW.rank_search);
 374   UPDATE placex set linked_place_id = null, indexed_status = 2
 375          where linked_place_id = NEW.place_id;
 376   -- update not necessary for osmline, cause linked_place_id does not exist
 377
 378   IF NEW.linked_place_id is not null THEN
 379     --DEBUG: RAISE WARNING 'place already linked to %', NEW.linked_place_id;
 380     RETURN NEW;
 381   END IF;
 382
 383   --DEBUG: RAISE WARNING 'Copy over address tags';
 384   -- housenumber is a computed field, so start with an empty value
 385   NEW.housenumber := NULL;
 386   IF NEW.address is not NULL THEN
 387       IF NEW.address ? 'conscriptionnumber' THEN
 388         i := getorcreate_housenumber_id(make_standard_name(NEW.address->'conscriptionnumber'));
 389         IF NEW.address ? 'streetnumber' THEN
 390             i := getorcreate_housenumber_id(make_standard_name(NEW.address->'streetnumber'));
 391             NEW.housenumber := (NEW.address->'conscriptionnumber') || '/' || (NEW.address->'streetnumber');
 392         ELSE
 393             NEW.housenumber := NEW.address->'conscriptionnumber';
 394         END IF;
 395       ELSEIF NEW.address ? 'streetnumber' THEN
 396         NEW.housenumber := NEW.address->'streetnumber';
 397         i := getorcreate_housenumber_id(make_standard_name(NEW.address->'streetnumber'));
 398       ELSEIF NEW.address ? 'housenumber' THEN
 399         NEW.housenumber := NEW.address->'housenumber';
 400         i := getorcreate_housenumber_id(make_standard_name(NEW.housenumber));
 401       END IF;
 402
 403       addr_street := NEW.address->'street';
 404       addr_place := NEW.address->'place';
 405
 406       IF NEW.address ? 'postcode' and NEW.address->'postcode' not similar to '%(,|;)%' THEN
 407         i := getorcreate_postcode_id(NEW.address->'postcode');
 408       END IF;
 409   END IF;
 410
 411   -- Speed up searches - just use the centroid of the feature
 412   -- cheaper but less acurate
 413   place_centroid := ST_PointOnSurface(NEW.geometry);
 414   -- For searching near features rather use the centroid
 415   near_centroid := ST_Envelope(NEW.geometry);
 416   NEW.centroid := null;
 417   NEW.postcode := null;
 418   --DEBUG: RAISE WARNING 'Computing preliminary centroid at %',ST_AsText(place_centroid);
 419
 420   -- recalculate country and partition
 421   IF NEW.rank_search = 4 AND NEW.address is not NULL AND NEW.address ? 'country' THEN
 422     -- for countries, believe the mapped country code,
 423     -- so that we remain in the right partition if the boundaries
 424     -- suddenly expand.
 425     NEW.country_code := lower(NEW.address->'country');
 426     NEW.partition := get_partition(lower(NEW.country_code));
 427     IF NEW.partition = 0 THEN
 428       NEW.country_code := lower(get_country_code(place_centroid));
 429       NEW.partition := get_partition(NEW.country_code);
 430     END IF;
 431   ELSE
 432     IF NEW.rank_search >= 4 THEN
 433       NEW.country_code := lower(get_country_code(place_centroid));
 434     ELSE
 435       NEW.country_code := NULL;
 436     END IF;
 437     NEW.partition := get_partition(NEW.country_code);
 438   END IF;
 439   --DEBUG: RAISE WARNING 'Country updated: "%"', NEW.country_code;
 440
 441   -- waterway ways are linked when they are part of a relation and have the same class/type
 442   IF NEW.osm_type = 'R' and NEW.class = 'waterway' THEN
 443       FOR relation_members IN select members from planet_osm_rels r where r.id = NEW.osm_id and r.parts != array[]::bigint[]
 444       LOOP
 445           FOR i IN 1..array_upper(relation_members, 1) BY 2 LOOP
 446               IF relation_members[i+1] in ('', 'main_stream', 'side_stream') AND substring(relation_members[i],1,1) = 'w' THEN
 447                 --DEBUG: RAISE WARNING 'waterway parent %, child %/%', NEW.osm_id, i, relation_members[i];
 448                 FOR linked_node_id IN SELECT place_id FROM placex
 449                   WHERE osm_type = 'W' and osm_id = substring(relation_members[i],2,200)::bigint
 450                   and class = NEW.class and type in ('river', 'stream', 'canal', 'drain', 'ditch')
 451                   and ( relation_members[i+1] != 'side_stream' or NEW.name->'name' = name->'name')
 452                 LOOP
 453                   UPDATE placex SET linked_place_id = NEW.place_id WHERE place_id = linked_node_id;
 454                 END LOOP;
 455               END IF;
 456           END LOOP;
 457       END LOOP;
 458       --DEBUG: RAISE WARNING 'Waterway processed';
 459   END IF;
 460
 461   -- What level are we searching from
 462   search_maxrank := NEW.rank_search;
 463
 464   -- Thought this wasn't needed but when we add new languages to the country_name table
 465   -- we need to update the existing names
 466   IF NEW.name is not null AND array_upper(akeys(NEW.name),1) > 1 THEN
 467     default_language := get_country_language_code(NEW.country_code);
 468     IF default_language IS NOT NULL THEN
 469       IF NEW.name ? 'name' AND NOT NEW.name ? ('name:'||default_language) THEN
 470         NEW.name := NEW.name || hstore(('name:'||default_language), (NEW.name -> 'name'));
 471       ELSEIF NEW.name ? ('name:'||default_language) AND NOT NEW.name ? 'name' THEN
 472         NEW.name := NEW.name || hstore('name', (NEW.name -> ('name:'||default_language)));
 473       END IF;
 474     END IF;
 475   END IF;
 476   --DEBUG: RAISE WARNING 'Local names updated';
 477
 478   -- Initialise the name vector using our name
 479   name_vector := make_keywords(NEW.name);
 480   nameaddress_vector := '{}'::int[];
 481
 482   FOR i IN 1..28 LOOP
 483     address_havelevel[i] := false;
 484   END LOOP;
 485
 486   NEW.importance := null;
 487   SELECT wikipedia, importance
 488     FROM compute_importance(NEW.extratags, NEW.country_code, NEW.osm_type, NEW.osm_id)
 489     INTO NEW.wikipedia,NEW.importance;
 490
 491 --DEBUG: RAISE WARNING 'Importance computed from wikipedia: %', NEW.importance;
 492
 493   -- ---------------------------------------------------------------------------
 494   -- For low level elements we inherit from our parent road
 495   IF (NEW.rank_search > 27 OR (NEW.type = 'postcode' AND NEW.rank_search = 25)) THEN
 496
 497     --DEBUG: RAISE WARNING 'finding street for % %', NEW.osm_type, NEW.osm_id;
 498
 499     -- We won't get a better centroid, besides these places are too small to care
 500     NEW.centroid := place_centroid;
 501
 502     NEW.parent_place_id := null;
 503
 504     -- if we have a POI and there is no address information,
 505     -- see if we can get it from a surrounding building
 506     IF NEW.osm_type = 'N' AND addr_street IS NULL AND addr_place IS NULL
 507        AND NEW.housenumber IS NULL THEN
 508       FOR location IN select address from placex where ST_Covers(geometry, place_centroid)
 509             and address is not null
 510             and (address ? 'housenumber' or address ? 'street' or address ? 'place')
 511             and rank_search > 28 AND ST_GeometryType(geometry) in ('ST_Polygon','ST_MultiPolygon')
 512             limit 1
 513       LOOP
 514         NEW.housenumber := location.address->'housenumber';
 515         addr_street := location.address->'street';
 516         addr_place := location.address->'place';
 517         --DEBUG: RAISE WARNING 'Found surrounding building % %', location.osm_type, location.osm_id;
 518       END LOOP;
 519     END IF;
 520
 521     -- We have to find our parent road.
 522     -- Copy data from linked items (points on ways, addr:street links, relations)
 523
 524     -- Is this object part of a relation?
 525     FOR relation IN select * from planet_osm_rels where parts @> ARRAY[NEW.osm_id] and members @> ARRAY[lower(NEW.osm_type)||NEW.osm_id]
 526     LOOP
 527       -- At the moment we only process one type of relation - associatedStreet
 528       IF relation.tags @> ARRAY['associatedStreet'] THEN
 529         FOR i IN 1..array_upper(relation.members, 1) BY 2 LOOP
 530           IF NEW.parent_place_id IS NULL AND relation.members[i+1] = 'street' THEN
 531 --RAISE WARNING 'node in relation %',relation;
 532             SELECT place_id from placex where osm_type = 'W'
 533               and osm_id = substring(relation.members[i],2,200)::bigint
 534               and rank_search = 26 and name is not null INTO NEW.parent_place_id;
 535           END IF;
 536         END LOOP;
 537       END IF;
 538     END LOOP;
 539     --DEBUG: RAISE WARNING 'Checked for street relation (%)', NEW.parent_place_id;
 540
 541     -- Note that addr:street links can only be indexed once the street itself is indexed
 542     IF NEW.parent_place_id IS NULL AND addr_street IS NOT NULL THEN
 543       address_street_word_ids := get_name_ids(make_standard_name(addr_street));
 544       IF address_street_word_ids IS NOT NULL THEN
 545         SELECT place_id from getNearestNamedRoadFeature(NEW.partition, near_centroid, address_street_word_ids) INTO NEW.parent_place_id;
 546       END IF;
 547     END IF;
 548     --DEBUG: RAISE WARNING 'Checked for addr:street (%)', NEW.parent_place_id;
 549
 550     IF NEW.parent_place_id IS NULL AND addr_place IS NOT NULL THEN
 551       address_street_word_ids := get_name_ids(make_standard_name(addr_place));
 552       IF address_street_word_ids IS NOT NULL THEN
 553         SELECT place_id from getNearestNamedPlaceFeature(NEW.partition, near_centroid, address_street_word_ids) INTO NEW.parent_place_id;
 554       END IF;
 555     END IF;
 556     --DEBUG: RAISE WARNING 'Checked for addr:place (%)', NEW.parent_place_id;
 557
 558     -- Is this node part of an interpolation?
 559     IF NEW.parent_place_id IS NULL AND NEW.osm_type = 'N' THEN
 560       SELECT q.parent_place_id FROM location_property_osmline q, planet_osm_ways x
 561         WHERE q.linegeo && NEW.geometry and x.id = q.osm_id and NEW.osm_id = any(x.nodes)
 562         LIMIT 1 INTO NEW.parent_place_id;
 563     END IF;
 564     --DEBUG: RAISE WARNING 'Checked for interpolation (%)', NEW.parent_place_id;
 565
 566     -- Is this node part of a way?
 567     IF NEW.parent_place_id IS NULL AND NEW.osm_type = 'N' THEN
 568
 569       FOR location IN
 570         SELECT p.place_id, p.osm_id, p.rank_search, p.address from placex p, planet_osm_ways w
 571          WHERE p.osm_type = 'W' and p.rank_search >= 26 and p.geometry && NEW.geometry and w.id = p.osm_id and NEW.osm_id = any(w.nodes)
 572       LOOP
 573         --DEBUG: RAISE WARNING 'Node is part of way % ', location.osm_id;
 574
 575         -- Way IS a road then we are on it - that must be our road
 576         IF location.rank_search < 28 THEN
 577 --RAISE WARNING 'node in way that is a street %',location;
 578           NEW.parent_place_id := location.place_id;
 579           EXIT;
 580         END IF;
 581         --DEBUG: RAISE WARNING 'Checked if way is street (%)', NEW.parent_place_id;
 582
 583         -- If the way mentions a street or place address, try that for parenting.
 584         IF location.address is not null THEN
 585           IF location.address ? 'street' THEN
 586             address_street_word_ids := get_name_ids(make_standard_name(location.address->'street'));
 587             IF address_street_word_ids IS NOT NULL THEN
 588               SELECT place_id from getNearestNamedRoadFeature(NEW.partition, near_centroid, address_street_word_ids) INTO NEW.parent_place_id;
 589               EXIT WHEN NEW.parent_place_id is not NULL;
 590             END IF;
 591           END IF;
 592           --DEBUG: RAISE WARNING 'Checked for addr:street in way (%)', NEW.parent_place_id;
 593
 594           IF location.address ? 'place' THEN
 595             address_street_word_ids := get_name_ids(make_standard_name(location.address->'place'));
 596             IF address_street_word_ids IS NOT NULL THEN
 597               SELECT place_id from getNearestNamedPlaceFeature(NEW.partition, near_centroid, address_street_word_ids) INTO NEW.parent_place_id;
 598               EXIT WHEN NEW.parent_place_id is not NULL;
 599             END IF;
 600           END IF;
 601         --DEBUG: RAISE WARNING 'Checked for addr:place in way (%)', NEW.parent_place_id;
 602         END IF;
 603
 604         -- Is the WAY part of a relation
 605         FOR relation IN select * from planet_osm_rels where parts @> ARRAY[location.osm_id] and members @> ARRAY['w'||location.osm_id]
 606         LOOP
 607           -- At the moment we only process one type of relation - associatedStreet
 608           IF relation.tags @> ARRAY['associatedStreet'] AND array_upper(relation.members, 1) IS NOT NULL THEN
 609             FOR i IN 1..array_upper(relation.members, 1) BY 2 LOOP
 610               IF NEW.parent_place_id IS NULL AND relation.members[i+1] = 'street' THEN
 611 --RAISE WARNING 'node in way that is in a relation %',relation;
 612                 SELECT place_id from placex where osm_type='W' and osm_id = substring(relation.members[i],2,200)::bigint
 613                   and rank_search = 26 and name is not null INTO NEW.parent_place_id;
 614               END IF;
 615             END LOOP;
 616           END IF;
 617         END LOOP;
 618         EXIT WHEN NEW.parent_place_id is not null;
 619         --DEBUG: RAISE WARNING 'Checked for street relation in way (%)', NEW.parent_place_id;
 620
 621       END LOOP;
 622     END IF;
 623
 624     -- Still nothing, just use the nearest road
 625     IF NEW.parent_place_id IS NULL THEN
 626       SELECT place_id FROM getNearestRoadFeature(NEW.partition, near_centroid) INTO NEW.parent_place_id;
 627     END IF;
 628     --DEBUG: RAISE WARNING 'Checked for nearest way (%)', NEW.parent_place_id;
 629
 630
 631     -- If we didn't find any road fallback to standard method
 632     IF NEW.parent_place_id IS NOT NULL THEN
 633
 634       -- Get the details of the parent road
 635       SELECT p.country_code, p.postcode FROM placex p
 636        WHERE p.place_id = NEW.parent_place_id INTO location;
 637
 638       NEW.country_code := location.country_code;
 639       --DEBUG: RAISE WARNING 'Got parent details from search name';
 640
 641       -- determine postcode
 642       IF NEW.rank_search > 4 THEN
 643           IF NEW.address is not null AND NEW.address ? 'postcode' THEN
 644               NEW.postcode = upper(trim(NEW.address->'postcode'));
 645           ELSE
 646              NEW.postcode := location.postcode;
 647           END IF;
 648           IF NEW.postcode is null THEN
 649             NEW.postcode := get_nearest_postcode(NEW.country_code, NEW.geometry);
 650           END IF;
 651       END IF;
 652
 653       -- If there is no name it isn't searchable, don't bother to create a search record
 654       IF NEW.name is NULL THEN
 655         --DEBUG: RAISE WARNING 'Not a searchable place % %', NEW.osm_type, NEW.osm_id;
 656         return NEW;
 657       END IF;
 658
 659       -- Performance, it would be more acurate to do all the rest of the import
 660       -- process but it takes too long
 661       -- Just be happy with inheriting from parent road only
 662       IF NEW.rank_search <= 25 and NEW.rank_address > 0 THEN
 663         result := add_location(NEW.place_id, NEW.country_code, NEW.partition, name_vector, NEW.rank_search, NEW.rank_address, upper(trim(NEW.address->'postcode')), NEW.geometry);
 664         --DEBUG: RAISE WARNING 'Place added to location table';
 665       END IF;
 666
 667       result := insertSearchName(NEW.partition, NEW.place_id, name_vector,
 668                                  NEW.rank_search, NEW.rank_address, NEW.geometry);
 669
 670       IF NOT %REVERSE-ONLY% THEN
 671           -- Merge address from parent
 672           SELECT s.name_vector, s.nameaddress_vector FROM search_name s
 673            WHERE s.place_id = NEW.parent_place_id INTO location;
 674
 675           nameaddress_vector := array_merge(nameaddress_vector,
 676                                             location.nameaddress_vector);
 677           nameaddress_vector := array_merge(nameaddress_vector, location.name_vector);
 678
 679           INSERT INTO search_name (place_id, search_rank, address_rank,
 680                                    importance, country_code, name_vector,
 681                                    nameaddress_vector, centroid)
 682                  VALUES (NEW.place_id, NEW.rank_search, NEW.rank_address,
 683                          NEW.importance, NEW.country_code, name_vector,
 684                          nameaddress_vector, place_centroid);
 685           --DEBUG: RAISE WARNING 'Place added to search table';
 686         END IF;
 687
 688       return NEW;
 689     END IF;
 690
 691   END IF;
 692
 693   -- ---------------------------------------------------------------------------
 694   -- Full indexing
 695   --DEBUG: RAISE WARNING 'Using full index mode for % %', NEW.osm_type, NEW.osm_id;
 696
 697   FOR linkedPlacex IN SELECT * FROM find_linked_place(NEW) LOOP
 698     -- If we don't already have one use this as the centre point of the geometry
 699     IF NEW.centroid IS NULL THEN
 700       --DEBUG: RAISE WARNING 'Linked %', linkedPlacex;
 701       NEW.centroid := coalesce(linkedPlacex.centroid,
 702                                ST_Centroid(linkedPlacex.geometry));
 703     END IF;
 704     place_centroid := NEW.centroid;
 705
 706     -- merge in the label name, re-init word vector
 707     IF NOT linkedPlacex.name IS NULL THEN
 708       NEW.name := linkedPlacex.name || NEW.name;
 709       name_vector := array_merge(name_vector, make_keywords(linkedPlacex.name));
 710
 711       -- Place might have had only a name tag before but has now received
 712       -- translations from the linked place. Make sure a name tag for the
 713       -- default language exists in this case.
 714       IF array_upper(akeys(NEW.name), 1) > 1 THEN
 715         default_language := get_country_language_code(NEW.country_code);
 716         IF default_language IS NOT NULL THEN
 717           IF NEW.name ? 'name' AND NOT NEW.name ? ('name:'||default_language) THEN
 718             NEW.name := NEW.name || hstore(('name:'||default_language), (NEW.name -> 'name'));
 719           ELSEIF NEW.name ? ('name:'||default_language) AND NOT NEW.name ? 'name' THEN
 720             NEW.name := NEW.name || hstore('name', (NEW.name -> ('name:'||default_language)));
 721           END IF;
 722         END IF;
 723       END IF;
 724     END IF;
 725
 726     -- merge in extra tags
 727     NEW.extratags := hstore(linkedPlacex.class, linkedPlacex.type)
 728                      || coalesce(linkedPlacex.extratags, ''::hstore)
 729                      || coalesce(NEW.extratags, ''::hstore);
 730
 731     -- mark the linked place (excludes from search results)
 732     UPDATE placex set linked_place_id = NEW.place_id
 733       WHERE place_id = linkedPlacex.place_id;
 734
 735     SELECT wikipedia, importance
 736       FROM compute_importance(linkedPlacex.extratags, NEW.country_code,
 737                               'N', linkedPlacex.osm_id)
 738       INTO linked_wikipedia,linked_importance;
 739
 740     -- Use the maximum importance if a one could be computed from the linked object.
 741     IF linked_importance is not null AND
 742        (NEW.importance is null or NEW.importance < linked_importance)
 743     THEN
 744       NEW.importance = linked_importance;
 745     END IF;
 746
 747   END LOOP;
 748
 749   -- make sure all names are in the word table
 750   IF NEW.admin_level = 2 AND NEW.class = 'boundary' AND NEW.type = 'administrative' AND NEW.country_code IS NOT NULL AND NEW.osm_type = 'R' THEN
 751     perform create_country(NEW.name, lower(NEW.country_code));
 752     --DEBUG: RAISE WARNING 'Country names updated';
 753   END IF;
 754
 755   NEW.parent_place_id = 0;
 756   parent_place_id_rank = 0;
 757
 758
 759   -- convert address store to array of tokenids
 760   --DEBUG: RAISE WARNING 'Starting address search';
 761   isin_tokens := '{}'::int[];
 762   IF NEW.address IS NOT NULL THEN
 763     FOR addr_item IN SELECT * FROM each(NEW.address)
 764     LOOP
 765       IF addr_item.key IN ('city', 'tiger:county', 'state', 'suburb', 'province', 'district', 'region', 'county', 'municipality', 'hamlet', 'village', 'subdistrict', 'town', 'neighbourhood', 'quarter', 'parish') THEN
 766         address_street_word_id := get_name_id(make_standard_name(addr_item.value));
 767         IF address_street_word_id IS NOT NULL AND NOT(ARRAY[address_street_word_id] <@ isin_tokens) THEN
 768           isin_tokens := isin_tokens || address_street_word_id;
 769         END IF;
 770         IF NOT %REVERSE-ONLY% THEN
 771           address_street_word_id := get_word_id(make_standard_name(addr_item.value));
 772           IF address_street_word_id IS NOT NULL THEN
 773             nameaddress_vector := array_merge(nameaddress_vector, ARRAY[address_street_word_id]);
 774           END IF;
 775         END IF;
 776       END IF;
 777       IF addr_item.key = 'is_in' THEN
 778         -- is_in items need splitting
 779         isin := regexp_split_to_array(addr_item.value, E'[;,]');
 780         IF array_upper(isin, 1) IS NOT NULL THEN
 781           FOR i IN 1..array_upper(isin, 1) LOOP
 782             address_street_word_id := get_name_id(make_standard_name(isin[i]));
 783             IF address_street_word_id IS NOT NULL AND NOT(ARRAY[address_street_word_id] <@ isin_tokens) THEN
 784               isin_tokens := isin_tokens || address_street_word_id;
 785             END IF;
 786
 787             -- merge word into address vector
 788             IF NOT %REVERSE-ONLY% THEN
 789               address_street_word_id := get_word_id(make_standard_name(isin[i]));
 790               IF address_street_word_id IS NOT NULL THEN
 791                 nameaddress_vector := array_merge(nameaddress_vector, ARRAY[address_street_word_id]);
 792               END IF;
 793             END IF;
 794           END LOOP;
 795         END IF;
 796       END IF;
 797     END LOOP;
 798   END IF;
 799   IF NOT %REVERSE-ONLY% THEN
 800     nameaddress_vector := array_merge(nameaddress_vector, isin_tokens);
 801   END IF;
 802
 803 -- RAISE WARNING 'ISIN: %', isin_tokens;
 804
 805   -- Process area matches
 806   location_rank_search := 0;
 807   location_distance := 0;
 808   location_parent := NULL;
 809   -- added ourself as address already
 810   address_havelevel[NEW.rank_address] := true;
 811   --DEBUG: RAISE WARNING '  getNearFeatures(%,''%'',%,''%'')',NEW.partition, place_centroid, search_maxrank, isin_tokens;
 812   FOR location IN
 813     SELECT * from getNearFeatures(NEW.partition,
 814                                   CASE WHEN NEW.rank_search >= 26
 815                                              AND NEW.rank_search < 30
 816                                        THEN NEW.geometry
 817                                        ELSE place_centroid END,
 818                                   search_maxrank, isin_tokens)
 819   LOOP
 820     IF location.rank_address != location_rank_search THEN
 821       location_rank_search := location.rank_address;
 822       IF location.isguess THEN
 823         location_distance := location.distance * 1.5;
 824       ELSE
 825         IF location.rank_address <= 12 THEN
 826           -- for county and above, if we have an area consider that exact
 827           -- (It would be nice to relax the constraint for places close to
 828           --  the boundary but we'd need the exact geometry for that. Too
 829           --  expensive.)
 830           location_distance = 0;
 831         ELSE
 832           -- Below county level remain slightly fuzzy.
 833           location_distance := location.distance * 0.5;
 834         END IF;
 835       END IF;
 836     ELSE
 837       CONTINUE WHEN location.keywords <@ location_keywords;
 838     END IF;
 839
 840     IF location.distance < location_distance OR NOT location.isguess THEN
 841       location_keywords := location.keywords;
 842
 843       location_isaddress := NOT address_havelevel[location.rank_address];
 844       IF location_isaddress AND location.isguess AND location_parent IS NOT NULL THEN
 845           location_isaddress := ST_Contains(location_parent,location.centroid);
 846       END IF;
 847
 848       -- RAISE WARNING '% isaddress: %', location.place_id, location_isaddress;
 849       -- Add it to the list of search terms
 850       IF NOT %REVERSE-ONLY% THEN
 851           nameaddress_vector := array_merge(nameaddress_vector, location.keywords::integer[]);
 852       END IF;
 853       INSERT INTO place_addressline (place_id, address_place_id, fromarea, isaddress, distance, cached_rank_address)
 854         VALUES (NEW.place_id, location.place_id, true, location_isaddress, location.distance, location.rank_address);
 855
 856       IF location_isaddress THEN
 857         -- add postcode if we have one
 858         -- (If multiple postcodes are available, we end up with the highest ranking one.)
 859         IF location.postcode is not null THEN
 860             NEW.postcode = location.postcode;
 861         END IF;
 862
 863         address_havelevel[location.rank_address] := true;
 864         IF NOT location.isguess THEN
 865           SELECT geometry FROM placex WHERE place_id = location.place_id INTO location_parent;
 866         END IF;
 867
 868         IF location.rank_address > parent_place_id_rank THEN
 869           NEW.parent_place_id = location.place_id;
 870           parent_place_id_rank = location.rank_address;
 871         END IF;
 872
 873       END IF;
 874
 875     --DEBUG: RAISE WARNING '  Terms: (%) %',location, nameaddress_vector;
 876
 877     END IF;
 878
 879   END LOOP;
 880   --DEBUG: RAISE WARNING 'address computed';
 881
 882   IF NEW.address is not null AND NEW.address ? 'postcode'
 883      AND NEW.address->'postcode' not similar to '%(,|;)%' THEN
 884     NEW.postcode := upper(trim(NEW.address->'postcode'));
 885   END IF;
 886
 887   IF NEW.postcode is null AND NEW.rank_search > 8 THEN
 888     NEW.postcode := get_nearest_postcode(NEW.country_code, NEW.geometry);
 889   END IF;
 890
 891   -- if we have a name add this to the name search table
 892   IF NEW.name IS NOT NULL THEN
 893
 894     IF NEW.rank_search <= 25 and NEW.rank_address > 0 THEN
 895       result := add_location(NEW.place_id, NEW.country_code, NEW.partition, name_vector, NEW.rank_search, NEW.rank_address, upper(trim(NEW.address->'postcode')), NEW.geometry);
 896       --DEBUG: RAISE WARNING 'added to location (full)';
 897     END IF;
 898
 899     IF NEW.rank_search between 26 and 27 and NEW.class = 'highway' THEN
 900       result := insertLocationRoad(NEW.partition, NEW.place_id, NEW.country_code, NEW.geometry);
 901       --DEBUG: RAISE WARNING 'insert into road location table (full)';
 902     END IF;
 903
 904     result := insertSearchName(NEW.partition, NEW.place_id, name_vector,
 905                                NEW.rank_search, NEW.rank_address, NEW.geometry);
 906     --DEBUG: RAISE WARNING 'added to search name (full)';
 907
 908     IF NOT %REVERSE-ONLY% THEN
 909         INSERT INTO search_name (place_id, search_rank, address_rank,
 910                                  importance, country_code, name_vector,
 911                                  nameaddress_vector, centroid)
 912                VALUES (NEW.place_id, NEW.rank_search, NEW.rank_address,
 913                        NEW.importance, NEW.country_code, name_vector,
 914                        nameaddress_vector, place_centroid);
 915     END IF;
 916
 917   END IF;
 918
 919   -- If we've not managed to pick up a better one - default centroid
 920   IF NEW.centroid IS NULL THEN
 921     NEW.centroid := place_centroid;
 922   END IF;
 923
 924   --DEBUG: RAISE WARNING 'place update % % finsihed.', NEW.osm_type, NEW.osm_id;
 925
 926   RETURN NEW;
 927 END;
 928 $$
 929 LANGUAGE plpgsql;
 930
 931
 932 CREATE OR REPLACE FUNCTION placex_delete()
 933   RETURNS TRIGGER
 934   AS $$
 935 DECLARE
 936   b BOOLEAN;
 937   classtable TEXT;
 938 BEGIN
 939   -- RAISE WARNING 'placex_delete % %',OLD.osm_type,OLD.osm_id;
 940
 941   update placex set linked_place_id = null, indexed_status = 2 where linked_place_id = OLD.place_id and indexed_status = 0;
 942   --DEBUG: RAISE WARNING 'placex_delete:01 % %',OLD.osm_type,OLD.osm_id;
 943   update placex set linked_place_id = null where linked_place_id = OLD.place_id;
 944   --DEBUG: RAISE WARNING 'placex_delete:02 % %',OLD.osm_type,OLD.osm_id;
 945
 946   IF OLD.rank_address < 30 THEN
 947
 948     -- mark everything linked to this place for re-indexing
 949     --DEBUG: RAISE WARNING 'placex_delete:03 % %',OLD.osm_type,OLD.osm_id;
 950     UPDATE placex set indexed_status = 2 from place_addressline where address_place_id = OLD.place_id
 951       and placex.place_id = place_addressline.place_id and indexed_status = 0 and place_addressline.isaddress;
 952
 953     --DEBUG: RAISE WARNING 'placex_delete:04 % %',OLD.osm_type,OLD.osm_id;
 954     DELETE FROM place_addressline where address_place_id = OLD.place_id;
 955
 956     --DEBUG: RAISE WARNING 'placex_delete:05 % %',OLD.osm_type,OLD.osm_id;
 957     b := deleteRoad(OLD.partition, OLD.place_id);
 958
 959     --DEBUG: RAISE WARNING 'placex_delete:06 % %',OLD.osm_type,OLD.osm_id;
 960     update placex set indexed_status = 2 where parent_place_id = OLD.place_id and indexed_status = 0;
 961     --DEBUG: RAISE WARNING 'placex_delete:07 % %',OLD.osm_type,OLD.osm_id;
 962     -- reparenting also for OSM Interpolation Lines (and for Tiger?)
 963     update location_property_osmline set indexed_status = 2 where indexed_status = 0 and parent_place_id = OLD.place_id;
 964
 965   END IF;
 966
 967   --DEBUG: RAISE WARNING 'placex_delete:08 % %',OLD.osm_type,OLD.osm_id;
 968
 969   IF OLD.rank_address < 26 THEN
 970     b := deleteLocationArea(OLD.partition, OLD.place_id, OLD.rank_search);
 971   END IF;
 972
 973   --DEBUG: RAISE WARNING 'placex_delete:09 % %',OLD.osm_type,OLD.osm_id;
 974
 975   IF OLD.name is not null THEN
 976     IF NOT %REVERSE-ONLY% THEN
 977       DELETE from search_name WHERE place_id = OLD.place_id;
 978     END IF;
 979     b := deleteSearchName(OLD.partition, OLD.place_id);
 980   END IF;
 981
 982   --DEBUG: RAISE WARNING 'placex_delete:10 % %',OLD.osm_type,OLD.osm_id;
 983
 984   DELETE FROM place_addressline where place_id = OLD.place_id;
 985
 986   --DEBUG: RAISE WARNING 'placex_delete:11 % %',OLD.osm_type,OLD.osm_id;
 987
 988   -- remove from tables for special search
 989   classtable := 'place_classtype_' || OLD.class || '_' || OLD.type;
 990   SELECT count(*)>0 FROM pg_tables WHERE tablename = classtable and schemaname = current_schema() INTO b;
 991   IF b THEN
 992     EXECUTE 'DELETE FROM ' || classtable::regclass || ' WHERE place_id = $1' USING OLD.place_id;
 993   END IF;
 994
 995   --DEBUG: RAISE WARNING 'placex_delete:12 % %',OLD.osm_type,OLD.osm_id;
 996
 997   RETURN OLD;
 998
 999 END;
1000 $$
1001 LANGUAGE plpgsql;