bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use v5.12;
   4
   5 use strict;
   6 use warnings;
   7
   8 use IO::File;
   9 use Math::Trig qw(deg2rad pip2 great_circle_distance);
  10 use JSON::XS;
  11 use LWP::UserAgent;
  12 use YAML::XS qw(LoadFile DumpFile);
  13
  14 my $originfile = shift @ARGV;
  15 my $clusterfile = shift @ARGV;
  16 my $zone = shift @ARGV;
  17 my $targetoriginfile = shift @ARGV;
  18 my $origins = LoadFile($originfile);
  19 my $clusters = LoadFile($clusterfile);
  20 my $gdnsname = shift @ARGV;
  21 my @servers;
  22
  23 # Initialise cluster details
  24 while (my($name,$cluster) = each %$clusters)
  25 {
  26     if ($cluster->{servers})
  27     {
  28         $cluster->{requests} = 0;
  29
  30         foreach my $server (@{$cluster->{servers}})
  31         {
  32             $server->{cluster} = $cluster;
  33             $cluster->{requests} = $cluster->{requests} + $server->{requests};
  34
  35             push @servers, $server;
  36         }
  37     }
  38     elsif ($cluster->{requests} > 0)
  39     {
  40         my $server = {
  41             cluster => $cluster,
  42             statuscake => $cluster->{statuscake},
  43             requests => $cluster->{requests},
  44             cname => $cluster->{cname},
  45             ipv4 => $cluster->{ipv4},
  46             ipv6 => $cluster->{ipv6}
  47         };
  48
  49         $cluster->{servers} = [ $server ];
  50
  51         push @servers, $server;
  52     }
  53     else
  54     {
  55         $cluster->{servers} = [];
  56     }
  57
  58     $cluster->{name} = $name;
  59     $cluster->{status} = "down";
  60 }
  61
  62 # Initialise server details
  63 foreach my $server (@servers)
  64 {
  65     $server->{status} = "up";
  66 }
  67
  68 # If statuscake support is enabled then check which servers are up
  69 if ($ENV{STATUSCAKE_APIKEY})
  70 {
  71     my $ua = LWP::UserAgent->new;
  72     my $cache;
  73
  74     $ua->agent("mkgeo/1.0");
  75     $ua->default_header("Authorization", "Bearer $ENV{STATUSCAKE_APIKEY}");
  76
  77     if (-f "statuscake.yml")
  78     {
  79         $cache = LoadFile("statuscake.yml");
  80     }
  81     else
  82     {
  83         $cache = {};
  84     }
  85
  86     my $page = 1;
  87     my $pages = 1;
  88
  89     while ($page <= $pages)
  90     {
  91         my $response = $ua->get("https://api.statuscake.com/v1/uptime?nouptime=true&limit=100&page=${page}");
  92
  93         if ($response->is_success)
  94         {
  95             my $uptime = decode_json($response->content);
  96
  97             foreach my $test (@{$uptime->{data}})
  98             {
  99                 my $testid = $test->{id};
 100
 101                 if ($test->{status} eq "up" && !$test->{paused})
 102                 {
 103                     $cache->{$testid} = "up";
 104                 }
 105                 else
 106                 {
 107                     $cache->{$testid} = "down";
 108                 }
 109             }
 110
 111             $page = $page + 1;
 112             $pages = $uptime->{metadata}->{page_count};
 113         }
 114     }
 115
 116     foreach my $server (@servers)
 117     {
 118         if (my $testids = $server->{statuscake})
 119         {
 120             $server->{status} = "up";
 121
 122             for my $testid (@$testids)
 123             {
 124                 my $testresult = $cache->{$testid} || "down";
 125
 126                 $server->{status} = "down" if $testresult eq "down";
 127             }
 128         }
 129         else
 130         {
 131             $server->{status} = "down";
 132         }
 133     }
 134
 135     DumpFile("statuscake-$$.yml", $cache);
 136     rename("statuscake-$$.yml", "statuscake.yml");
 137 }
 138
 139 # Mark a cluster as up if any servers are up
 140 foreach my $server (@servers)
 141 {
 142     if ($server->{status} eq "up")
 143     {
 144         $server->{cluster}->{status} = "up";
 145     }
 146     else
 147     {
 148         $server->{cluster}->{requests} = $server->{cluster}->{requests} - $server->{requests};
 149     }
 150 }
 151
 152 # Create target origins object
 153 my $targetorigins = {};
 154
 155 # Initialise cluster details
 156 while (my($name,$cluster) = each %$clusters)
 157 {
 158     $cluster->{requests_limit} = $cluster->{requests};
 159     $cluster->{requests_used} = 0;
 160
 161     next if $cluster->{global};
 162
 163     $targetorigins->{$cluster->{name}} = {
 164         code => $cluster->{name},
 165         name => $cluster->{name},
 166         lat => $cluster->{lat},
 167         lon => $cluster->{lon},
 168         requests => 0
 169     };
 170 }
 171
 172 my @mappings = ();
 173
 174 # Scan origins and work out which clusters each can use
 175 foreach my $origin (values %$origins)
 176 {
 177     foreach my $cluster (values %$clusters)
 178     {
 179         my $match = match_origin($cluster, $origin);
 180
 181         if ($cluster->{status} eq "up" && $match ne "denied")
 182         {
 183             my $priority = $match eq "preferred" ? 20 : 10;
 184             my $distance;
 185
 186             if ($cluster->{global})
 187             {
 188                 $distance = 0;
 189             }
 190             else
 191             {
 192                 $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 193             }
 194
 195             push @mappings, {
 196                 origin => $origin, cluster => $cluster,
 197                 priority => $priority, distance => $distance
 198             };
 199         }
 200     }
 201 }
 202
 203 # Allocate each country to a cluster
 204 allocate_clusters(@mappings);
 205
 206 # If we failed to allocate every origin then loop, increasing
 207 # the requests for each cluster by a little and retrying until
 208 # we manage to allocate everything
 209 while (grep { !exists($_->{cluster}) } values %$origins)
 210 {
 211     # Clear any existing mappings of countries to clusters
 212     foreach my $origin (values %$origins)
 213     {
 214         delete $origin->{cluster};
 215     }
 216
 217     # Reset requests usage for clusters and increase limits by 10%
 218     foreach my $cluster (values %$clusters)
 219     {
 220         $cluster->{requests_used} = 0;
 221         $cluster->{requests_limit} = $cluster->{requests_limit} * 1.1;
 222     }
 223
 224     # Try the allocate again
 225     allocate_clusters(@mappings);
 226 }
 227
 228 # Report on allocation results
 229 foreach my $name (sort keys %$clusters)
 230 {
 231     my $cluster = $clusters->{$name};
 232     my $used = int($cluster->{requests_used} + 0.5);
 233     my $limit = $cluster->{requests_limit};
 234
 235     if ($limit > 0)
 236     {
 237         my $proportion = int($used / $limit * 100 + 0.5);
 238
 239         print "${name}: used ${used} of ${limit} (${proportion}%)\n";
 240     }
 241     else
 242     {
 243         print "${name}: used ${used} of ${limit}\n";
 244     }
 245 }
 246
 247 # Create JSON collection object
 248 my @json;
 249
 250 # Open output files
 251 my $zonefile = IO::File->new("> include/${zone}.js") || die "$!";
 252 my $jsonfile = IO::File->new("> json/${zone}.openstreetmap.org.json") || die "$!";
 253
 254 # Output headers
 255 $zonefile->print("var \U${zone}\E_RECORDS = [\n");
 256
 257 # Output details for each country
 258 foreach my $origin (sort { $a->{name} cmp $b->{name} } values %$origins)
 259 {
 260     my $cluster = $origin->{cluster};
 261
 262     if (!defined($gdnsname))
 263     {
 264         $zonefile->print("  CNAME(\"\L$origin->{code}\E.${zone}\", \"$cluster->{name}.${zone}.openstreetmap.org.\", TTL(\"10m\")),\n");
 265     }
 266
 267     if ($cluster->{lon} && $cluster->{lat})
 268     {
 269         my $clon = $origin->{lon};
 270         my $clat = $origin->{lat};
 271         my $slon = $cluster->{lon};
 272         my $slat = $cluster->{lat};
 273
 274         if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 275         {
 276             $slon = $slon + 360;
 277         }
 278         elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 279         {
 280             $clon = $clon + 360;
 281         }
 282
 283         push @json, {
 284             type => "Feature",
 285             geometry => {
 286                 type => "LineString",
 287                 coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 288             },
 289             properties => {
 290                 origin => $origin->{name},
 291                 server => $cluster->{name},
 292                 colour => $cluster->{colour}
 293             }
 294         };
 295     }
 296
 297     next if $cluster->{global};
 298
 299     $targetorigins->{$cluster->{name}}->{requests} += $origin->{requests};
 300 }
 301
 302 # Skip default records if we don't need them
 303 if (!defined($gdnsname))
 304 {
 305     # Output default records for IPs that can't be mapped to a country
 306     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 307     {
 308         my $name = $cluster->{name};
 309
 310         if (my $default = $cluster->{default})
 311         {
 312             output_server($zonefile, "${default}.${zone}", $cluster, 0);
 313         }
 314         elsif (exists($cluster->{default}))
 315         {
 316             output_server($zonefile, "${zone}", $cluster, 0);
 317         }
 318     }
 319 }
 320
 321 # Output A records for each cluster
 322 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 323 {
 324     my $name = $cluster->{name};
 325
 326     if (@{$cluster->{servers}} > 1)
 327     {
 328         output_server($zonefile, "${name}-%02d.${zone}", $cluster, 1);
 329     }
 330     else
 331     {
 332         output_server($zonefile, "${name}.${zone}", $cluster, 1);
 333     }
 334 }
 335
 336 # Output the GeoJSON text
 337 $jsonfile->print(encode_json(\@json));
 338
 339 # Output footers
 340 $zonefile->print("];\n");
 341
 342 # Close the output files
 343 $zonefile->close();
 344 $zonefile->close();
 345
 346 # Output gdnsd configuration
 347 if (defined($gdnsname))
 348 {
 349     my $gdnsmapfile = IO::File->new("> gdns/${gdnsname}.map") || die "$!";
 350     my $gdnsresourcefile = IO::File->new("> gdns/${gdnsname}.resource") || die "$!";
 351     my $gdnsweightedfile = IO::File->new("> gdns/${gdnsname}.weighted") || die "$!";
 352     my $continent = "";
 353
 354     $gdnsmapfile->print("${gdnsname} => {\n");
 355     $gdnsmapfile->print("  geoip2_db => /usr/share/GeoIP/GeoLite2-Country.mmdb\n");
 356     $gdnsmapfile->print("  datacenters => [" . join(",", sort(keys(%$clusters))) . "]\n");
 357     $gdnsmapfile->print("  map => {\n");
 358     $gdnsmapfile->print("    default => [" . join(",", sort(map { $_->{name} } grep { $_->{default} } values(%$clusters))) . "]\n");
 359
 360     foreach my $origin (sort { $a->{continent} cmp $b->{continent} || $a->{code} cmp $b->{code} } values %$origins)
 361     {
 362         my $code = $origin->{code};
 363         my $cluster = $origin->{cluster}->{name};
 364
 365         next if $code eq "XK";
 366
 367         if ($continent ne $origin->{continent})
 368         {
 369             $gdnsmapfile->print("    }\n") if $continent;
 370
 371             $continent = $origin->{continent};
 372
 373             $gdnsmapfile->print("    ${continent} => {\n");
 374         }
 375
 376         $gdnsmapfile->print("      ${code} => [${cluster}]\n");
 377     }
 378
 379     $gdnsmapfile->print("    }\n") if $continent;
 380
 381     $gdnsmapfile->print("  }\n");
 382     $gdnsmapfile->print("}\n");
 383
 384     $gdnsresourcefile->print("${gdnsname} => {\n");
 385     $gdnsresourcefile->print("  map => ${gdnsname}\n");
 386     $gdnsresourcefile->print("  dcmap => {\n");
 387
 388     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 389     {
 390         my $name = $cluster->{name};
 391
 392         if (@{$cluster->{servers}} > 1 && grep { $_->{status} eq "up" } @{$cluster->{servers}})
 393         {
 394             $gdnsweightedfile->print("${name} => {\n");
 395
 396             while (my($index,$server) = each @{$cluster->{servers}})
 397             {
 398                 if ($server->{status} eq "up")
 399                 {
 400                     my $number = sprintf("%02d", $index + 1);
 401                     my $requests = $server->{requests};
 402
 403                     if (my $cname = $server->{cname})
 404                     {
 405                         $gdnsweightedfile->print("  ${name}-${number} = [ ${cname}., ${requests} ]\n");
 406                     }
 407                     else
 408                     {
 409                         $gdnsweightedfile->print("  ${name}-${number} = [ ${name}-${number}.${zone}.openstreetmap.org., ${requests} ]\n");
 410                     }
 411                 }
 412             }
 413
 414             $gdnsweightedfile->print("}\n");
 415
 416             $gdnsresourcefile->print("    ${name} => %weighted!${name}\n");
 417         }
 418         elsif (my $cname = $cluster->{cname})
 419         {
 420             $gdnsresourcefile->print("    ${name} => ${cname}.\n");
 421         }
 422         else
 423         {
 424             $gdnsresourcefile->print("    ${name} => ${name}.${zone}.openstreetmap.org.\n");
 425         }
 426     }
 427
 428     $gdnsresourcefile->print("  }\n");
 429     $gdnsresourcefile->print("}\n");
 430
 431     $gdnsweightedfile->close();
 432     $gdnsresourcefile->close();
 433     $gdnsmapfile->close();
 434 }
 435
 436 # Output the target details in origin format if required
 437 DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 438
 439 exit 0;
 440
 441 #
 442 # Match an origin against a cluster
 443 #
 444 sub match_origin
 445 {
 446     my $cluster = shift;
 447     my $origin = shift;
 448     my $match;
 449
 450     if ($cluster->{preferred} &&
 451         $cluster->{preferred}->{origins} &&
 452         grep { $_ eq $origin->{name} } @{$cluster->{preferred}->{origins}})
 453     {
 454         $match = "preferred";
 455     }
 456     elsif ($cluster->{allowed} &&
 457            $cluster->{allowed}->{origins} &&
 458            grep { $_ eq $origin->{name} } @{$cluster->{allowed}->{origins}})
 459     {
 460         $match = "allowed";
 461     }
 462     elsif ($cluster->{preferred} &&
 463            $cluster->{preferred}->{countries} &&
 464            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 465     {
 466         $match = "preferred";
 467     }
 468     elsif ($cluster->{allowed} &&
 469            $cluster->{allowed}->{countries} &&
 470            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 471     {
 472         $match = "allowed";
 473     }
 474     elsif ($cluster->{denied} &&
 475            $cluster->{denied}->{countries} &&
 476            grep { $_ eq $origin->{country} } @{$cluster->{denied}->{countries}})
 477     {
 478         $match = "denied";
 479     }
 480     elsif ($cluster->{preferred} &&
 481            $cluster->{preferred}->{continents} &&
 482            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 483     {
 484         $match = "preferred";
 485     }
 486     elsif ($cluster->{allowed} &&
 487            $cluster->{allowed}->{continents} &&
 488            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 489     {
 490         $match = "allowed";
 491     }
 492     elsif ($cluster->{denied} &&
 493            $cluster->{denied}->{continents} &&
 494            grep { $_ eq $origin->{continent} } @{$cluster->{denied}->{continents}})
 495     {
 496         $match = "denied";
 497     }
 498     elsif ($cluster->{allowed})
 499     {
 500         $match = "denied";
 501     }
 502     else
 503     {
 504         $match = "allowed";
 505     }
 506
 507     return $match;
 508 }
 509
 510 #
 511 # Compute the great circle distance between two points
 512 #
 513 sub distance
 514 {
 515     my $lat1 = deg2rad(shift);
 516     my $lon1 = deg2rad(shift);
 517     my $lat2 = deg2rad(shift);
 518     my $lon2 = deg2rad(shift);
 519
 520     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 521 }
 522
 523 #
 524 # Allocate each origin to a cluster
 525 #
 526 sub allocate_clusters
 527 {
 528     my @mappings = sort { compare_mappings($a, $b) } @_;
 529
 530     # Loop over the mappings, trying to assign each origin to the
 531     # nearest cluster, but subject to the request limits
 532     while (my $mapping = shift @mappings)
 533     {
 534         my @group;
 535
 536         push @group, $mapping;
 537
 538         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 539         {
 540             push @group, shift @mappings;
 541         }
 542
 543         for my $mapping (sort compare_requests @group)
 544         {
 545             my $origin = $mapping->{origin};
 546             my $cluster = $mapping->{cluster};
 547
 548             if (!exists($origin->{cluster}) &&
 549                 $cluster->{requests_used} + $origin->{requests} <= $cluster->{requests_limit})
 550             {
 551                 $origin->{cluster} = $cluster;
 552                 $cluster->{requests_used} = $cluster->{requests_used} + $origin->{requests};
 553             }
 554         }
 555     }
 556
 557     return;
 558 }
 559
 560 #
 561 # Compare two mappings to decide which to use
 562 #
 563 sub compare_mappings
 564 {
 565     my $a = shift;
 566     my $b = shift;
 567
 568     return $b->{priority} <=> $a->{priority} ||
 569            $a->{distance} <=> $b->{distance};
 570 }
 571
 572 #
 573 # Compare two mappings to decide which to try first
 574 #
 575 sub compare_requests
 576 {
 577     my $a_used = ( $a->{cluster}->{requests_used} * 100.0 ) / ( $a->{cluster}->{requests_limit} * 1.0 );
 578     my $b_used = ( $b->{cluster}->{requests_used} * 100.0 ) / ( $b->{cluster}->{requests_limit} * 1.0 );
 579
 580     return $a_used <=> $b_used;
 581 }
 582
 583 #
 584 # Output DNS records for a server
 585 #
 586 sub output_server
 587 {
 588     my $zonefile = shift;
 589     my $name = shift;
 590     my $cluster = shift;
 591     my $all = shift;
 592
 593     while (my($index,$server) = each @{$cluster->{servers}})
 594     {
 595         if ($all || $server->{status} eq "up")
 596         {
 597             if ($server->{ipv4})
 598             {
 599                 $zonefile->printf("  A(\"${name}\", \"$server->{ipv4}\", TTL(\"10m\")),\n", $index + 1);
 600             }
 601
 602             if ($server->{ipv6})
 603             {
 604                 $zonefile->printf("  AAAA(\"${name}\", \"$server->{ipv6}\", TTL(\"10m\")),\n", $index + 1);
 605             }
 606         }
 607     }
 608
 609     return;
 610 }