bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use v5.12;
   4
   5 use strict;
   6 use warnings;
   7
   8 use IO::File;
   9 use Math::Trig qw(deg2rad pip2 great_circle_distance);
  10 use JSON::XS;
  11 use LWP::UserAgent;
  12 use YAML::XS qw(LoadFile DumpFile);
  13
  14 my $originfile = shift @ARGV;
  15 my $clusterfile = shift @ARGV;
  16 my $zone = shift @ARGV;
  17 my $targetoriginfile = shift @ARGV;
  18 my $origins = LoadFile($originfile);
  19 my $clusters = LoadFile($clusterfile);
  20 my $gdnsname = shift @ARGV;
  21 my @servers;
  22
  23 # Initialise cluster details
  24 while (my($name,$cluster) = each %$clusters)
  25 {
  26     if ($cluster->{servers})
  27     {
  28         $cluster->{requests} = 0;
  29
  30         foreach my $server (@{$cluster->{servers}})
  31         {
  32             $server->{cluster} = $cluster;
  33             $cluster->{requests} = $cluster->{requests} + $server->{requests};
  34
  35             push @servers, $server;
  36         }
  37     }
  38     elsif ($cluster->{requests} > 0)
  39     {
  40         my $server = {
  41             cluster => $cluster,
  42             statuscake => $cluster->{statuscake},
  43             requests => $cluster->{requests},
  44             cname => $cluster->{cname},
  45             ipv4 => $cluster->{ipv4},
  46             ipv6 => $cluster->{ipv6}
  47         };
  48
  49         $cluster->{servers} = [ $server ];
  50
  51         push @servers, $server;
  52     }
  53     else
  54     {
  55         $cluster->{servers} = [];
  56     }
  57
  58     $cluster->{name} = $name;
  59     $cluster->{status} = "down";
  60 }
  61
  62 # Initialise server details
  63 foreach my $server (@servers)
  64 {
  65     $server->{status} = "up";
  66 }
  67
  68 # If statuscake support is enabled then check which servers are up
  69 if ($ENV{STATUSCAKE_APIKEY})
  70 {
  71     my $ua = LWP::UserAgent->new;
  72     my $cache;
  73
  74     $ua->agent("mkgeo/1.0");
  75     $ua->default_header("Authorization", "Bearer $ENV{STATUSCAKE_APIKEY}");
  76
  77     if (-f "statuscake.yml")
  78     {
  79         $cache = LoadFile("statuscake.yml");
  80     }
  81     else
  82     {
  83         $cache = {};
  84     }
  85
  86     my $page = 1;
  87     my $pages = 1;
  88
  89     while ($page <= $pages)
  90     {
  91         my $response = $ua->get("https://api.statuscake.com/v1/uptime?nouptime=true&limit=100&page=${page}");
  92
  93         if ($response->is_success)
  94         {
  95             my $uptime = decode_json($response->content);
  96
  97             foreach my $test (@{$uptime->{data}})
  98             {
  99                 my $testid = $test->{id};
 100
 101                 if ($test->{status} eq "up" && !$test->{paused})
 102                 {
 103                     $cache->{$testid} = "up";
 104                 }
 105                 else
 106                 {
 107                     $cache->{$testid} = "down";
 108                 }
 109             }
 110
 111             $page = $page + 1;
 112             $pages = $uptime->{metadata}->{page_count};
 113         }
 114     }
 115
 116     foreach my $server (@servers)
 117     {
 118         if (my $testids = $server->{statuscake})
 119         {
 120             $server->{status} = "up";
 121
 122             for my $testid (@$testids)
 123             {
 124                 my $testresult = $cache->{$testid} || "down";
 125
 126                 $server->{status} = "down" if $testresult eq "down";
 127             }
 128         }
 129         else
 130         {
 131             $server->{status} = "down";
 132         }
 133     }
 134
 135     DumpFile("statuscake-$$.yml", $cache);
 136     rename("statuscake-$$.yml", "statuscake.yml");
 137 }
 138
 139 # Mark a cluster as up if any servers are up
 140 foreach my $server (@servers)
 141 {
 142     if ($server->{status} eq "up")
 143     {
 144         $server->{cluster}->{status} = "up";
 145     }
 146     else
 147     {
 148         $server->{cluster}->{requests} = $server->{cluster}->{requests} - $server->{requests};
 149     }
 150 }
 151
 152 # Abort if no servers at all are up
 153 exit 0 unless grep { $_->{status} eq "up" } values(%$clusters);
 154
 155 # Create target origins object
 156 my $targetorigins = {};
 157
 158 # Initialise cluster details
 159 while (my($name,$cluster) = each %$clusters)
 160 {
 161     $cluster->{requests_limit} = $cluster->{requests};
 162     $cluster->{requests_used} = 0;
 163
 164     next if $cluster->{global};
 165
 166     $targetorigins->{$cluster->{name}} = {
 167         code => $cluster->{name},
 168         name => $cluster->{name},
 169         lat => $cluster->{lat},
 170         lon => $cluster->{lon},
 171         requests => 0
 172     };
 173 }
 174
 175 my @mappings = ();
 176
 177 # Scan origins and work out which clusters each can use
 178 foreach my $origin (values %$origins)
 179 {
 180     foreach my $cluster (values %$clusters)
 181     {
 182         my $match = match_origin($cluster, $origin);
 183
 184         if ($cluster->{status} eq "up" && $match ne "denied")
 185         {
 186             my $priority = $match eq "preferred" ? 20 : 10;
 187             my $distance;
 188
 189             if ($cluster->{global})
 190             {
 191                 $distance = 0;
 192             }
 193             else
 194             {
 195                 $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 196             }
 197
 198             push @mappings, {
 199                 origin => $origin, cluster => $cluster,
 200                 priority => $priority, distance => $distance
 201             };
 202         }
 203     }
 204 }
 205
 206 # Allocate each country to a cluster
 207 allocate_clusters(@mappings);
 208
 209 # If we failed to allocate every origin then loop, increasing
 210 # the requests for each cluster by a little and retrying until
 211 # we manage to allocate everything
 212 while (grep { !exists($_->{cluster}) } values %$origins)
 213 {
 214     # Clear any existing mappings of countries to clusters
 215     foreach my $origin (values %$origins)
 216     {
 217         delete $origin->{cluster};
 218     }
 219
 220     # Reset requests usage for clusters and increase limits by 10%
 221     foreach my $cluster (values %$clusters)
 222     {
 223         $cluster->{requests_used} = 0;
 224         $cluster->{requests_limit} = $cluster->{requests_limit} * 1.1;
 225     }
 226
 227     # Try the allocate again
 228     allocate_clusters(@mappings);
 229 }
 230
 231 # Report on allocation results
 232 foreach my $name (sort keys %$clusters)
 233 {
 234     my $cluster = $clusters->{$name};
 235     my $used = int($cluster->{requests_used} + 0.5);
 236     my $limit = $cluster->{requests_limit};
 237
 238     if ($limit > 0)
 239     {
 240         my $proportion = int($used / $limit * 100 + 0.5);
 241
 242         print "${name}: used ${used} of ${limit} (${proportion}%)\n";
 243     }
 244     else
 245     {
 246         print "${name}: used ${used} of ${limit}\n";
 247     }
 248 }
 249
 250 # Create JSON collection object
 251 my @json;
 252
 253 # Open output files
 254 my $zonefile = IO::File->new("> include/${zone}.js") || die "$!";
 255 my $jsonfile = IO::File->new("> json/${zone}.openstreetmap.org.json") || die "$!";
 256
 257 # Output headers
 258 $zonefile->print("var \U${zone}\E_RECORDS = [\n");
 259
 260 # Output details for each country
 261 foreach my $origin (sort { $a->{name} cmp $b->{name} } values %$origins)
 262 {
 263     my $cluster = $origin->{cluster};
 264
 265     if (!defined($gdnsname))
 266     {
 267         $zonefile->print("  CNAME(\"\L$origin->{code}\E.${zone}\", \"$cluster->{name}.${zone}.openstreetmap.org.\", TTL(\"10m\")),\n");
 268     }
 269
 270     if ($cluster->{lon} && $cluster->{lat})
 271     {
 272         my $clon = $origin->{lon};
 273         my $clat = $origin->{lat};
 274         my $slon = $cluster->{lon};
 275         my $slat = $cluster->{lat};
 276
 277         if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 278         {
 279             $slon = $slon + 360;
 280         }
 281         elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 282         {
 283             $clon = $clon + 360;
 284         }
 285
 286         push @json, {
 287             type => "Feature",
 288             geometry => {
 289                 type => "LineString",
 290                 coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 291             },
 292             properties => {
 293                 origin => $origin->{name},
 294                 server => $cluster->{name},
 295                 colour => $cluster->{colour}
 296             }
 297         };
 298     }
 299
 300     next if $cluster->{global};
 301
 302     $targetorigins->{$cluster->{name}}->{requests} += $origin->{requests};
 303 }
 304
 305 # Skip default records if we don't need them
 306 if (!defined($gdnsname))
 307 {
 308     # Output default records for IPs that can't be mapped to a country
 309     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 310     {
 311         my $name = $cluster->{name};
 312
 313         if (my $default = $cluster->{default})
 314         {
 315             output_server($zonefile, "${default}.${zone}", $cluster, 0);
 316         }
 317         elsif (exists($cluster->{default}))
 318         {
 319             output_server($zonefile, "${zone}", $cluster, 0);
 320         }
 321     }
 322 }
 323
 324 # Output A records for each cluster
 325 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 326 {
 327     my $name = $cluster->{name};
 328
 329     if (@{$cluster->{servers}} > 1)
 330     {
 331         output_server($zonefile, "${name}-%02d.${zone}", $cluster, 1);
 332     }
 333     else
 334     {
 335         output_server($zonefile, "${name}.${zone}", $cluster, 1);
 336     }
 337 }
 338
 339 # Output the GeoJSON text
 340 $jsonfile->print(encode_json(\@json));
 341
 342 # Output footers
 343 $zonefile->print("];\n");
 344
 345 # Close the output files
 346 $zonefile->close();
 347 $zonefile->close();
 348
 349 # Output gdnsd configuration
 350 if (defined($gdnsname))
 351 {
 352     my $gdnsmapfile = IO::File->new("> gdns/${gdnsname}.map") || die "$!";
 353     my $gdnsresourcefile = IO::File->new("> gdns/${gdnsname}.resource") || die "$!";
 354     my $gdnsweightedfile = IO::File->new("> gdns/${gdnsname}.weighted") || die "$!";
 355     my $continent = "";
 356
 357     $gdnsmapfile->print("${gdnsname} => {\n");
 358     $gdnsmapfile->print("  geoip2_db => /usr/share/GeoIP/GeoLite2-Country.mmdb\n");
 359     $gdnsmapfile->print("  datacenters => [" . join(",", sort(keys(%$clusters))) . "]\n");
 360     $gdnsmapfile->print("  map => {\n");
 361     $gdnsmapfile->print("    default => [" . join(",", sort(map { $_->{name} } grep { $_->{default} } values(%$clusters))) . "]\n");
 362
 363     foreach my $origin (sort { $a->{continent} cmp $b->{continent} || $a->{code} cmp $b->{code} } values %$origins)
 364     {
 365         my $code = $origin->{code};
 366         my $cluster = $origin->{cluster}->{name};
 367
 368         next if $code eq "XK";
 369
 370         if ($continent ne $origin->{continent})
 371         {
 372             $gdnsmapfile->print("    }\n") if $continent;
 373
 374             $continent = $origin->{continent};
 375
 376             $gdnsmapfile->print("    ${continent} => {\n");
 377         }
 378
 379         $gdnsmapfile->print("      ${code} => [${cluster}]\n");
 380     }
 381
 382     $gdnsmapfile->print("    }\n") if $continent;
 383
 384     $gdnsmapfile->print("  }\n");
 385     $gdnsmapfile->print("}\n");
 386
 387     $gdnsresourcefile->print("${gdnsname} => {\n");
 388     $gdnsresourcefile->print("  map => ${gdnsname}\n");
 389     $gdnsresourcefile->print("  dcmap => {\n");
 390
 391     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 392     {
 393         my $name = $cluster->{name};
 394
 395         if (@{$cluster->{servers}} > 1 && grep { $_->{status} eq "up" } @{$cluster->{servers}})
 396         {
 397             $gdnsweightedfile->print("${name} => {\n");
 398
 399             while (my($index,$server) = each @{$cluster->{servers}})
 400             {
 401                 if ($server->{status} eq "up")
 402                 {
 403                     my $number = sprintf("%02d", $index + 1);
 404                     my $requests = $server->{requests};
 405
 406                     if (my $cname = $server->{cname})
 407                     {
 408                         $gdnsweightedfile->print("  ${name}-${number} = [ ${cname}., ${requests} ]\n");
 409                     }
 410                     else
 411                     {
 412                         $gdnsweightedfile->print("  ${name}-${number} = [ ${name}-${number}.${zone}.openstreetmap.org., ${requests} ]\n");
 413                     }
 414                 }
 415             }
 416
 417             $gdnsweightedfile->print("}\n");
 418
 419             $gdnsresourcefile->print("    ${name} => %weighted!${name}\n");
 420         }
 421         elsif (my $cname = $cluster->{cname})
 422         {
 423             $gdnsresourcefile->print("    ${name} => ${cname}.\n");
 424         }
 425         else
 426         {
 427             $gdnsresourcefile->print("    ${name} => ${name}.${zone}.openstreetmap.org.\n");
 428         }
 429     }
 430
 431     $gdnsresourcefile->print("  }\n");
 432     $gdnsresourcefile->print("}\n");
 433
 434     $gdnsweightedfile->close();
 435     $gdnsresourcefile->close();
 436     $gdnsmapfile->close();
 437 }
 438
 439 # Output the target details in origin format if required
 440 DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 441
 442 exit 0;
 443
 444 #
 445 # Match an origin against a cluster
 446 #
 447 sub match_origin
 448 {
 449     my $cluster = shift;
 450     my $origin = shift;
 451     my $match;
 452
 453     if ($cluster->{preferred} &&
 454         $cluster->{preferred}->{origins} &&
 455         grep { $_ eq $origin->{name} } @{$cluster->{preferred}->{origins}})
 456     {
 457         $match = "preferred";
 458     }
 459     elsif ($cluster->{allowed} &&
 460            $cluster->{allowed}->{origins} &&
 461            grep { $_ eq $origin->{name} } @{$cluster->{allowed}->{origins}})
 462     {
 463         $match = "allowed";
 464     }
 465     elsif ($cluster->{preferred} &&
 466            $cluster->{preferred}->{countries} &&
 467            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 468     {
 469         $match = "preferred";
 470     }
 471     elsif ($cluster->{allowed} &&
 472            $cluster->{allowed}->{countries} &&
 473            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 474     {
 475         $match = "allowed";
 476     }
 477     elsif ($cluster->{denied} &&
 478            $cluster->{denied}->{countries} &&
 479            grep { $_ eq $origin->{country} } @{$cluster->{denied}->{countries}})
 480     {
 481         $match = "denied";
 482     }
 483     elsif ($cluster->{preferred} &&
 484            $cluster->{preferred}->{continents} &&
 485            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 486     {
 487         $match = "preferred";
 488     }
 489     elsif ($cluster->{allowed} &&
 490            $cluster->{allowed}->{continents} &&
 491            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 492     {
 493         $match = "allowed";
 494     }
 495     elsif ($cluster->{denied} &&
 496            $cluster->{denied}->{continents} &&
 497            grep { $_ eq $origin->{continent} } @{$cluster->{denied}->{continents}})
 498     {
 499         $match = "denied";
 500     }
 501     elsif ($cluster->{allowed})
 502     {
 503         $match = "denied";
 504     }
 505     else
 506     {
 507         $match = "allowed";
 508     }
 509
 510     return $match;
 511 }
 512
 513 #
 514 # Compute the great circle distance between two points
 515 #
 516 sub distance
 517 {
 518     my $lat1 = deg2rad(shift);
 519     my $lon1 = deg2rad(shift);
 520     my $lat2 = deg2rad(shift);
 521     my $lon2 = deg2rad(shift);
 522
 523     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 524 }
 525
 526 #
 527 # Allocate each origin to a cluster
 528 #
 529 sub allocate_clusters
 530 {
 531     my @mappings = sort { compare_mappings($a, $b) } @_;
 532
 533     # Loop over the mappings, trying to assign each origin to the
 534     # nearest cluster, but subject to the request limits
 535     while (my $mapping = shift @mappings)
 536     {
 537         my @group;
 538
 539         push @group, $mapping;
 540
 541         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 542         {
 543             push @group, shift @mappings;
 544         }
 545
 546         for my $mapping (sort compare_requests @group)
 547         {
 548             my $origin = $mapping->{origin};
 549             my $cluster = $mapping->{cluster};
 550
 551             if (!exists($origin->{cluster}) &&
 552                 $cluster->{requests_used} + $origin->{requests} <= $cluster->{requests_limit})
 553             {
 554                 $origin->{cluster} = $cluster;
 555                 $cluster->{requests_used} = $cluster->{requests_used} + $origin->{requests};
 556             }
 557         }
 558     }
 559
 560     return;
 561 }
 562
 563 #
 564 # Compare two mappings to decide which to use
 565 #
 566 sub compare_mappings
 567 {
 568     my $a = shift;
 569     my $b = shift;
 570
 571     return $b->{priority} <=> $a->{priority} ||
 572            $a->{distance} <=> $b->{distance};
 573 }
 574
 575 #
 576 # Compare two mappings to decide which to try first
 577 #
 578 sub compare_requests
 579 {
 580     my $a_used = ( $a->{cluster}->{requests_used} * 100.0 ) / ( $a->{cluster}->{requests_limit} * 1.0 );
 581     my $b_used = ( $b->{cluster}->{requests_used} * 100.0 ) / ( $b->{cluster}->{requests_limit} * 1.0 );
 582
 583     return $a_used <=> $b_used;
 584 }
 585
 586 #
 587 # Output DNS records for a server
 588 #
 589 sub output_server
 590 {
 591     my $zonefile = shift;
 592     my $name = shift;
 593     my $cluster = shift;
 594     my $all = shift;
 595
 596     while (my($index,$server) = each @{$cluster->{servers}})
 597     {
 598         if ($all || $server->{status} eq "up")
 599         {
 600             if ($server->{ipv4})
 601             {
 602                 $zonefile->printf("  A(\"${name}\", \"$server->{ipv4}\", TTL(\"10m\")),\n", $index + 1);
 603             }
 604
 605             if ($server->{ipv6})
 606             {
 607                 $zonefile->printf("  AAAA(\"${name}\", \"$server->{ipv6}\", TTL(\"10m\")),\n", $index + 1);
 608             }
 609         }
 610     }
 611
 612     return;
 613 }