bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use v5.12;
   4
   5 use strict;
   6 use warnings;
   7
   8 use IO::File;
   9 use Math::Trig qw(deg2rad pip2 great_circle_distance);
  10 use JSON::XS;
  11 use LWP::UserAgent;
  12 use YAML::XS qw(LoadFile DumpFile);
  13
  14 my $originfile = shift @ARGV;
  15 my $clusterfile = shift @ARGV;
  16 my $zone = shift @ARGV;
  17 my $targetoriginfile = shift @ARGV;
  18 my $origins = LoadFile($originfile);
  19 my $clusters = LoadFile($clusterfile);
  20 my $gdnsname = shift @ARGV;
  21 my @servers;
  22
  23 # Initialise cluster details
  24 while (my($name,$cluster) = each %$clusters)
  25 {
  26     if ($cluster->{servers})
  27     {
  28         $cluster->{bandwidth} = 0;
  29
  30         foreach my $server (@{$cluster->{servers}})
  31         {
  32             $server->{cluster} = $cluster;
  33             $cluster->{bandwidth} = $cluster->{bandwidth} + $server->{bandwidth};
  34
  35             push @servers, $server;
  36         }
  37     }
  38     else
  39     {
  40         my $server = {
  41             cluster => $cluster,
  42             statuscake => $cluster->{statuscake},
  43             bandwidth => $cluster->{bandwidth},
  44             ipv4 => $cluster->{ipv4},
  45             ipv6 => $cluster->{ipv6}
  46         };
  47
  48         $cluster->{servers} = [ $server ];
  49
  50         push @servers, $server;
  51     }
  52
  53     $cluster->{name} = $name;
  54     $cluster->{status} = "down";
  55 }
  56
  57 # Initialise server details
  58 foreach my $server (@servers)
  59 {
  60     $server->{status} = "up";
  61 }
  62
  63 # If statuscake support is enabled then check which servers are up
  64 if ($ENV{STATUSCAKE_USERNAME} && $ENV{STATUSCAKE_APIKEY})
  65 {
  66     my $ua = LWP::UserAgent->new;
  67     my $cache;
  68
  69     $ua->agent("mkgeo/1.0");
  70     $ua->default_header("Username", $ENV{STATUSCAKE_USERNAME});
  71     $ua->default_header("API", $ENV{STATUSCAKE_APIKEY});
  72
  73     if (-f "statuscake.yml")
  74     {
  75         $cache = LoadFile("statuscake.yml");
  76     }
  77     else
  78     {
  79         $cache = {};
  80     }
  81
  82     my $response = $ua->get("https://app.statuscake.com/API/Tests/");
  83
  84     if ($response->is_success)
  85     {
  86         my $tests = decode_json($response->content);
  87
  88         foreach my $test (@$tests)
  89         {
  90             my $testid = $test->{TestID};
  91
  92             if ($test->{Status} eq "Up" && !$test->{Paused})
  93             {
  94                 $cache->{$testid} = "up";
  95             }
  96             else
  97             {
  98                 $cache->{$testid} = "down";
  99             }
 100         }
 101     }
 102
 103     foreach my $server (@servers)
 104     {
 105         if (my $testids = $server->{statuscake})
 106         {
 107             $server->{status} = "up";
 108
 109             for my $testid (@$testids)
 110             {
 111                 my $testresult = $cache->{$testid} || "down";
 112
 113                 $server->{status} = "down" if $testresult eq "down";
 114             }
 115         }
 116         else
 117         {
 118             $server->{status} = "down";
 119         }
 120     }
 121
 122     DumpFile("statuscake-$$.yml", $cache);
 123     rename("statuscake-$$.yml", "statuscake.yml");
 124 }
 125
 126 # Mark a cluster as up if any servers are up
 127 foreach my $server (@servers)
 128 {
 129     if ($server->{status} eq "up")
 130     {
 131         $server->{cluster}->{status} = "up";
 132     }
 133     else
 134     {
 135         $server->{cluster}->{bandwidth} = $server->{cluster}->{bandwidth} - $server->{bandwidth};
 136     }
 137 }
 138
 139 # Create target origins object
 140 my $targetorigins = {};
 141
 142 # Initialise cluster details
 143 while (my($name,$cluster) = each %$clusters)
 144 {
 145     $cluster->{bandwidth_limit} = $cluster->{bandwidth} * 1024 * 1024;
 146     $cluster->{bandwidth_used} = 0;
 147
 148     $targetorigins->{$cluster->{name}} = {
 149         code => $cluster->{name},
 150         name => $cluster->{name},
 151         lat => $cluster->{lat},
 152         lon => $cluster->{lon},
 153         bandwidth => 0
 154     };
 155 }
 156
 157 my @mappings = ();
 158
 159 # Scan origins and work out which clusters each can use
 160 foreach my $origin (values %$origins)
 161 {
 162     foreach my $cluster (values %$clusters)
 163     {
 164         my $match = match_origin($cluster, $origin);
 165
 166         if ($cluster->{status} eq "up" && $match ne "denied")
 167         {
 168             my $priority = $match eq "preferred" ? 20 : 10;
 169             my $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 170
 171             push @mappings, {
 172                 origin => $origin, cluster => $cluster,
 173                 priority => $priority, distance => $distance
 174             };
 175         }
 176     }
 177 }
 178
 179 # Allocate each country to a cluster
 180 allocate_clusters(@mappings);
 181
 182 # If we failed to allocate every origin then loop, increasing
 183 # the bandwidth for each cluster by a little and retrying until
 184 # we manage to allocate everything
 185 while (grep { !exists($_->{cluster}) } values %$origins)
 186 {
 187     # Clear any existing mappings of countries to clusters
 188     foreach my $origin (values %$origins)
 189     {
 190         delete $origin->{cluster};
 191     }
 192
 193     # Reset bandwidth usage for clusters and increase limits by 10%
 194     foreach my $cluster (values %$clusters)
 195     {
 196         $cluster->{bandwidth_used} = 0;
 197         $cluster->{bandwidth_limit} = $cluster->{bandwidth_limit} * 1.1;
 198     }
 199
 200     # Try the allocate again
 201     allocate_clusters(@mappings);
 202 }
 203
 204 # Create JSON collection object
 205 my @json;
 206
 207 # Open output files
 208 my $zonefile = IO::File->new("> include/${zone}.js") || die "$!";
 209 my $jsonfile = IO::File->new("> json/${zone}.openstreetmap.org.json") || die "$!";
 210
 211 # Output headers
 212 $zonefile->print("var \U${zone}\E_RECORDS = [\n");
 213
 214 # Output details for each country
 215 foreach my $origin (sort { $a->{name} cmp $b->{name} } values %$origins)
 216 {
 217     my $cluster = $origin->{cluster};
 218     my $clon = $origin->{lon};
 219     my $clat = $origin->{lat};
 220     my $slon = $cluster->{lon};
 221     my $slat = $cluster->{lat};
 222
 223     if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 224     {
 225         $slon = $slon + 360;
 226     }
 227     elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 228     {
 229         $clon = $clon + 360;
 230     }
 231
 232     if (!defined($gdnsname))
 233     {
 234         $zonefile->print("  CNAME(\"\L$origin->{code}\E.${zone}\", \"$cluster->{name}.${zone}.openstreetmap.org.\", TTL(\"10m\")),\n");
 235     }
 236
 237     push @json, {
 238         type => "Feature",
 239         geometry => {
 240             type => "LineString",
 241             coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 242         },
 243         properties => {
 244             origin => $origin->{name},
 245             server => $cluster->{name},
 246             colour => $cluster->{colour}
 247         }
 248     };
 249
 250     $targetorigins->{$cluster->{name}}->{bandwidth} += $origin->{bandwidth};
 251 }
 252
 253 # Skip default records if we don't need them
 254 if (!defined($gdnsname))
 255 {
 256     # Output default records for IPs that can't be mapped to a country
 257     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 258     {
 259         my $name = $cluster->{name};
 260
 261         if (my $default = $cluster->{default})
 262         {
 263             output_server($zonefile, "${default}.${zone}", $cluster, 0);
 264         }
 265         elsif (exists($cluster->{default}))
 266         {
 267             output_server($zonefile, "${zone}", $cluster, 0);
 268         }
 269     }
 270 }
 271
 272 # Output A records for each cluster
 273 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 274 {
 275     my $name = $cluster->{name};
 276
 277     if (@{$cluster->{servers}} > 1)
 278     {
 279         output_server($zonefile, "${name}-%02d.${zone}", $cluster, 1);
 280     }
 281     else
 282     {
 283         output_server($zonefile, "${name}.${zone}", $cluster, 1);
 284     }
 285 }
 286
 287 # Output the GeoJSON text
 288 $jsonfile->print(encode_json(\@json));
 289
 290 # Output footers
 291 $zonefile->print("];\n");
 292
 293 # Close the output files
 294 $zonefile->close();
 295 $zonefile->close();
 296
 297 # Output gdnsd configuration
 298 if (defined($gdnsname))
 299 {
 300     my $gdnsmapfile = IO::File->new("> gdns/${gdnsname}.map") || die "$!";
 301     my $gdnsresourcefile = IO::File->new("> gdns/${gdnsname}.resource") || die "$!";
 302     my $gdnsweightedfile = IO::File->new("> gdns/${gdnsname}.weighted") || die "$!";
 303     my $continent = "";
 304
 305     $gdnsmapfile->print("${gdnsname} => {\n");
 306     $gdnsmapfile->print("  geoip2_db => /usr/share/GeoIP/GeoLite2-Country.mmdb\n");
 307     $gdnsmapfile->print("  datacenters => [" . join(",", sort(keys(%$clusters))) . "]\n");
 308     $gdnsmapfile->print("  map => {\n");
 309     $gdnsmapfile->print("    default => [" . join(",", sort(map { $_->{name} } grep { $_->{default} } values(%$clusters))) . "]\n");
 310
 311     foreach my $origin (sort { $a->{continent} cmp $b->{continent} || $a->{code} cmp $b->{code} } values %$origins)
 312     {
 313         my $code = $origin->{code};
 314         my $cluster = $origin->{cluster}->{name};
 315
 316         next if $code eq "XK";
 317
 318         if ($continent ne $origin->{continent})
 319         {
 320             $gdnsmapfile->print("    }\n") if $continent;
 321
 322             $continent = $origin->{continent};
 323
 324             $gdnsmapfile->print("    ${continent} => {\n");
 325         }
 326
 327         $gdnsmapfile->print("      ${code} => [${cluster}]\n");
 328     }
 329
 330     $gdnsmapfile->print("    }\n") if $continent;
 331
 332     $gdnsmapfile->print("  }\n");
 333     $gdnsmapfile->print("}\n");
 334
 335     $gdnsresourcefile->print("${gdnsname} => {\n");
 336     $gdnsresourcefile->print("  map => ${gdnsname}\n");
 337     $gdnsresourcefile->print("  dcmap => {\n");
 338
 339     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 340     {
 341         my $name = $cluster->{name};
 342
 343         if (@{$cluster->{servers}} > 1 && grep { $_->{status} eq "up" } @{$cluster->{servers}})
 344         {
 345             $gdnsweightedfile->print("${name} => {\n");
 346
 347             while (my($index,$server) = each @{$cluster->{servers}})
 348             {
 349                 if ($server->{status} eq "up")
 350                 {
 351                     my $number = sprintf("%02d", $index + 1);
 352                     my $bandwidth = $server->{bandwidth};
 353
 354                     $gdnsweightedfile->print("  ${name}-${number} = [ ${name}-${number}.${zone}.openstreetmap.org., ${bandwidth} ]\n");
 355                 }
 356             }
 357
 358             $gdnsweightedfile->print("}\n");
 359
 360             $gdnsresourcefile->print("    ${name} => %weighted!${name}\n");
 361         }
 362         else
 363         {
 364             $gdnsresourcefile->print("    ${name} => ${name}.${zone}.openstreetmap.org.\n");
 365         }
 366     }
 367
 368     $gdnsresourcefile->print("  }\n");
 369     $gdnsresourcefile->print("}\n");
 370
 371     $gdnsweightedfile->close();
 372     $gdnsresourcefile->close();
 373     $gdnsmapfile->close();
 374 }
 375
 376 # Output the target details in origin format if required
 377 DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 378
 379 exit 0;
 380
 381 #
 382 # Match an origin against a cluster
 383 #
 384 sub match_origin
 385 {
 386     my $cluster = shift;
 387     my $origin = shift;
 388     my $match;
 389
 390     if ($cluster->{preferred} &&
 391         $cluster->{preferred}->{origins} &&
 392         grep { $_ eq $origin->{name} } @{$cluster->{preferred}->{origins}})
 393     {
 394         $match = "preferred";
 395     }
 396     elsif ($cluster->{allowed} &&
 397            $cluster->{allowed}->{origins} &&
 398            grep { $_ eq $origin->{name} } @{$cluster->{allowed}->{origins}})
 399     {
 400         $match = "allowed";
 401     }
 402     elsif ($cluster->{preferred} &&
 403            $cluster->{preferred}->{countries} &&
 404            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 405     {
 406         $match = "preferred";
 407     }
 408     elsif ($cluster->{allowed} &&
 409            $cluster->{allowed}->{countries} &&
 410            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 411     {
 412         $match = "allowed";
 413     }
 414     elsif ($cluster->{denied} &&
 415            $cluster->{denied}->{countries} &&
 416            grep { $_ eq $origin->{country} } @{$cluster->{denied}->{countries}})
 417     {
 418         $match = "denied";
 419     }
 420     elsif ($cluster->{preferred} &&
 421            $cluster->{preferred}->{continents} &&
 422            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 423     {
 424         $match = "preferred";
 425     }
 426     elsif ($cluster->{allowed} &&
 427            $cluster->{allowed}->{continents} &&
 428            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 429     {
 430         $match = "allowed";
 431     }
 432     elsif ($cluster->{denied} &&
 433            $cluster->{denied}->{continents} &&
 434            grep { $_ eq $origin->{continent} } @{$cluster->{denied}->{continents}})
 435     {
 436         $match = "denied";
 437     }
 438     elsif ($cluster->{allowed})
 439     {
 440         $match = "denied";
 441     }
 442     else
 443     {
 444         $match = "allowed";
 445     }
 446
 447     return $match;
 448 }
 449
 450 #
 451 # Compute the great circle distance between two points
 452 #
 453 sub distance
 454 {
 455     my $lat1 = deg2rad(shift);
 456     my $lon1 = deg2rad(shift);
 457     my $lat2 = deg2rad(shift);
 458     my $lon2 = deg2rad(shift);
 459
 460     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 461 }
 462
 463 #
 464 # Allocate each origin to a cluster
 465 #
 466 sub allocate_clusters
 467 {
 468     my @mappings = sort { compare_mappings($a, $b) } @_;
 469
 470     # Loop over the mappings, trying to assign each origin to the
 471     # nearest cluster, but subject to the bandwidth limits
 472     while (my $mapping = shift @mappings)
 473     {
 474         my @group;
 475
 476         push @group, $mapping;
 477
 478         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 479         {
 480             push @group, shift @mappings;
 481         }
 482
 483         for my $mapping (sort compare_bandwidth @group)
 484         {
 485             my $origin = $mapping->{origin};
 486             my $cluster = $mapping->{cluster};
 487
 488             if (!exists($origin->{cluster}) &&
 489                 $cluster->{bandwidth_used} + $origin->{bandwidth} <= $cluster->{bandwidth_limit})
 490             {
 491                 $origin->{cluster} = $cluster;
 492                 $cluster->{bandwidth_used} = $cluster->{bandwidth_used} + $origin->{bandwidth};
 493             }
 494         }
 495     }
 496
 497     return;
 498 }
 499
 500 #
 501 # Compare two mappings to decide which to use
 502 #
 503 sub compare_mappings
 504 {
 505     my $a = shift;
 506     my $b = shift;
 507
 508     return $b->{priority} <=> $a->{priority} ||
 509            $a->{distance} <=> $b->{distance};
 510 }
 511
 512 #
 513 # Compare two mappings to decide which to try first
 514 #
 515 sub compare_bandwidth
 516 {
 517     my $a_used = ( $a->{cluster}->{bandwidth_used} * 100.0 ) / ( $a->{cluster}->{bandwidth_limit} * 1.0 );
 518     my $b_used = ( $b->{cluster}->{bandwidth_used} * 100.0 ) / ( $b->{cluster}->{bandwidth_limit} * 1.0 );
 519
 520     return $a_used <=> $b_used;
 521 }
 522
 523 #
 524 # Output DNS records for a server
 525 #
 526 sub output_server
 527 {
 528     my $zonefile = shift;
 529     my $name = shift;
 530     my $cluster = shift;
 531     my $all = shift;
 532
 533     while (my($index,$server) = each @{$cluster->{servers}})
 534     {
 535         if ($all || $server->{status} eq "up")
 536         {
 537             $zonefile->printf("  A(\"${name}\", \"$server->{ipv4}\", TTL(\"10m\")),\n", $index + 1);
 538
 539             if ($server->{ipv6})
 540             {
 541                 $zonefile->printf("  AAAA(\"${name}\", \"$server->{ipv6}\", TTL(\"10m\")),\n", $index + 1);
 542             }
 543         }
 544     }
 545
 546     return;
 547 }