bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use v5.12;
   4
   5 use strict;
   6 use warnings;
   7
   8 use IO::File;
   9 use Math::Trig qw(deg2rad pip2 great_circle_distance);
  10 use JSON::XS;
  11 use LWP::UserAgent;
  12 use YAML;
  13
  14 my $originfile = shift @ARGV;
  15 my $clusterfile = shift @ARGV;
  16 my $zone = shift @ARGV;
  17 my $targetoriginfile = shift @ARGV;
  18 my $origins = YAML::LoadFile($originfile);
  19 my $clusters = YAML::LoadFile($clusterfile);
  20 my $gdnsname = shift @ARGV;
  21 my @servers;
  22
  23 # Initialise cluster details
  24 while (my($name,$cluster) = each %$clusters)
  25 {
  26     if ($cluster->{servers})
  27     {
  28         $cluster->{bandwidth} = 0;
  29
  30         foreach my $server (@{$cluster->{servers}})
  31         {
  32             $server->{cluster} = $cluster;
  33             $cluster->{bandwidth} = $cluster->{bandwidth} + $server->{bandwidth};
  34
  35             push @servers, $server;
  36         }
  37     }
  38     else
  39     {
  40         my $server = {
  41             cluster => $cluster,
  42             statuscake => $cluster->{statuscake},
  43             bandwidth => $cluster->{bandwidth},
  44             ipv4 => $cluster->{ipv4},
  45             ipv6 => $cluster->{ipv6}
  46         };
  47
  48         $cluster->{servers} = [ $server ];
  49
  50         push @servers, $server;
  51     }
  52
  53     $cluster->{name} = $name;
  54     $cluster->{status} = "down";
  55 }
  56
  57 # Initialise server details
  58 foreach my $server (@servers)
  59 {
  60     $server->{status} = "up";
  61 }
  62
  63 # If statuscake support is enabled then check which servers are up
  64 if ($ENV{STATUSCAKE_USERNAME} && $ENV{STATUSCAKE_APIKEY})
  65 {
  66     my $ua = LWP::UserAgent->new;
  67     my $cache;
  68
  69     $ua->agent("mkgeo/1.0");
  70     $ua->default_header("Username", $ENV{STATUSCAKE_USERNAME});
  71     $ua->default_header("API", $ENV{STATUSCAKE_APIKEY});
  72
  73     if (-f "statuscake.yml")
  74     {
  75         $cache = YAML::LoadFile("statuscake.yml");
  76     }
  77     else
  78     {
  79         $cache = {};
  80     }
  81
  82     my $response = $ua->get("https://app.statuscake.com/API/Tests/");
  83
  84     if ($response->is_success)
  85     {
  86         my $tests = decode_json($response->content);
  87
  88         foreach my $test (@$tests)
  89         {
  90             my $testid = $test->{TestID};
  91
  92             if ($test->{Status} eq "Up" && !$test->{Paused})
  93             {
  94                 $cache->{$testid} = "up";
  95             }
  96             else
  97             {
  98                 $cache->{$testid} = "down";
  99             }
 100         }
 101     }
 102
 103     foreach my $server (@servers)
 104     {
 105         if (my $testids = $server->{statuscake})
 106         {
 107             $server->{status} = "up";
 108
 109             for my $testid (@$testids)
 110             {
 111                 my $testresult = $cache->{$testid} || "down";
 112
 113                 $server->{status} = "down" if $testresult eq "down";
 114             }
 115         }
 116         else
 117         {
 118             $server->{status} = "down";
 119         }
 120     }
 121
 122     YAML::DumpFile("statuscake.yml", $cache);
 123 }
 124
 125 # Mark a cluster as up if any servers are up
 126 foreach my $server (@servers)
 127 {
 128     if ($server->{status} eq "up")
 129     {
 130         $server->{cluster}->{status} = "up";
 131     }
 132     else
 133     {
 134         $server->{cluster}->{bandwidth} = $server->{cluster}->{bandwidth} - $server->{bandwidth};
 135     }
 136 }
 137
 138 # Create target origins object
 139 my $targetorigins = {};
 140
 141 # Initialise cluster details
 142 while (my($name,$cluster) = each %$clusters)
 143 {
 144     $cluster->{bandwidth_limit} = $cluster->{bandwidth} * 1024 * 1024;
 145     $cluster->{bandwidth_used} = 0;
 146
 147     $targetorigins->{$cluster->{name}} = {
 148         code => $cluster->{name},
 149         name => $cluster->{name},
 150         lat => $cluster->{lat},
 151         lon => $cluster->{lon},
 152         bandwidth => 0
 153     };
 154 }
 155
 156 my @mappings = ();
 157
 158 # Scan origins and work out which clusters each can use
 159 foreach my $origin (values %$origins)
 160 {
 161     foreach my $cluster (values %$clusters)
 162     {
 163         my $match = match_origin($cluster, $origin);
 164
 165         if ($cluster->{status} eq "up" && $match ne "denied")
 166         {
 167             my $priority = $match eq "preferred" ? 20 : 10;
 168             my $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 169
 170             push @mappings, {
 171                 origin => $origin, cluster => $cluster,
 172                 priority => $priority, distance => $distance
 173             };
 174         }
 175     }
 176 }
 177
 178 # Allocate each country to a cluster
 179 allocate_clusters(@mappings);
 180
 181 # If we failed to allocate every origin then loop, increasing
 182 # the bandwidth for each cluster by a little and retrying until
 183 # we manage to allocate everything
 184 while (grep { !exists($_->{cluster}) } values %$origins)
 185 {
 186     # Clear any existing mappings of countries to clusters
 187     foreach my $origin (values %$origins)
 188     {
 189         delete $origin->{cluster};
 190     }
 191
 192     # Reset bandwidth usage for clusters and increase limits by 10%
 193     foreach my $cluster (values %$clusters)
 194     {
 195         $cluster->{bandwidth_used} = 0;
 196         $cluster->{bandwidth_limit} = $cluster->{bandwidth_limit} * 1.1;
 197     }
 198
 199     # Try the allocate again
 200     allocate_clusters(@mappings);
 201 }
 202
 203 # Create JSON collection object
 204 my @json;
 205
 206 # Open output files
 207 my $zonefile = IO::File->new("> include/${zone}.js") || die "$!";
 208 my $jsonfile = IO::File->new("> json/${zone}.json") || die "$!";
 209
 210 # Output headers
 211 $zonefile->print("var \U${zone}\E_RECORDS = [\n");
 212
 213 # Output details for each country
 214 foreach my $origin (sort { $a->{name} cmp $b->{name} } values %$origins)
 215 {
 216     my $cluster = $origin->{cluster};
 217     my $clon = $origin->{lon};
 218     my $clat = $origin->{lat};
 219     my $slon = $cluster->{lon};
 220     my $slat = $cluster->{lat};
 221
 222     if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 223     {
 224         $slon = $slon + 360;
 225     }
 226     elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 227     {
 228         $clon = $clon + 360;
 229     }
 230
 231     if (!defined($gdnsname))
 232     {
 233         $zonefile->print("  CNAME(\"\L$origin->{code}\E.${zone}\", \"$cluster->{name}.${zone}.openstreetmap.org.\", TTL(\"10m\")),\n");
 234     }
 235
 236     push @json, {
 237         type => "Feature",
 238         geometry => {
 239             type => "LineString",
 240             coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 241         },
 242         properties => {
 243             origin => $origin->{name},
 244             server => $cluster->{name},
 245             colour => $cluster->{colour}
 246         }
 247     };
 248
 249     $targetorigins->{$cluster->{name}}->{bandwidth} += $origin->{bandwidth};
 250 }
 251
 252 # Skip default records if we don't need them
 253 if (!defined($gdnsname))
 254 {
 255     # Output default records for IPs that can't be mapped to a country
 256     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 257     {
 258         my $name = $cluster->{name};
 259
 260         if (my $default = $cluster->{default})
 261         {
 262             output_server($zonefile, "${default}.${zone}", $cluster);
 263         }
 264         elsif (exists($cluster->{default}))
 265         {
 266             output_server($zonefile, "${zone}", $cluster);
 267         }
 268     }
 269 }
 270
 271 # Output A records for each cluster
 272 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 273 {
 274     my $name = $cluster->{name};
 275
 276     output_server($zonefile, "${name}.${zone}", $cluster);
 277
 278     if (@{$cluster->{servers}} > 1)
 279     {
 280         output_server($zonefile, "${name}-%02d.${zone}", $cluster);
 281     }
 282 }
 283
 284 # Output the GeoJSON text
 285 $jsonfile->print(encode_json(\@json));
 286
 287 # Output footers
 288 $zonefile->print("];\n");
 289
 290 # Close the output files
 291 $zonefile->close();
 292 $zonefile->close();
 293
 294 # Output gdnsd configuration
 295 if (defined($gdnsname))
 296 {
 297     my $gdnsmapfile = IO::File->new("> gdns/${gdnsname}.map") || die "$!";
 298     my $gdnsresourcefile = IO::File->new("> gdns/${gdnsname}.resource") || die "$!";
 299     my $gdnsweightedfile = IO::File->new("> gdns/${gdnsname}.weighted") || die "$!";
 300     my $continent = "";
 301
 302     $gdnsmapfile->print("${gdnsname} => {\n");
 303     $gdnsmapfile->print("  geoip2_db => /usr/share/GeoIP/GeoLite2-Country.mmdb\n");
 304     $gdnsmapfile->print("  datacenters => [" . join(",", sort(keys(%$clusters))) . "]\n");
 305     $gdnsmapfile->print("  map => {\n");
 306     $gdnsmapfile->print("    default => [" . join(",", sort(map { $_->{name} } grep { $_->{default} } values(%$clusters))) . "]\n");
 307
 308     foreach my $origin (sort { $a->{continent} cmp $b->{continent} || $a->{code} cmp $b->{code} } values %$origins)
 309     {
 310         my $code = $origin->{code};
 311         my $cluster = $origin->{cluster}->{name};
 312
 313         next if $code eq "XK";
 314
 315         if ($continent ne $origin->{continent})
 316         {
 317             $gdnsmapfile->print("    }\n") if $continent;
 318
 319             $continent = $origin->{continent};
 320
 321             $gdnsmapfile->print("    ${continent} => {\n");
 322         }
 323
 324         $gdnsmapfile->print("      ${code} => [${cluster}]\n");
 325     }
 326
 327     $gdnsmapfile->print("    }\n") if $continent;
 328
 329     $gdnsmapfile->print("  }\n");
 330     $gdnsmapfile->print("}\n");
 331
 332     $gdnsresourcefile->print("${gdnsname} => {\n");
 333     $gdnsresourcefile->print("  map => ${gdnsname}\n");
 334     $gdnsresourcefile->print("  dcmap => {\n");
 335
 336     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 337     {
 338         my $name = $cluster->{name};
 339
 340         if (@{$cluster->{servers}} > 1)
 341         {
 342             $gdnsweightedfile->print("${name} => {\n");
 343
 344             while (my($index,$server) = each @{$cluster->{servers}})
 345             {
 346                 if ($server->{status} eq "up")
 347                 {
 348                     my $number = sprintf("%02d", $index + 1);
 349                     my $bandwidth = $server->{bandwidth};
 350
 351                     $gdnsweightedfile->print("  ${name}-${number} = [ ${name}-${number}.${zone}., ${bandwidth} ]\n");
 352                 }
 353             }
 354
 355             $gdnsweightedfile->print("}\n");
 356
 357             $gdnsresourcefile->print("    ${name} => %weighted!${name}\n");
 358         }
 359         else
 360         {
 361             $gdnsresourcefile->print("    ${name} => ${name}.${zone}.\n");
 362         }
 363     }
 364
 365     $gdnsresourcefile->print("  }\n");
 366     $gdnsresourcefile->print("}\n");
 367
 368     $gdnsweightedfile->close();
 369     $gdnsresourcefile->close();
 370     $gdnsmapfile->close();
 371 }
 372
 373 # Output the target details in origin format if required
 374 YAML::DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 375
 376 exit 0;
 377
 378 #
 379 # Match an origin against a cluster
 380 #
 381 sub match_origin
 382 {
 383     my $cluster = shift;
 384     my $origin = shift;
 385     my $match;
 386
 387     if ($cluster->{preferred} &&
 388         $cluster->{preferred}->{origins} &&
 389         grep { $_ eq $origin->{name} } @{$cluster->{preferred}->{origins}})
 390     {
 391         $match = "preferred";
 392     }
 393     elsif ($cluster->{allowed} &&
 394            $cluster->{allowed}->{origins} &&
 395            grep { $_ eq $origin->{name} } @{$cluster->{allowed}->{origins}})
 396     {
 397         $match = "allowed";
 398     }
 399     elsif ($cluster->{preferred} &&
 400            $cluster->{preferred}->{countries} &&
 401            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 402     {
 403         $match = "preferred";
 404     }
 405     elsif ($cluster->{allowed} &&
 406            $cluster->{allowed}->{countries} &&
 407            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 408     {
 409         $match = "allowed";
 410     }
 411     elsif ($cluster->{denied} &&
 412            $cluster->{denied}->{countries} &&
 413            grep { $_ eq $origin->{country} } @{$cluster->{denied}->{countries}})
 414     {
 415         $match = "denied";
 416     }
 417     elsif ($cluster->{preferred} &&
 418            $cluster->{preferred}->{continents} &&
 419            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 420     {
 421         $match = "preferred";
 422     }
 423     elsif ($cluster->{allowed} &&
 424            $cluster->{allowed}->{continents} &&
 425            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 426     {
 427         $match = "allowed";
 428     }
 429     elsif ($cluster->{denied} &&
 430            $cluster->{denied}->{continents} &&
 431            grep { $_ eq $origin->{continent} } @{$cluster->{denied}->{continents}})
 432     {
 433         $match = "denied";
 434     }
 435     elsif ($cluster->{allowed})
 436     {
 437         $match = "denied";
 438     }
 439     else
 440     {
 441         $match = "allowed";
 442     }
 443
 444     return $match;
 445 }
 446
 447 #
 448 # Compute the great circle distance between two points
 449 #
 450 sub distance
 451 {
 452     my $lat1 = deg2rad(shift);
 453     my $lon1 = deg2rad(shift);
 454     my $lat2 = deg2rad(shift);
 455     my $lon2 = deg2rad(shift);
 456
 457     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 458 }
 459
 460 #
 461 # Allocate each origin to a cluster
 462 #
 463 sub allocate_clusters
 464 {
 465     my @mappings = sort { compare_mappings($a, $b) } @_;
 466
 467     # Loop over the mappings, trying to assign each origin to the
 468     # nearest cluster, but subject to the bandwidth limits
 469     while (my $mapping = shift @mappings)
 470     {
 471         my @group;
 472
 473         push @group, $mapping;
 474
 475         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 476         {
 477             push @group, shift @mappings;
 478         }
 479
 480         for my $mapping (sort compare_bandwidth @group)
 481         {
 482             my $origin = $mapping->{origin};
 483             my $cluster = $mapping->{cluster};
 484
 485             if (!exists($origin->{cluster}) &&
 486                 $cluster->{bandwidth_used} + $origin->{bandwidth} <= $cluster->{bandwidth_limit})
 487             {
 488                 $origin->{cluster} = $cluster;
 489                 $cluster->{bandwidth_used} = $cluster->{bandwidth_used} + $origin->{bandwidth};
 490             }
 491         }
 492     }
 493
 494     return;
 495 }
 496
 497 #
 498 # Compare two mappings to decide which to use
 499 #
 500 sub compare_mappings
 501 {
 502     my $a = shift;
 503     my $b = shift;
 504
 505     return $b->{priority} <=> $a->{priority} ||
 506            $a->{distance} <=> $b->{distance};
 507 }
 508
 509 #
 510 # Compare two mappings to decide which to try first
 511 #
 512 sub compare_bandwidth
 513 {
 514     my $a_used = ( $a->{cluster}->{bandwidth_used} * 100.0 ) / ( $a->{cluster}->{bandwidth_limit} * 1.0 );
 515     my $b_used = ( $b->{cluster}->{bandwidth_used} * 100.0 ) / ( $b->{cluster}->{bandwidth_limit} * 1.0 );
 516
 517     return $a_used <=> $b_used;
 518 }
 519
 520 #
 521 # Output DNS records for a server
 522 #
 523 sub output_server
 524 {
 525     my $zonefile = shift;
 526     my $name = shift;
 527     my $cluster = shift;
 528
 529     while (my($index,$server) = each @{$cluster->{servers}})
 530     {
 531         if ($server->{status} eq "up")
 532         {
 533             $zonefile->printf("  A(\"${name}\", \"$server->{ipv4}\", TTL(\"10m\")),\n", $index + 1);
 534
 535             if ($server->{ipv6})
 536             {
 537                 my $ipv6 = $server->{ipv6};
 538
 539                 $ipv6 =~ s/([0-9a-f]{4})(?=.)/$1:/ig;
 540
 541                 $zonefile->printf("  AAAA(\"${name}\", \"${ipv6}\", TTL(\"10m\")),\n", $index + 1);
 542             }
 543         }
 544     }
 545
 546     return;
 547 }