bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use v5.12;
   4
   5 use strict;
   6 use warnings;
   7
   8 use IO::File;
   9 use Math::Trig qw(deg2rad pip2 great_circle_distance);
  10 use JSON::XS;
  11 use LWP::UserAgent;
  12 use YAML::XS qw(LoadFile DumpFile);
  13
  14 my $originfile = shift @ARGV;
  15 my $clusterfile = shift @ARGV;
  16 my $zone = shift @ARGV;
  17 my $targetoriginfile = shift @ARGV;
  18 my $origins = LoadFile($originfile);
  19 my $clusters = LoadFile($clusterfile);
  20 my $gdnsname = shift @ARGV;
  21 my @servers;
  22
  23 # Initialise cluster details
  24 while (my($name,$cluster) = each %$clusters)
  25 {
  26     if ($cluster->{servers})
  27     {
  28         $cluster->{requests} = 0;
  29
  30         foreach my $server (@{$cluster->{servers}})
  31         {
  32             $server->{cluster} = $cluster;
  33             $cluster->{requests} = $cluster->{requests} + $server->{requests};
  34
  35             push @servers, $server;
  36         }
  37     }
  38     else
  39     {
  40         my $server = {
  41             cluster => $cluster,
  42             statuscake => $cluster->{statuscake},
  43             requests => $cluster->{requests},
  44             cname => $cluster->{cname},
  45             ipv4 => $cluster->{ipv4},
  46             ipv6 => $cluster->{ipv6}
  47         };
  48
  49         $cluster->{servers} = [ $server ];
  50
  51         push @servers, $server;
  52     }
  53
  54     $cluster->{name} = $name;
  55     $cluster->{status} = "down";
  56 }
  57
  58 # Initialise server details
  59 foreach my $server (@servers)
  60 {
  61     $server->{status} = "up";
  62 }
  63
  64 # If statuscake support is enabled then check which servers are up
  65 if ($ENV{STATUSCAKE_APIKEY})
  66 {
  67     my $ua = LWP::UserAgent->new;
  68     my $cache;
  69
  70     $ua->agent("mkgeo/1.0");
  71     $ua->default_header("Authorization", "Bearer $ENV{STATUSCAKE_APIKEY}");
  72
  73     if (-f "statuscake.yml")
  74     {
  75         $cache = LoadFile("statuscake.yml");
  76     }
  77     else
  78     {
  79         $cache = {};
  80     }
  81
  82     my $page = 1;
  83     my $pages = 1;
  84
  85     while ($page <= $pages)
  86     {
  87         my $response = $ua->get("https://api.statuscake.com/v1/uptime?nouptime=true&limit=100&page=${page}");
  88
  89         if ($response->is_success)
  90         {
  91             my $uptime = decode_json($response->content);
  92
  93             foreach my $test (@{$uptime->{data}})
  94             {
  95                 my $testid = $test->{id};
  96
  97                 if ($test->{status} eq "up" && !$test->{paused})
  98                 {
  99                     $cache->{$testid} = "up";
 100                 }
 101                 else
 102                 {
 103                     $cache->{$testid} = "down";
 104                 }
 105             }
 106
 107             $page = $page + 1;
 108             $pages = $uptime->{metadata}->{page_count};
 109         }
 110     }
 111
 112     foreach my $server (@servers)
 113     {
 114         if (my $testids = $server->{statuscake})
 115         {
 116             $server->{status} = "up";
 117
 118             for my $testid (@$testids)
 119             {
 120                 my $testresult = $cache->{$testid} || "down";
 121
 122                 $server->{status} = "down" if $testresult eq "down";
 123             }
 124         }
 125         else
 126         {
 127             $server->{status} = "down";
 128         }
 129     }
 130
 131     DumpFile("statuscake-$$.yml", $cache);
 132     rename("statuscake-$$.yml", "statuscake.yml");
 133 }
 134
 135 # Mark a cluster as up if any servers are up
 136 foreach my $server (@servers)
 137 {
 138     if ($server->{status} eq "up")
 139     {
 140         $server->{cluster}->{status} = "up";
 141     }
 142     else
 143     {
 144         $server->{cluster}->{requests} = $server->{cluster}->{requests} - $server->{requests};
 145     }
 146 }
 147
 148 # Create target origins object
 149 my $targetorigins = {};
 150
 151 # Initialise cluster details
 152 while (my($name,$cluster) = each %$clusters)
 153 {
 154     $cluster->{requests_limit} = $cluster->{requests};
 155     $cluster->{requests_used} = 0;
 156
 157     next if $cluster->{global};
 158
 159     $targetorigins->{$cluster->{name}} = {
 160         code => $cluster->{name},
 161         name => $cluster->{name},
 162         lat => $cluster->{lat},
 163         lon => $cluster->{lon},
 164         requests => 0
 165     };
 166 }
 167
 168 my @mappings = ();
 169
 170 # Scan origins and work out which clusters each can use
 171 foreach my $origin (values %$origins)
 172 {
 173     foreach my $cluster (values %$clusters)
 174     {
 175         my $match = match_origin($cluster, $origin);
 176
 177         if ($cluster->{status} eq "up" && $match ne "denied")
 178         {
 179             my $priority = $match eq "preferred" ? 20 : 10;
 180             my $distance;
 181
 182             if ($cluster->{global})
 183             {
 184                 $distance = 0;
 185             }
 186             else
 187             {
 188                 $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 189             }
 190
 191             push @mappings, {
 192                 origin => $origin, cluster => $cluster,
 193                 priority => $priority, distance => $distance
 194             };
 195         }
 196     }
 197 }
 198
 199 # Allocate each country to a cluster
 200 allocate_clusters(@mappings);
 201
 202 # If we failed to allocate every origin then loop, increasing
 203 # the requests for each cluster by a little and retrying until
 204 # we manage to allocate everything
 205 while (grep { !exists($_->{cluster}) } values %$origins)
 206 {
 207     # Clear any existing mappings of countries to clusters
 208     foreach my $origin (values %$origins)
 209     {
 210         delete $origin->{cluster};
 211     }
 212
 213     # Reset requests usage for clusters and increase limits by 10%
 214     foreach my $cluster (values %$clusters)
 215     {
 216         $cluster->{requests_used} = 0;
 217         $cluster->{requests_limit} = $cluster->{requests_limit} * 1.1;
 218     }
 219
 220     # Try the allocate again
 221     allocate_clusters(@mappings);
 222 }
 223
 224 # Report on allocation results
 225 foreach my $name (sort keys %$clusters)
 226 {
 227     my $cluster = $clusters->{$name};
 228     my $used = int($cluster->{requests_used} + 0.5);
 229     my $limit = $cluster->{requests_limit};
 230     my $proportion = int($used / $limit * 100 + 0.5);
 231
 232     print "${name}: used ${used} of ${limit} (${proportion}%)\n";
 233 }
 234
 235 # Create JSON collection object
 236 my @json;
 237
 238 # Open output files
 239 my $zonefile = IO::File->new("> include/${zone}.js") || die "$!";
 240 my $jsonfile = IO::File->new("> json/${zone}.openstreetmap.org.json") || die "$!";
 241
 242 # Output headers
 243 $zonefile->print("var \U${zone}\E_RECORDS = [\n");
 244
 245 # Output details for each country
 246 foreach my $origin (sort { $a->{name} cmp $b->{name} } values %$origins)
 247 {
 248     my $cluster = $origin->{cluster};
 249
 250     if (!defined($gdnsname))
 251     {
 252         $zonefile->print("  CNAME(\"\L$origin->{code}\E.${zone}\", \"$cluster->{name}.${zone}.openstreetmap.org.\", TTL(\"10m\")),\n");
 253     }
 254
 255     if ($cluster->{lon} && $cluster->{lat})
 256     {
 257         my $clon = $origin->{lon};
 258         my $clat = $origin->{lat};
 259         my $slon = $cluster->{lon};
 260         my $slat = $cluster->{lat};
 261
 262         if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 263         {
 264             $slon = $slon + 360;
 265         }
 266         elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 267         {
 268             $clon = $clon + 360;
 269         }
 270
 271         push @json, {
 272             type => "Feature",
 273             geometry => {
 274                 type => "LineString",
 275                 coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 276             },
 277             properties => {
 278                 origin => $origin->{name},
 279                 server => $cluster->{name},
 280                 colour => $cluster->{colour}
 281             }
 282         };
 283     }
 284
 285     next if $cluster->{global};
 286
 287     $targetorigins->{$cluster->{name}}->{requests} += $origin->{requests};
 288 }
 289
 290 # Skip default records if we don't need them
 291 if (!defined($gdnsname))
 292 {
 293     # Output default records for IPs that can't be mapped to a country
 294     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 295     {
 296         my $name = $cluster->{name};
 297
 298         if (my $default = $cluster->{default})
 299         {
 300             output_server($zonefile, "${default}.${zone}", $cluster, 0);
 301         }
 302         elsif (exists($cluster->{default}))
 303         {
 304             output_server($zonefile, "${zone}", $cluster, 0);
 305         }
 306     }
 307 }
 308
 309 # Output A records for each cluster
 310 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 311 {
 312     my $name = $cluster->{name};
 313
 314     if (@{$cluster->{servers}} > 1)
 315     {
 316         output_server($zonefile, "${name}-%02d.${zone}", $cluster, 1);
 317     }
 318     else
 319     {
 320         output_server($zonefile, "${name}.${zone}", $cluster, 1);
 321     }
 322 }
 323
 324 # Output the GeoJSON text
 325 $jsonfile->print(encode_json(\@json));
 326
 327 # Output footers
 328 $zonefile->print("];\n");
 329
 330 # Close the output files
 331 $zonefile->close();
 332 $zonefile->close();
 333
 334 # Output gdnsd configuration
 335 if (defined($gdnsname))
 336 {
 337     my $gdnsmapfile = IO::File->new("> gdns/${gdnsname}.map") || die "$!";
 338     my $gdnsresourcefile = IO::File->new("> gdns/${gdnsname}.resource") || die "$!";
 339     my $gdnsweightedfile = IO::File->new("> gdns/${gdnsname}.weighted") || die "$!";
 340     my $continent = "";
 341
 342     $gdnsmapfile->print("${gdnsname} => {\n");
 343     $gdnsmapfile->print("  geoip2_db => /usr/share/GeoIP/GeoLite2-Country.mmdb\n");
 344     $gdnsmapfile->print("  datacenters => [" . join(",", sort(keys(%$clusters))) . "]\n");
 345     $gdnsmapfile->print("  map => {\n");
 346     $gdnsmapfile->print("    default => [" . join(",", sort(map { $_->{name} } grep { $_->{default} } values(%$clusters))) . "]\n");
 347
 348     foreach my $origin (sort { $a->{continent} cmp $b->{continent} || $a->{code} cmp $b->{code} } values %$origins)
 349     {
 350         my $code = $origin->{code};
 351         my $cluster = $origin->{cluster}->{name};
 352
 353         next if $code eq "XK";
 354
 355         if ($continent ne $origin->{continent})
 356         {
 357             $gdnsmapfile->print("    }\n") if $continent;
 358
 359             $continent = $origin->{continent};
 360
 361             $gdnsmapfile->print("    ${continent} => {\n");
 362         }
 363
 364         $gdnsmapfile->print("      ${code} => [${cluster}]\n");
 365     }
 366
 367     $gdnsmapfile->print("    }\n") if $continent;
 368
 369     $gdnsmapfile->print("  }\n");
 370     $gdnsmapfile->print("}\n");
 371
 372     $gdnsresourcefile->print("${gdnsname} => {\n");
 373     $gdnsresourcefile->print("  map => ${gdnsname}\n");
 374     $gdnsresourcefile->print("  dcmap => {\n");
 375
 376     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 377     {
 378         my $name = $cluster->{name};
 379
 380         if (@{$cluster->{servers}} > 1 && grep { $_->{status} eq "up" } @{$cluster->{servers}})
 381         {
 382             $gdnsweightedfile->print("${name} => {\n");
 383
 384             while (my($index,$server) = each @{$cluster->{servers}})
 385             {
 386                 if ($server->{status} eq "up")
 387                 {
 388                     my $number = sprintf("%02d", $index + 1);
 389                     my $requests = $server->{requests};
 390
 391                     if (my $cname = $server->{cname})
 392                     {
 393                         $gdnsweightedfile->print("  ${name}-${number} = [ ${cname}., ${requests} ]\n");
 394                     }
 395                     else
 396                     {
 397                         $gdnsweightedfile->print("  ${name}-${number} = [ ${name}-${number}.${zone}.openstreetmap.org., ${requests} ]\n");
 398                     }
 399                 }
 400             }
 401
 402             $gdnsweightedfile->print("}\n");
 403
 404             $gdnsresourcefile->print("    ${name} => %weighted!${name}\n");
 405         }
 406         elsif (my $cname = $cluster->{cname})
 407         {
 408             $gdnsresourcefile->print("    ${name} => ${cname}.\n");
 409         }
 410         else
 411         {
 412             $gdnsresourcefile->print("    ${name} => ${name}.${zone}.openstreetmap.org.\n");
 413         }
 414     }
 415
 416     $gdnsresourcefile->print("  }\n");
 417     $gdnsresourcefile->print("}\n");
 418
 419     $gdnsweightedfile->close();
 420     $gdnsresourcefile->close();
 421     $gdnsmapfile->close();
 422 }
 423
 424 # Output the target details in origin format if required
 425 DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 426
 427 exit 0;
 428
 429 #
 430 # Match an origin against a cluster
 431 #
 432 sub match_origin
 433 {
 434     my $cluster = shift;
 435     my $origin = shift;
 436     my $match;
 437
 438     if ($cluster->{preferred} &&
 439         $cluster->{preferred}->{origins} &&
 440         grep { $_ eq $origin->{name} } @{$cluster->{preferred}->{origins}})
 441     {
 442         $match = "preferred";
 443     }
 444     elsif ($cluster->{allowed} &&
 445            $cluster->{allowed}->{origins} &&
 446            grep { $_ eq $origin->{name} } @{$cluster->{allowed}->{origins}})
 447     {
 448         $match = "allowed";
 449     }
 450     elsif ($cluster->{preferred} &&
 451            $cluster->{preferred}->{countries} &&
 452            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 453     {
 454         $match = "preferred";
 455     }
 456     elsif ($cluster->{allowed} &&
 457            $cluster->{allowed}->{countries} &&
 458            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 459     {
 460         $match = "allowed";
 461     }
 462     elsif ($cluster->{denied} &&
 463            $cluster->{denied}->{countries} &&
 464            grep { $_ eq $origin->{country} } @{$cluster->{denied}->{countries}})
 465     {
 466         $match = "denied";
 467     }
 468     elsif ($cluster->{preferred} &&
 469            $cluster->{preferred}->{continents} &&
 470            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 471     {
 472         $match = "preferred";
 473     }
 474     elsif ($cluster->{allowed} &&
 475            $cluster->{allowed}->{continents} &&
 476            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 477     {
 478         $match = "allowed";
 479     }
 480     elsif ($cluster->{denied} &&
 481            $cluster->{denied}->{continents} &&
 482            grep { $_ eq $origin->{continent} } @{$cluster->{denied}->{continents}})
 483     {
 484         $match = "denied";
 485     }
 486     elsif ($cluster->{allowed})
 487     {
 488         $match = "denied";
 489     }
 490     else
 491     {
 492         $match = "allowed";
 493     }
 494
 495     return $match;
 496 }
 497
 498 #
 499 # Compute the great circle distance between two points
 500 #
 501 sub distance
 502 {
 503     my $lat1 = deg2rad(shift);
 504     my $lon1 = deg2rad(shift);
 505     my $lat2 = deg2rad(shift);
 506     my $lon2 = deg2rad(shift);
 507
 508     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 509 }
 510
 511 #
 512 # Allocate each origin to a cluster
 513 #
 514 sub allocate_clusters
 515 {
 516     my @mappings = sort { compare_mappings($a, $b) } @_;
 517
 518     # Loop over the mappings, trying to assign each origin to the
 519     # nearest cluster, but subject to the request limits
 520     while (my $mapping = shift @mappings)
 521     {
 522         my @group;
 523
 524         push @group, $mapping;
 525
 526         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 527         {
 528             push @group, shift @mappings;
 529         }
 530
 531         for my $mapping (sort compare_requests @group)
 532         {
 533             my $origin = $mapping->{origin};
 534             my $cluster = $mapping->{cluster};
 535
 536             if (!exists($origin->{cluster}) &&
 537                 $cluster->{requests_used} + $origin->{requests} <= $cluster->{requests_limit})
 538             {
 539                 $origin->{cluster} = $cluster;
 540                 $cluster->{requests_used} = $cluster->{requests_used} + $origin->{requests};
 541             }
 542         }
 543     }
 544
 545     return;
 546 }
 547
 548 #
 549 # Compare two mappings to decide which to use
 550 #
 551 sub compare_mappings
 552 {
 553     my $a = shift;
 554     my $b = shift;
 555
 556     return $b->{priority} <=> $a->{priority} ||
 557            $a->{distance} <=> $b->{distance};
 558 }
 559
 560 #
 561 # Compare two mappings to decide which to try first
 562 #
 563 sub compare_requests
 564 {
 565     my $a_used = ( $a->{cluster}->{requests_used} * 100.0 ) / ( $a->{cluster}->{requests_limit} * 1.0 );
 566     my $b_used = ( $b->{cluster}->{requests_used} * 100.0 ) / ( $b->{cluster}->{requests_limit} * 1.0 );
 567
 568     return $a_used <=> $b_used;
 569 }
 570
 571 #
 572 # Output DNS records for a server
 573 #
 574 sub output_server
 575 {
 576     my $zonefile = shift;
 577     my $name = shift;
 578     my $cluster = shift;
 579     my $all = shift;
 580
 581     while (my($index,$server) = each @{$cluster->{servers}})
 582     {
 583         if ($all || $server->{status} eq "up")
 584         {
 585             if ($server->{ipv4})
 586             {
 587                 $zonefile->printf("  A(\"${name}\", \"$server->{ipv4}\", TTL(\"10m\")),\n", $index + 1);
 588             }
 589
 590             if ($server->{ipv6})
 591             {
 592                 $zonefile->printf("  AAAA(\"${name}\", \"$server->{ipv6}\", TTL(\"10m\")),\n", $index + 1);
 593             }
 594         }
 595     }
 596
 597     return;
 598 }