bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use v5.12;
   4
   5 use strict;
   6 use warnings;
   7
   8 use IO::File;
   9 use Math::Trig qw(deg2rad pip2 great_circle_distance);
  10 use JSON::XS;
  11 use LWP::UserAgent;
  12 use YAML::XS qw(LoadFile DumpFile);
  13
  14 my $originfile = shift @ARGV;
  15 my $clusterfile = shift @ARGV;
  16 my $zone = shift @ARGV;
  17 my $targetoriginfile = shift @ARGV;
  18 my $origins = LoadFile($originfile);
  19 my $clusters = LoadFile($clusterfile);
  20 my $gdnsname = shift @ARGV;
  21 my @servers;
  22
  23 # Initialise cluster details
  24 while (my($name,$cluster) = each %$clusters)
  25 {
  26     if ($cluster->{servers})
  27     {
  28         $cluster->{requests} = 0;
  29
  30         foreach my $server (@{$cluster->{servers}})
  31         {
  32             $server->{cluster} = $cluster;
  33             $cluster->{requests} = $cluster->{requests} + $server->{requests};
  34
  35             push @servers, $server;
  36         }
  37     }
  38     else
  39     {
  40         my $server = {
  41             cluster => $cluster,
  42             statuscake => $cluster->{statuscake},
  43             requests => $cluster->{requests},
  44             cname => $cluster->{cname},
  45             ipv4 => $cluster->{ipv4},
  46             ipv6 => $cluster->{ipv6}
  47         };
  48
  49         $cluster->{servers} = [ $server ];
  50
  51         push @servers, $server;
  52     }
  53
  54     $cluster->{name} = $name;
  55     $cluster->{status} = "down";
  56 }
  57
  58 # Initialise server details
  59 foreach my $server (@servers)
  60 {
  61     $server->{status} = "up";
  62 }
  63
  64 # If statuscake support is enabled then check which servers are up
  65 if ($ENV{STATUSCAKE_APIKEY})
  66 {
  67     my $ua = LWP::UserAgent->new;
  68     my $cache;
  69
  70     $ua->agent("mkgeo/1.0");
  71     $ua->default_header("Authorization", "Bearer $ENV{STATUSCAKE_APIKEY}");
  72
  73     if (-f "statuscake.yml")
  74     {
  75         $cache = LoadFile("statuscake.yml");
  76     }
  77     else
  78     {
  79         $cache = {};
  80     }
  81
  82     my $page = 1;
  83     my $pages = 1;
  84
  85     while ($page <= $pages)
  86     {
  87         my $response = $ua->get("https://api.statuscake.com/v1/uptime?nouptime=true&limit=100&page=${page}");
  88
  89         if ($response->is_success)
  90         {
  91             my $uptime = decode_json($response->content);
  92
  93             foreach my $test (@{$uptime->{data}})
  94             {
  95                 my $testid = $test->{id};
  96
  97                 if ($test->{status} eq "up" && !$test->{paused})
  98                 {
  99                     $cache->{$testid} = "up";
 100                 }
 101                 else
 102                 {
 103                     $cache->{$testid} = "down";
 104                 }
 105             }
 106
 107             $page = $page + 1;
 108             $pages = $uptime->{metadata}->{page_count};
 109         }
 110     }
 111
 112     foreach my $server (@servers)
 113     {
 114         if (my $testids = $server->{statuscake})
 115         {
 116             $server->{status} = "up";
 117
 118             for my $testid (@$testids)
 119             {
 120                 my $testresult = $cache->{$testid} || "down";
 121
 122                 $server->{status} = "down" if $testresult eq "down";
 123             }
 124         }
 125         else
 126         {
 127             $server->{status} = "down";
 128         }
 129     }
 130
 131     DumpFile("statuscake-$$.yml", $cache);
 132     rename("statuscake-$$.yml", "statuscake.yml");
 133 }
 134
 135 # Mark a cluster as up if any servers are up
 136 foreach my $server (@servers)
 137 {
 138     if ($server->{status} eq "up")
 139     {
 140         $server->{cluster}->{status} = "up";
 141     }
 142     else
 143     {
 144         $server->{cluster}->{requests} = $server->{cluster}->{requests} - $server->{requests};
 145     }
 146 }
 147
 148 # Create target origins object
 149 my $targetorigins = {};
 150
 151 # Initialise cluster details
 152 while (my($name,$cluster) = each %$clusters)
 153 {
 154     $cluster->{requests_limit} = $cluster->{requests};
 155     $cluster->{requests_used} = 0;
 156
 157     next if $cluster->{global};
 158
 159     $targetorigins->{$cluster->{name}} = {
 160         code => $cluster->{name},
 161         name => $cluster->{name},
 162         lat => $cluster->{lat},
 163         lon => $cluster->{lon},
 164         requests => 0
 165     };
 166 }
 167
 168 my @mappings = ();
 169
 170 # Scan origins and work out which clusters each can use
 171 foreach my $origin (values %$origins)
 172 {
 173     foreach my $cluster (values %$clusters)
 174     {
 175         my $match = match_origin($cluster, $origin);
 176
 177         if ($cluster->{status} eq "up" && $match ne "denied")
 178         {
 179             my $priority = $match eq "preferred" ? 20 : 10;
 180             my $distance;
 181
 182             if ($cluster->{global})
 183             {
 184                 $distance = 0;
 185             }
 186             else
 187             {
 188                 $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 189             }
 190
 191             push @mappings, {
 192                 origin => $origin, cluster => $cluster,
 193                 priority => $priority, distance => $distance
 194             };
 195         }
 196     }
 197 }
 198
 199 # Allocate each country to a cluster
 200 allocate_clusters(@mappings);
 201
 202 # If we failed to allocate every origin then loop, increasing
 203 # the requests for each cluster by a little and retrying until
 204 # we manage to allocate everything
 205 while (grep { !exists($_->{cluster}) } values %$origins)
 206 {
 207     # Clear any existing mappings of countries to clusters
 208     foreach my $origin (values %$origins)
 209     {
 210         delete $origin->{cluster};
 211     }
 212
 213     # Reset requests usage for clusters and increase limits by 10%
 214     foreach my $cluster (values %$clusters)
 215     {
 216         $cluster->{requests_used} = 0;
 217         $cluster->{requests_limit} = $cluster->{requests_limit} * 1.1;
 218     }
 219
 220     # Try the allocate again
 221     allocate_clusters(@mappings);
 222 }
 223
 224 # Report on allocation results
 225 foreach my $name (sort keys %$clusters)
 226 {
 227     my $cluster = $clusters->{$name};
 228     my $used = int($cluster->{requests_used} + 0.5);
 229     my $limit = $cluster->{requests_limit};
 230
 231     if ($limit > 0)
 232     {
 233         my $proportion = int($used / $limit * 100 + 0.5);
 234
 235         print "${name}: used ${used} of ${limit} (${proportion}%)\n";
 236     }
 237     else
 238     {
 239         print "${name}: used ${used} of ${limit}\n";
 240     }
 241 }
 242
 243 # Create JSON collection object
 244 my @json;
 245
 246 # Open output files
 247 my $zonefile = IO::File->new("> include/${zone}.js") || die "$!";
 248 my $jsonfile = IO::File->new("> json/${zone}.openstreetmap.org.json") || die "$!";
 249
 250 # Output headers
 251 $zonefile->print("var \U${zone}\E_RECORDS = [\n");
 252
 253 # Output details for each country
 254 foreach my $origin (sort { $a->{name} cmp $b->{name} } values %$origins)
 255 {
 256     my $cluster = $origin->{cluster};
 257
 258     if (!defined($gdnsname))
 259     {
 260         $zonefile->print("  CNAME(\"\L$origin->{code}\E.${zone}\", \"$cluster->{name}.${zone}.openstreetmap.org.\", TTL(\"10m\")),\n");
 261     }
 262
 263     if ($cluster->{lon} && $cluster->{lat})
 264     {
 265         my $clon = $origin->{lon};
 266         my $clat = $origin->{lat};
 267         my $slon = $cluster->{lon};
 268         my $slat = $cluster->{lat};
 269
 270         if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 271         {
 272             $slon = $slon + 360;
 273         }
 274         elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 275         {
 276             $clon = $clon + 360;
 277         }
 278
 279         push @json, {
 280             type => "Feature",
 281             geometry => {
 282                 type => "LineString",
 283                 coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 284             },
 285             properties => {
 286                 origin => $origin->{name},
 287                 server => $cluster->{name},
 288                 colour => $cluster->{colour}
 289             }
 290         };
 291     }
 292
 293     next if $cluster->{global};
 294
 295     $targetorigins->{$cluster->{name}}->{requests} += $origin->{requests};
 296 }
 297
 298 # Skip default records if we don't need them
 299 if (!defined($gdnsname))
 300 {
 301     # Output default records for IPs that can't be mapped to a country
 302     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 303     {
 304         my $name = $cluster->{name};
 305
 306         if (my $default = $cluster->{default})
 307         {
 308             output_server($zonefile, "${default}.${zone}", $cluster, 0);
 309         }
 310         elsif (exists($cluster->{default}))
 311         {
 312             output_server($zonefile, "${zone}", $cluster, 0);
 313         }
 314     }
 315 }
 316
 317 # Output A records for each cluster
 318 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 319 {
 320     my $name = $cluster->{name};
 321
 322     if (@{$cluster->{servers}} > 1)
 323     {
 324         output_server($zonefile, "${name}-%02d.${zone}", $cluster, 1);
 325     }
 326     else
 327     {
 328         output_server($zonefile, "${name}.${zone}", $cluster, 1);
 329     }
 330 }
 331
 332 # Output the GeoJSON text
 333 $jsonfile->print(encode_json(\@json));
 334
 335 # Output footers
 336 $zonefile->print("];\n");
 337
 338 # Close the output files
 339 $zonefile->close();
 340 $zonefile->close();
 341
 342 # Output gdnsd configuration
 343 if (defined($gdnsname))
 344 {
 345     my $gdnsmapfile = IO::File->new("> gdns/${gdnsname}.map") || die "$!";
 346     my $gdnsresourcefile = IO::File->new("> gdns/${gdnsname}.resource") || die "$!";
 347     my $gdnsweightedfile = IO::File->new("> gdns/${gdnsname}.weighted") || die "$!";
 348     my $continent = "";
 349
 350     $gdnsmapfile->print("${gdnsname} => {\n");
 351     $gdnsmapfile->print("  geoip2_db => /usr/share/GeoIP/GeoLite2-Country.mmdb\n");
 352     $gdnsmapfile->print("  datacenters => [" . join(",", sort(keys(%$clusters))) . "]\n");
 353     $gdnsmapfile->print("  map => {\n");
 354     $gdnsmapfile->print("    default => [" . join(",", sort(map { $_->{name} } grep { $_->{default} } values(%$clusters))) . "]\n");
 355
 356     foreach my $origin (sort { $a->{continent} cmp $b->{continent} || $a->{code} cmp $b->{code} } values %$origins)
 357     {
 358         my $code = $origin->{code};
 359         my $cluster = $origin->{cluster}->{name};
 360
 361         next if $code eq "XK";
 362
 363         if ($continent ne $origin->{continent})
 364         {
 365             $gdnsmapfile->print("    }\n") if $continent;
 366
 367             $continent = $origin->{continent};
 368
 369             $gdnsmapfile->print("    ${continent} => {\n");
 370         }
 371
 372         $gdnsmapfile->print("      ${code} => [${cluster}]\n");
 373     }
 374
 375     $gdnsmapfile->print("    }\n") if $continent;
 376
 377     $gdnsmapfile->print("  }\n");
 378     $gdnsmapfile->print("}\n");
 379
 380     $gdnsresourcefile->print("${gdnsname} => {\n");
 381     $gdnsresourcefile->print("  map => ${gdnsname}\n");
 382     $gdnsresourcefile->print("  dcmap => {\n");
 383
 384     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 385     {
 386         my $name = $cluster->{name};
 387
 388         if (@{$cluster->{servers}} > 1 && grep { $_->{status} eq "up" } @{$cluster->{servers}})
 389         {
 390             $gdnsweightedfile->print("${name} => {\n");
 391
 392             while (my($index,$server) = each @{$cluster->{servers}})
 393             {
 394                 if ($server->{status} eq "up")
 395                 {
 396                     my $number = sprintf("%02d", $index + 1);
 397                     my $requests = $server->{requests};
 398
 399                     if (my $cname = $server->{cname})
 400                     {
 401                         $gdnsweightedfile->print("  ${name}-${number} = [ ${cname}., ${requests} ]\n");
 402                     }
 403                     else
 404                     {
 405                         $gdnsweightedfile->print("  ${name}-${number} = [ ${name}-${number}.${zone}.openstreetmap.org., ${requests} ]\n");
 406                     }
 407                 }
 408             }
 409
 410             $gdnsweightedfile->print("}\n");
 411
 412             $gdnsresourcefile->print("    ${name} => %weighted!${name}\n");
 413         }
 414         elsif (my $cname = $cluster->{cname})
 415         {
 416             $gdnsresourcefile->print("    ${name} => ${cname}.\n");
 417         }
 418         else
 419         {
 420             $gdnsresourcefile->print("    ${name} => ${name}.${zone}.openstreetmap.org.\n");
 421         }
 422     }
 423
 424     $gdnsresourcefile->print("  }\n");
 425     $gdnsresourcefile->print("}\n");
 426
 427     $gdnsweightedfile->close();
 428     $gdnsresourcefile->close();
 429     $gdnsmapfile->close();
 430 }
 431
 432 # Output the target details in origin format if required
 433 DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 434
 435 exit 0;
 436
 437 #
 438 # Match an origin against a cluster
 439 #
 440 sub match_origin
 441 {
 442     my $cluster = shift;
 443     my $origin = shift;
 444     my $match;
 445
 446     if ($cluster->{preferred} &&
 447         $cluster->{preferred}->{origins} &&
 448         grep { $_ eq $origin->{name} } @{$cluster->{preferred}->{origins}})
 449     {
 450         $match = "preferred";
 451     }
 452     elsif ($cluster->{allowed} &&
 453            $cluster->{allowed}->{origins} &&
 454            grep { $_ eq $origin->{name} } @{$cluster->{allowed}->{origins}})
 455     {
 456         $match = "allowed";
 457     }
 458     elsif ($cluster->{preferred} &&
 459            $cluster->{preferred}->{countries} &&
 460            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 461     {
 462         $match = "preferred";
 463     }
 464     elsif ($cluster->{allowed} &&
 465            $cluster->{allowed}->{countries} &&
 466            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 467     {
 468         $match = "allowed";
 469     }
 470     elsif ($cluster->{denied} &&
 471            $cluster->{denied}->{countries} &&
 472            grep { $_ eq $origin->{country} } @{$cluster->{denied}->{countries}})
 473     {
 474         $match = "denied";
 475     }
 476     elsif ($cluster->{preferred} &&
 477            $cluster->{preferred}->{continents} &&
 478            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 479     {
 480         $match = "preferred";
 481     }
 482     elsif ($cluster->{allowed} &&
 483            $cluster->{allowed}->{continents} &&
 484            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 485     {
 486         $match = "allowed";
 487     }
 488     elsif ($cluster->{denied} &&
 489            $cluster->{denied}->{continents} &&
 490            grep { $_ eq $origin->{continent} } @{$cluster->{denied}->{continents}})
 491     {
 492         $match = "denied";
 493     }
 494     elsif ($cluster->{allowed})
 495     {
 496         $match = "denied";
 497     }
 498     else
 499     {
 500         $match = "allowed";
 501     }
 502
 503     return $match;
 504 }
 505
 506 #
 507 # Compute the great circle distance between two points
 508 #
 509 sub distance
 510 {
 511     my $lat1 = deg2rad(shift);
 512     my $lon1 = deg2rad(shift);
 513     my $lat2 = deg2rad(shift);
 514     my $lon2 = deg2rad(shift);
 515
 516     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 517 }
 518
 519 #
 520 # Allocate each origin to a cluster
 521 #
 522 sub allocate_clusters
 523 {
 524     my @mappings = sort { compare_mappings($a, $b) } @_;
 525
 526     # Loop over the mappings, trying to assign each origin to the
 527     # nearest cluster, but subject to the request limits
 528     while (my $mapping = shift @mappings)
 529     {
 530         my @group;
 531
 532         push @group, $mapping;
 533
 534         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 535         {
 536             push @group, shift @mappings;
 537         }
 538
 539         for my $mapping (sort compare_requests @group)
 540         {
 541             my $origin = $mapping->{origin};
 542             my $cluster = $mapping->{cluster};
 543
 544             if (!exists($origin->{cluster}) &&
 545                 $cluster->{requests_used} + $origin->{requests} <= $cluster->{requests_limit})
 546             {
 547                 $origin->{cluster} = $cluster;
 548                 $cluster->{requests_used} = $cluster->{requests_used} + $origin->{requests};
 549             }
 550         }
 551     }
 552
 553     return;
 554 }
 555
 556 #
 557 # Compare two mappings to decide which to use
 558 #
 559 sub compare_mappings
 560 {
 561     my $a = shift;
 562     my $b = shift;
 563
 564     return $b->{priority} <=> $a->{priority} ||
 565            $a->{distance} <=> $b->{distance};
 566 }
 567
 568 #
 569 # Compare two mappings to decide which to try first
 570 #
 571 sub compare_requests
 572 {
 573     my $a_used = ( $a->{cluster}->{requests_used} * 100.0 ) / ( $a->{cluster}->{requests_limit} * 1.0 );
 574     my $b_used = ( $b->{cluster}->{requests_used} * 100.0 ) / ( $b->{cluster}->{requests_limit} * 1.0 );
 575
 576     return $a_used <=> $b_used;
 577 }
 578
 579 #
 580 # Output DNS records for a server
 581 #
 582 sub output_server
 583 {
 584     my $zonefile = shift;
 585     my $name = shift;
 586     my $cluster = shift;
 587     my $all = shift;
 588
 589     while (my($index,$server) = each @{$cluster->{servers}})
 590     {
 591         if ($all || $server->{status} eq "up")
 592         {
 593             if ($server->{ipv4})
 594             {
 595                 $zonefile->printf("  A(\"${name}\", \"$server->{ipv4}\", TTL(\"10m\")),\n", $index + 1);
 596             }
 597
 598             if ($server->{ipv6})
 599             {
 600                 $zonefile->printf("  AAAA(\"${name}\", \"$server->{ipv6}\", TTL(\"10m\")),\n", $index + 1);
 601             }
 602         }
 603     }
 604
 605     return;
 606 }