bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use v5.12;
   4
   5 use strict;
   6 use warnings;
   7
   8 use IO::File;
   9 use Math::Trig qw(deg2rad pip2 great_circle_distance);
  10 use JSON::XS;
  11 use LWP::UserAgent;
  12 use YAML::XS qw(LoadFile DumpFile);
  13
  14 my $originfile = shift @ARGV;
  15 my $clusterfile = shift @ARGV;
  16 my $zone = shift @ARGV;
  17 my $targetoriginfile = shift @ARGV;
  18 my $origins = LoadFile($originfile);
  19 my $clusters = LoadFile($clusterfile);
  20 my $gdnsname = shift @ARGV;
  21 my @servers;
  22
  23 # Initialise cluster details
  24 while (my($name,$cluster) = each %$clusters)
  25 {
  26     if ($cluster->{servers})
  27     {
  28         $cluster->{bandwidth} = 0;
  29
  30         foreach my $server (@{$cluster->{servers}})
  31         {
  32             $server->{cluster} = $cluster;
  33             $cluster->{bandwidth} = $cluster->{bandwidth} + $server->{bandwidth};
  34
  35             push @servers, $server;
  36         }
  37     }
  38     else
  39     {
  40         my $server = {
  41             cluster => $cluster,
  42             statuscake => $cluster->{statuscake},
  43             bandwidth => $cluster->{bandwidth},
  44             cname => $cluster->{cname},
  45             ipv4 => $cluster->{ipv4},
  46             ipv6 => $cluster->{ipv6}
  47         };
  48
  49         $cluster->{servers} = [ $server ];
  50
  51         push @servers, $server;
  52     }
  53
  54     $cluster->{name} = $name;
  55     $cluster->{status} = "down";
  56 }
  57
  58 # Initialise server details
  59 foreach my $server (@servers)
  60 {
  61     $server->{status} = "up";
  62 }
  63
  64 # If statuscake support is enabled then check which servers are up
  65 if ($ENV{STATUSCAKE_USERNAME} && $ENV{STATUSCAKE_APIKEY})
  66 {
  67     my $ua = LWP::UserAgent->new;
  68     my $cache;
  69
  70     $ua->agent("mkgeo/1.0");
  71     $ua->default_header("Username", $ENV{STATUSCAKE_USERNAME});
  72     $ua->default_header("API", $ENV{STATUSCAKE_APIKEY});
  73
  74     if (-f "statuscake.yml")
  75     {
  76         $cache = LoadFile("statuscake.yml");
  77     }
  78     else
  79     {
  80         $cache = {};
  81     }
  82
  83     my $response = $ua->get("https://app.statuscake.com/API/Tests/");
  84
  85     if ($response->is_success)
  86     {
  87         my $tests = decode_json($response->content);
  88
  89         foreach my $test (@$tests)
  90         {
  91             my $testid = $test->{TestID};
  92
  93             if ($test->{Status} eq "Up" && !$test->{Paused})
  94             {
  95                 $cache->{$testid} = "up";
  96             }
  97             else
  98             {
  99                 $cache->{$testid} = "down";
 100             }
 101         }
 102     }
 103
 104     foreach my $server (@servers)
 105     {
 106         if (my $testids = $server->{statuscake})
 107         {
 108             $server->{status} = "up";
 109
 110             for my $testid (@$testids)
 111             {
 112                 my $testresult = $cache->{$testid} || "down";
 113
 114                 $server->{status} = "down" if $testresult eq "down";
 115             }
 116         }
 117         else
 118         {
 119             $server->{status} = "down";
 120         }
 121     }
 122
 123     DumpFile("statuscake-$$.yml", $cache);
 124     rename("statuscake-$$.yml", "statuscake.yml");
 125 }
 126
 127 # Mark a cluster as up if any servers are up
 128 foreach my $server (@servers)
 129 {
 130     if ($server->{status} eq "up")
 131     {
 132         $server->{cluster}->{status} = "up";
 133     }
 134     else
 135     {
 136         $server->{cluster}->{bandwidth} = $server->{cluster}->{bandwidth} - $server->{bandwidth};
 137     }
 138 }
 139
 140 # Create target origins object
 141 my $targetorigins = {};
 142
 143 # Initialise cluster details
 144 while (my($name,$cluster) = each %$clusters)
 145 {
 146     $cluster->{bandwidth_limit} = $cluster->{bandwidth} * 1024 * 1024;
 147     $cluster->{bandwidth_used} = 0;
 148
 149     $targetorigins->{$cluster->{name}} = {
 150         code => $cluster->{name},
 151         name => $cluster->{name},
 152         lat => $cluster->{lat},
 153         lon => $cluster->{lon},
 154         bandwidth => 0
 155     };
 156 }
 157
 158 my @mappings = ();
 159
 160 # Scan origins and work out which clusters each can use
 161 foreach my $origin (values %$origins)
 162 {
 163     foreach my $cluster (values %$clusters)
 164     {
 165         my $match = match_origin($cluster, $origin);
 166
 167         if ($cluster->{status} eq "up" && $match ne "denied")
 168         {
 169             my $priority = $match eq "preferred" ? 20 : 10;
 170             my $distance;
 171
 172             if ($cluster->{global})
 173             {
 174                 $distance = 0;
 175             }
 176             else
 177             {
 178                 $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 179             }
 180
 181             push @mappings, {
 182                 origin => $origin, cluster => $cluster,
 183                 priority => $priority, distance => $distance
 184             };
 185         }
 186     }
 187 }
 188
 189 # Allocate each country to a cluster
 190 allocate_clusters(@mappings);
 191
 192 # If we failed to allocate every origin then loop, increasing
 193 # the bandwidth for each cluster by a little and retrying until
 194 # we manage to allocate everything
 195 while (grep { !exists($_->{cluster}) } values %$origins)
 196 {
 197     # Clear any existing mappings of countries to clusters
 198     foreach my $origin (values %$origins)
 199     {
 200         delete $origin->{cluster};
 201     }
 202
 203     # Reset bandwidth usage for clusters and increase limits by 10%
 204     foreach my $cluster (values %$clusters)
 205     {
 206         $cluster->{bandwidth_used} = 0;
 207         $cluster->{bandwidth_limit} = $cluster->{bandwidth_limit} * 1.1;
 208     }
 209
 210     # Try the allocate again
 211     allocate_clusters(@mappings);
 212 }
 213
 214 # Create JSON collection object
 215 my @json;
 216
 217 # Open output files
 218 my $zonefile = IO::File->new("> include/${zone}.js") || die "$!";
 219 my $jsonfile = IO::File->new("> json/${zone}.openstreetmap.org.json") || die "$!";
 220
 221 # Output headers
 222 $zonefile->print("var \U${zone}\E_RECORDS = [\n");
 223
 224 # Output details for each country
 225 foreach my $origin (sort { $a->{name} cmp $b->{name} } values %$origins)
 226 {
 227     my $cluster = $origin->{cluster};
 228
 229     if (!defined($gdnsname))
 230     {
 231         $zonefile->print("  CNAME(\"\L$origin->{code}\E.${zone}\", \"$cluster->{name}.${zone}.openstreetmap.org.\", TTL(\"10m\")),\n");
 232     }
 233
 234     if ($cluster->{lon} && $cluster->{lat})
 235     {
 236         my $clon = $origin->{lon};
 237         my $clat = $origin->{lat};
 238         my $slon = $cluster->{lon};
 239         my $slat = $cluster->{lat};
 240
 241         if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 242         {
 243             $slon = $slon + 360;
 244         }
 245         elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 246         {
 247             $clon = $clon + 360;
 248         }
 249
 250         push @json, {
 251             type => "Feature",
 252             geometry => {
 253                 type => "LineString",
 254                 coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 255             },
 256             properties => {
 257                 origin => $origin->{name},
 258                 server => $cluster->{name},
 259                 colour => $cluster->{colour}
 260             }
 261         };
 262     }
 263
 264     $targetorigins->{$cluster->{name}}->{bandwidth} += $origin->{bandwidth};
 265 }
 266
 267 # Skip default records if we don't need them
 268 if (!defined($gdnsname))
 269 {
 270     # Output default records for IPs that can't be mapped to a country
 271     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 272     {
 273         my $name = $cluster->{name};
 274
 275         if (my $default = $cluster->{default})
 276         {
 277             output_server($zonefile, "${default}.${zone}", $cluster, 0);
 278         }
 279         elsif (exists($cluster->{default}))
 280         {
 281             output_server($zonefile, "${zone}", $cluster, 0);
 282         }
 283     }
 284 }
 285
 286 # Output A records for each cluster
 287 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 288 {
 289     my $name = $cluster->{name};
 290
 291     if (@{$cluster->{servers}} > 1)
 292     {
 293         output_server($zonefile, "${name}-%02d.${zone}", $cluster, 1);
 294     }
 295     else
 296     {
 297         output_server($zonefile, "${name}.${zone}", $cluster, 1);
 298     }
 299 }
 300
 301 # Output the GeoJSON text
 302 $jsonfile->print(encode_json(\@json));
 303
 304 # Output footers
 305 $zonefile->print("];\n");
 306
 307 # Close the output files
 308 $zonefile->close();
 309 $zonefile->close();
 310
 311 # Output gdnsd configuration
 312 if (defined($gdnsname))
 313 {
 314     my $gdnsmapfile = IO::File->new("> gdns/${gdnsname}.map") || die "$!";
 315     my $gdnsresourcefile = IO::File->new("> gdns/${gdnsname}.resource") || die "$!";
 316     my $gdnsweightedfile = IO::File->new("> gdns/${gdnsname}.weighted") || die "$!";
 317     my $continent = "";
 318
 319     $gdnsmapfile->print("${gdnsname} => {\n");
 320     $gdnsmapfile->print("  geoip2_db => /usr/share/GeoIP/GeoLite2-Country.mmdb\n");
 321     $gdnsmapfile->print("  datacenters => [" . join(",", sort(keys(%$clusters))) . "]\n");
 322     $gdnsmapfile->print("  map => {\n");
 323     $gdnsmapfile->print("    default => [" . join(",", sort(map { $_->{name} } grep { $_->{default} } values(%$clusters))) . "]\n");
 324
 325     foreach my $origin (sort { $a->{continent} cmp $b->{continent} || $a->{code} cmp $b->{code} } values %$origins)
 326     {
 327         my $code = $origin->{code};
 328         my $cluster = $origin->{cluster}->{name};
 329
 330         next if $code eq "XK";
 331
 332         if ($continent ne $origin->{continent})
 333         {
 334             $gdnsmapfile->print("    }\n") if $continent;
 335
 336             $continent = $origin->{continent};
 337
 338             $gdnsmapfile->print("    ${continent} => {\n");
 339         }
 340
 341         $gdnsmapfile->print("      ${code} => [${cluster}]\n");
 342     }
 343
 344     $gdnsmapfile->print("    }\n") if $continent;
 345
 346     $gdnsmapfile->print("  }\n");
 347     $gdnsmapfile->print("}\n");
 348
 349     $gdnsresourcefile->print("${gdnsname} => {\n");
 350     $gdnsresourcefile->print("  map => ${gdnsname}\n");
 351     $gdnsresourcefile->print("  dcmap => {\n");
 352
 353     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 354     {
 355         my $name = $cluster->{name};
 356
 357         if (@{$cluster->{servers}} > 1 && grep { $_->{status} eq "up" } @{$cluster->{servers}})
 358         {
 359             $gdnsweightedfile->print("${name} => {\n");
 360
 361             while (my($index,$server) = each @{$cluster->{servers}})
 362             {
 363                 if ($server->{status} eq "up")
 364                 {
 365                     my $number = sprintf("%02d", $index + 1);
 366                     my $bandwidth = $server->{bandwidth};
 367
 368                     if (my $cname = $server->{cname})
 369                     {
 370                         $gdnsweightedfile->print("  ${name}-${number} = [ ${cname}., ${bandwidth} ]\n");
 371                     }
 372                     else
 373                     {
 374                         $gdnsweightedfile->print("  ${name}-${number} = [ ${name}-${number}.${zone}.openstreetmap.org., ${bandwidth} ]\n");
 375                     }
 376                 }
 377             }
 378
 379             $gdnsweightedfile->print("}\n");
 380
 381             $gdnsresourcefile->print("    ${name} => %weighted!${name}\n");
 382         }
 383         elsif (my $cname = $cluster->{cname})
 384         {
 385             $gdnsresourcefile->print("    ${name} => ${cname}.\n");
 386         }
 387         else
 388         {
 389             $gdnsresourcefile->print("    ${name} => ${name}.${zone}.openstreetmap.org.\n");
 390         }
 391     }
 392
 393     $gdnsresourcefile->print("  }\n");
 394     $gdnsresourcefile->print("}\n");
 395
 396     $gdnsweightedfile->close();
 397     $gdnsresourcefile->close();
 398     $gdnsmapfile->close();
 399 }
 400
 401 # Output the target details in origin format if required
 402 DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 403
 404 exit 0;
 405
 406 #
 407 # Match an origin against a cluster
 408 #
 409 sub match_origin
 410 {
 411     my $cluster = shift;
 412     my $origin = shift;
 413     my $match;
 414
 415     if ($cluster->{preferred} &&
 416         $cluster->{preferred}->{origins} &&
 417         grep { $_ eq $origin->{name} } @{$cluster->{preferred}->{origins}})
 418     {
 419         $match = "preferred";
 420     }
 421     elsif ($cluster->{allowed} &&
 422            $cluster->{allowed}->{origins} &&
 423            grep { $_ eq $origin->{name} } @{$cluster->{allowed}->{origins}})
 424     {
 425         $match = "allowed";
 426     }
 427     elsif ($cluster->{preferred} &&
 428            $cluster->{preferred}->{countries} &&
 429            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 430     {
 431         $match = "preferred";
 432     }
 433     elsif ($cluster->{allowed} &&
 434            $cluster->{allowed}->{countries} &&
 435            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 436     {
 437         $match = "allowed";
 438     }
 439     elsif ($cluster->{denied} &&
 440            $cluster->{denied}->{countries} &&
 441            grep { $_ eq $origin->{country} } @{$cluster->{denied}->{countries}})
 442     {
 443         $match = "denied";
 444     }
 445     elsif ($cluster->{preferred} &&
 446            $cluster->{preferred}->{continents} &&
 447            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 448     {
 449         $match = "preferred";
 450     }
 451     elsif ($cluster->{allowed} &&
 452            $cluster->{allowed}->{continents} &&
 453            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 454     {
 455         $match = "allowed";
 456     }
 457     elsif ($cluster->{denied} &&
 458            $cluster->{denied}->{continents} &&
 459            grep { $_ eq $origin->{continent} } @{$cluster->{denied}->{continents}})
 460     {
 461         $match = "denied";
 462     }
 463     elsif ($cluster->{allowed})
 464     {
 465         $match = "denied";
 466     }
 467     else
 468     {
 469         $match = "allowed";
 470     }
 471
 472     return $match;
 473 }
 474
 475 #
 476 # Compute the great circle distance between two points
 477 #
 478 sub distance
 479 {
 480     my $lat1 = deg2rad(shift);
 481     my $lon1 = deg2rad(shift);
 482     my $lat2 = deg2rad(shift);
 483     my $lon2 = deg2rad(shift);
 484
 485     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 486 }
 487
 488 #
 489 # Allocate each origin to a cluster
 490 #
 491 sub allocate_clusters
 492 {
 493     my @mappings = sort { compare_mappings($a, $b) } @_;
 494
 495     # Loop over the mappings, trying to assign each origin to the
 496     # nearest cluster, but subject to the bandwidth limits
 497     while (my $mapping = shift @mappings)
 498     {
 499         my @group;
 500
 501         push @group, $mapping;
 502
 503         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 504         {
 505             push @group, shift @mappings;
 506         }
 507
 508         for my $mapping (sort compare_bandwidth @group)
 509         {
 510             my $origin = $mapping->{origin};
 511             my $cluster = $mapping->{cluster};
 512
 513             if (!exists($origin->{cluster}) &&
 514                 $cluster->{bandwidth_used} + $origin->{bandwidth} <= $cluster->{bandwidth_limit})
 515             {
 516                 $origin->{cluster} = $cluster;
 517                 $cluster->{bandwidth_used} = $cluster->{bandwidth_used} + $origin->{bandwidth};
 518             }
 519         }
 520     }
 521
 522     return;
 523 }
 524
 525 #
 526 # Compare two mappings to decide which to use
 527 #
 528 sub compare_mappings
 529 {
 530     my $a = shift;
 531     my $b = shift;
 532
 533     return $b->{priority} <=> $a->{priority} ||
 534            $a->{distance} <=> $b->{distance};
 535 }
 536
 537 #
 538 # Compare two mappings to decide which to try first
 539 #
 540 sub compare_bandwidth
 541 {
 542     my $a_used = ( $a->{cluster}->{bandwidth_used} * 100.0 ) / ( $a->{cluster}->{bandwidth_limit} * 1.0 );
 543     my $b_used = ( $b->{cluster}->{bandwidth_used} * 100.0 ) / ( $b->{cluster}->{bandwidth_limit} * 1.0 );
 544
 545     return $a_used <=> $b_used;
 546 }
 547
 548 #
 549 # Output DNS records for a server
 550 #
 551 sub output_server
 552 {
 553     my $zonefile = shift;
 554     my $name = shift;
 555     my $cluster = shift;
 556     my $all = shift;
 557
 558     while (my($index,$server) = each @{$cluster->{servers}})
 559     {
 560         if ($all || $server->{status} eq "up")
 561         {
 562             if ($server->{ipv4})
 563             {
 564                 $zonefile->printf("  A(\"${name}\", \"$server->{ipv4}\", TTL(\"10m\")),\n", $index + 1);
 565             }
 566
 567             if ($server->{ipv6})
 568             {
 569                 $zonefile->printf("  AAAA(\"${name}\", \"$server->{ipv6}\", TTL(\"10m\")),\n", $index + 1);
 570             }
 571         }
 572     }
 573
 574     return;
 575 }