bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use v5.12;
   4
   5 use strict;
   6 use warnings;
   7
   8 use IO::File;
   9 use Math::Trig qw(deg2rad pip2 great_circle_distance);
  10 use JSON::XS;
  11 use LWP::UserAgent;
  12 use YAML;
  13
  14 my $originfile = shift @ARGV;
  15 my $clusterfile = shift @ARGV;
  16 my $zone = shift @ARGV;
  17 my $targetoriginfile = shift @ARGV;
  18 my $origins = YAML::LoadFile($originfile);
  19 my $clusters = YAML::LoadFile($clusterfile);
  20 my $gdnsname = shift @ARGV;
  21 my @servers;
  22
  23 # Initialise cluster details
  24 while (my($name,$cluster) = each %$clusters)
  25 {
  26     if ($cluster->{servers})
  27     {
  28         $cluster->{bandwidth} = 0;
  29
  30         foreach my $server (@{$cluster->{servers}})
  31         {
  32             $server->{cluster} = $cluster;
  33             $cluster->{bandwidth} = $cluster->{bandwidth} + $server->{bandwidth};
  34
  35             push @servers, $server;
  36         }
  37     }
  38     else
  39     {
  40         my $server = {
  41             cluster => $cluster,
  42             statuscake => $cluster->{statuscake},
  43             bandwidth => $cluster->{bandwidth},
  44             ipv4 => $cluster->{ipv4},
  45             ipv6 => $cluster->{ipv6}
  46         };
  47
  48         $cluster->{servers} = [ $server ];
  49
  50         push @servers, $server;
  51     }
  52
  53     $cluster->{name} = $name;
  54     $cluster->{status} = "down";
  55 }
  56
  57 # Initialise server details
  58 foreach my $server (@servers)
  59 {
  60     $server->{status} = "up";
  61 }
  62
  63 # If statuscake support is enabled then check which servers are up
  64 if ($ENV{STATUSCAKE_USERNAME} && $ENV{STATUSCAKE_APIKEY})
  65 {
  66     my $ua = LWP::UserAgent->new;
  67     my $cache;
  68
  69     $ua->agent("mkgeo/1.0");
  70     $ua->default_header("Username", $ENV{STATUSCAKE_USERNAME});
  71     $ua->default_header("API", $ENV{STATUSCAKE_APIKEY});
  72
  73     if (-f "statuscake.yml")
  74     {
  75         $cache = YAML::LoadFile("statuscake.yml");
  76     }
  77     else
  78     {
  79         $cache = {};
  80     }
  81
  82     my $response = $ua->get("https://app.statuscake.com/API/Tests/");
  83
  84     if ($response->is_success)
  85     {
  86         my $tests = decode_json($response->content);
  87
  88         foreach my $test (@$tests)
  89         {
  90             my $testid = $test->{TestID};
  91
  92             if ($test->{Status} eq "Up" && !$test->{Paused})
  93             {
  94                 $cache->{$testid} = "up";
  95             }
  96             else
  97             {
  98                 $cache->{$testid} = "down";
  99             }
 100         }
 101     }
 102
 103     foreach my $server (@servers)
 104     {
 105         if (my $testids = $server->{statuscake})
 106         {
 107             $server->{status} = "up";
 108
 109             for my $testid (@$testids)
 110             {
 111                 my $testresult = $cache->{$testid} || "down";
 112
 113                 $server->{status} = "down" if $testresult eq "down";
 114             }
 115         }
 116         else
 117         {
 118             $server->{status} = "down";
 119         }
 120     }
 121
 122     YAML::DumpFile("statuscake.yml", $cache);
 123 }
 124
 125 # Mark a cluster as up if any servers are up
 126 foreach my $server (@servers)
 127 {
 128     if ($server->{status} eq "up")
 129     {
 130         $server->{cluster}->{status} = "up";
 131     }
 132     else
 133     {
 134         $server->{cluster}->{bandwidth} = $server->{cluster}->{bandwidth} - $server->{bandwidth};
 135     }
 136 }
 137
 138 # Create target origins object
 139 my $targetorigins = {};
 140
 141 # Initialise cluster details
 142 while (my($name,$cluster) = each %$clusters)
 143 {
 144     $cluster->{bandwidth_limit} = $cluster->{bandwidth} * 1024 * 1024;
 145     $cluster->{bandwidth_used} = 0;
 146
 147     $targetorigins->{$cluster->{name}} = {
 148         code => $cluster->{name},
 149         name => $cluster->{name},
 150         lat => $cluster->{lat},
 151         lon => $cluster->{lon},
 152         bandwidth => 0
 153     };
 154 }
 155
 156 my @mappings = ();
 157
 158 # Scan origins and work out which clusters each can use
 159 foreach my $origin (values %$origins)
 160 {
 161     foreach my $cluster (values %$clusters)
 162     {
 163         my $match = match_origin($cluster, $origin);
 164
 165         if ($cluster->{status} eq "up" && $match ne "denied")
 166         {
 167             my $priority = $match eq "preferred" ? 20 : 10;
 168             my $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 169
 170             push @mappings, {
 171                 origin => $origin, cluster => $cluster,
 172                 priority => $priority, distance => $distance
 173             };
 174         }
 175     }
 176 }
 177
 178 # Allocate each country to a cluster
 179 allocate_clusters(@mappings);
 180
 181 # If we failed to allocate every origin then loop, increasing
 182 # the bandwidth for each cluster by a little and retrying until
 183 # we manage to allocate everything
 184 while (grep { !exists($_->{cluster}) } values %$origins)
 185 {
 186     # Clear any existing mappings of countries to clusters
 187     foreach my $origin (values %$origins)
 188     {
 189         delete $origin->{cluster};
 190     }
 191
 192     # Reset bandwidth usage for clusters and increase limits by 10%
 193     foreach my $cluster (values %$clusters)
 194     {
 195         $cluster->{bandwidth_used} = 0;
 196         $cluster->{bandwidth_limit} = $cluster->{bandwidth_limit} * 1.1;
 197     }
 198
 199     # Try the allocate again
 200     allocate_clusters(@mappings);
 201 }
 202
 203 # Create JSON collection object
 204 my @json;
 205
 206 # Open output files
 207 my $zonefile = IO::File->new("> data/${zone}") || die "$!";
 208 my $jsonfile = IO::File->new("> json/${zone}.json") || die "$!";
 209
 210 # Output details for each country
 211 foreach my $origin (sort { $a->{name} cmp $b->{name} } values %$origins)
 212 {
 213     my $cluster = $origin->{cluster};
 214     my $clon = $origin->{lon};
 215     my $clat = $origin->{lat};
 216     my $slon = $cluster->{lon};
 217     my $slat = $cluster->{lat};
 218
 219     if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 220     {
 221         $slon = $slon + 360;
 222     }
 223     elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 224     {
 225         $clon = $clon + 360;
 226     }
 227
 228     $zonefile->print("# $origin->{name}\n");
 229     $zonefile->print("C\L$origin->{code}\E.${zone}:$cluster->{name}.${zone}:600\n");
 230
 231     push @json, {
 232         type => "Feature",
 233         geometry => {
 234             type => "LineString",
 235             coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 236         },
 237         properties => {
 238             origin => $origin->{name},
 239             server => $cluster->{name},
 240             colour => $cluster->{colour}
 241         }
 242     };
 243
 244     $targetorigins->{$cluster->{name}}->{bandwidth} += $origin->{bandwidth};
 245 }
 246
 247 # Header for default records
 248 $zonefile->print("# Unknown origins\n");
 249
 250 # Output default records for IPs that can't be mapped to a country
 251 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 252 {
 253     my $name = $cluster->{name};
 254
 255     if (my $default = $cluster->{default})
 256     {
 257         output_server($zonefile, "${default}.${zone}", $cluster);
 258     }
 259     elsif (exists($cluster->{default}))
 260     {
 261         output_server($zonefile, "${zone}", $cluster);
 262     }
 263 }
 264
 265 # Header for underlying servers
 266 $zonefile->print("# Servers\n");
 267
 268 # Output A records for each cluster
 269 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 270 {
 271     my $name = $cluster->{name};
 272
 273     output_server($zonefile, "${name}.${zone}", $cluster);
 274
 275     if (@{$cluster->{servers}} > 1)
 276     {
 277         output_server($zonefile, "${name}-%02d.${zone}", $cluster);
 278     }
 279 }
 280
 281 # Output the GeoJSON text
 282 $jsonfile->print(encode_json(\@json));
 283
 284 # Close the output files
 285 $jsonfile->close();
 286 $zonefile->close();
 287
 288 # Output gdnsd configuration
 289 if (defined($gdnsname))
 290 {
 291     my $gdnsmapfile = IO::File->new("> gdns/${gdnsname}.map") || die "$!";
 292     my $gdnsresourcefile = IO::File->new("> gdns/${gdnsname}.resource") || die "$!";
 293     my $gdnsweightedfile = IO::File->new("> gdns/${gdnsname}.weighted") || die "$!";
 294     my $continent = "";
 295
 296     $gdnsmapfile->print("${gdnsname} => {\n");
 297     $gdnsmapfile->print("  geoip2_db => /usr/share/GeoIP/GeoLite2-Country.mmdb\n");
 298     $gdnsmapfile->print("  datacenters => [" . join(",", sort(keys(%$clusters))) . "]\n");
 299     $gdnsmapfile->print("  map => {\n");
 300     $gdnsmapfile->print("    default => [" . join(",", sort(map { $_->{name} } grep { $_->{default} } values(%$clusters))) . "]\n");
 301
 302     foreach my $origin (sort { $a->{continent} cmp $b->{continent} || $a->{code} cmp $b->{code} } values %$origins)
 303     {
 304         my $code = $origin->{code};
 305         my $cluster = $origin->{cluster}->{name};
 306
 307         next if $code eq "XK";
 308
 309         if ($continent ne $origin->{continent})
 310         {
 311             $gdnsmapfile->print("    }\n") if $continent;
 312
 313             $continent = $origin->{continent};
 314
 315             $gdnsmapfile->print("    ${continent} => {\n");
 316         }
 317
 318         $gdnsmapfile->print("      ${code} => [${cluster}]\n");
 319     }
 320
 321     $gdnsmapfile->print("    }\n") if $continent;
 322
 323     $gdnsmapfile->print("  }\n");
 324     $gdnsmapfile->print("}\n");
 325
 326     $gdnsresourcefile->print("${gdnsname} => {\n");
 327     $gdnsresourcefile->print("  map => ${gdnsname}\n");
 328     $gdnsresourcefile->print("  dcmap => {\n");
 329
 330     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 331     {
 332         my $name = $cluster->{name};
 333
 334         if (@{$cluster->{servers}} > 1)
 335         {
 336             $gdnsweightedfile->print("${name} => {\n");
 337
 338             while (my($index,$server) = each @{$cluster->{servers}})
 339             {
 340                 if ($server->{status} eq "up")
 341                 {
 342                     my $number = sprintf("%02d", $index + 1);
 343                     my $bandwidth = $server->{bandwidth};
 344
 345                     $gdnsweightedfile->print("  ${name}-${number} = [ ${name}-${number}.${zone}., ${bandwidth} ]\n");
 346                 }
 347             }
 348
 349             $gdnsweightedfile->print("}\n");
 350
 351             $gdnsresourcefile->print("    ${name} => %weighted!${name}\n");
 352         }
 353         else
 354         {
 355             $gdnsresourcefile->print("    ${name} => ${name}.${zone}.\n");
 356         }
 357     }
 358
 359     $gdnsresourcefile->print("  }\n");
 360     $gdnsresourcefile->print("}\n");
 361
 362     $gdnsweightedfile->close();
 363     $gdnsresourcefile->close();
 364     $gdnsmapfile->close();
 365 }
 366
 367 # Output the target details in origin format if required
 368 YAML::DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 369
 370 exit 0;
 371
 372 #
 373 # Match an origin against a cluster
 374 #
 375 sub match_origin
 376 {
 377     my $cluster = shift;
 378     my $origin = shift;
 379     my $match;
 380
 381     if ($cluster->{preferred} &&
 382         $cluster->{preferred}->{origins} &&
 383         grep { $_ eq $origin->{name} } @{$cluster->{preferred}->{origins}})
 384     {
 385         $match = "preferred";
 386     }
 387     elsif ($cluster->{allowed} &&
 388            $cluster->{allowed}->{origins} &&
 389            grep { $_ eq $origin->{name} } @{$cluster->{allowed}->{origins}})
 390     {
 391         $match = "allowed";
 392     }
 393     elsif ($cluster->{preferred} &&
 394            $cluster->{preferred}->{countries} &&
 395            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 396     {
 397         $match = "preferred";
 398     }
 399     elsif ($cluster->{allowed} &&
 400            $cluster->{allowed}->{countries} &&
 401            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 402     {
 403         $match = "allowed";
 404     }
 405     elsif ($cluster->{denied} &&
 406            $cluster->{denied}->{countries} &&
 407            grep { $_ eq $origin->{country} } @{$cluster->{denied}->{countries}})
 408     {
 409         $match = "denied";
 410     }
 411     elsif ($cluster->{preferred} &&
 412            $cluster->{preferred}->{continents} &&
 413            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 414     {
 415         $match = "preferred";
 416     }
 417     elsif ($cluster->{allowed} &&
 418            $cluster->{allowed}->{continents} &&
 419            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 420     {
 421         $match = "allowed";
 422     }
 423     elsif ($cluster->{denied} &&
 424            $cluster->{denied}->{continents} &&
 425            grep { $_ eq $origin->{continent} } @{$cluster->{denied}->{continents}})
 426     {
 427         $match = "denied";
 428     }
 429     elsif ($cluster->{allowed})
 430     {
 431         $match = "denied";
 432     }
 433     else
 434     {
 435         $match = "allowed";
 436     }
 437
 438     return $match;
 439 }
 440
 441 #
 442 # Compute the great circle distance between two points
 443 #
 444 sub distance
 445 {
 446     my $lat1 = deg2rad(shift);
 447     my $lon1 = deg2rad(shift);
 448     my $lat2 = deg2rad(shift);
 449     my $lon2 = deg2rad(shift);
 450
 451     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 452 }
 453
 454 #
 455 # Allocate each origin to a cluster
 456 #
 457 sub allocate_clusters
 458 {
 459     my @mappings = sort { compare_mappings($a, $b) } @_;
 460
 461     # Loop over the mappings, trying to assign each origin to the
 462     # nearest cluster, but subject to the bandwidth limits
 463     while (my $mapping = shift @mappings)
 464     {
 465         my @group;
 466
 467         push @group, $mapping;
 468
 469         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 470         {
 471             push @group, shift @mappings;
 472         }
 473
 474         for my $mapping (sort compare_bandwidth @group)
 475         {
 476             my $origin = $mapping->{origin};
 477             my $cluster = $mapping->{cluster};
 478
 479             if (!exists($origin->{cluster}) &&
 480                 $cluster->{bandwidth_used} + $origin->{bandwidth} <= $cluster->{bandwidth_limit})
 481             {
 482                 $origin->{cluster} = $cluster;
 483                 $cluster->{bandwidth_used} = $cluster->{bandwidth_used} + $origin->{bandwidth};
 484             }
 485         }
 486     }
 487
 488     return;
 489 }
 490
 491 #
 492 # Compare two mappings to decide which to use
 493 #
 494 sub compare_mappings
 495 {
 496     my $a = shift;
 497     my $b = shift;
 498
 499     return $b->{priority} <=> $a->{priority} ||
 500            $a->{distance} <=> $b->{distance};
 501 }
 502
 503 #
 504 # Compare two mappings to decide which to try first
 505 #
 506 sub compare_bandwidth
 507 {
 508     my $a_used = ( $a->{cluster}->{bandwidth_used} * 100.0 ) / ( $a->{cluster}->{bandwidth_limit} * 1.0 );
 509     my $b_used = ( $b->{cluster}->{bandwidth_used} * 100.0 ) / ( $b->{cluster}->{bandwidth_limit} * 1.0 );
 510
 511     return $a_used <=> $b_used;
 512 }
 513
 514 #
 515 # Output DNS records for a server
 516 #
 517 sub output_server
 518 {
 519     my $zonefile = shift;
 520     my $name = shift;
 521     my $cluster = shift;
 522
 523     while (my($index,$server) = each @{$cluster->{servers}})
 524     {
 525         if ($server->{status} eq "up")
 526         {
 527             $zonefile->printf("+${name}:$server->{ipv4}:600\n", $index + 1);
 528
 529             if ($server->{ipv6})
 530             {
 531                 $zonefile->printf("3${name}:$server->{ipv6}:600\n", $index + 1);
 532             }
 533         }
 534     }
 535
 536     return;
 537 }