bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use Math::Trig qw(deg2rad pip2 great_circle_distance);
   8 use JSON::XS;
   9 use LWP::UserAgent::Determined;
  10 use YAML;
  11
  12 my $originfile = shift @ARGV;
  13 my $clusterfile = shift @ARGV;
  14 my $zone = shift @ARGV;
  15 my $targetoriginfile = shift @ARGV;
  16 my $origins = YAML::LoadFile($originfile);
  17 my $clusters = YAML::LoadFile($clusterfile);
  18 my @servers;
  19
  20 # Initialise cluster details
  21 while (my($name,$cluster) = each %$clusters)
  22 {
  23     if ($cluster->{servers})
  24     {
  25         $cluster->{bandwidth} = 0;
  26
  27         foreach my $server (@{$cluster->{servers}})
  28         {
  29             $server->{cluster} = $cluster;
  30             $cluster->{bandwidth} = $cluster->{bandwidth} + $server->{bandwidth};
  31
  32             push @servers, $server;
  33         }
  34     }
  35     else
  36     {
  37         my $server = {
  38             cluster => $cluster,
  39             pingdom => $cluster->{pingdom},
  40             bandwidth => $cluster->{bandwidth},
  41             ipv4 => $cluster->{ipv4},
  42             ipv6 => $cluster->{ipv6}
  43         };
  44
  45         $cluster->{servers} = [ $server ];
  46
  47         push @servers, $server;
  48     }
  49
  50     $cluster->{name} = $name;
  51
  52     if ($ENV{PINGDOM_USERNAME} && $ENV{PINGDOM_PASSWORD})
  53     {
  54         $cluster->{status} = "down";
  55     }
  56     else
  57     {
  58         $cluster->{status} = "up";
  59     }
  60 }
  61
  62 # Initialise server details
  63 foreach my $server (@servers)
  64 {
  65     if ($ENV{PINGDOM_USERNAME} && $ENV{PINGDOM_PASSWORD})
  66     {
  67         $server->{status} = "down";
  68     }
  69     else
  70     {
  71         $server->{status} = "up";
  72     }
  73 }
  74
  75 # If pingdom support is enabled then check which servers are up
  76 if ($ENV{PINGDOM_USERNAME} && $ENV{PINGDOM_PASSWORD})
  77 {
  78     my $ua = LWP::UserAgent::Determined->new;
  79     $ua->timeout(15);
  80
  81     $ua->default_header("App-Key", "2cohi62u5haxvqmypk3ljqqrze1jufrh");
  82     $ua->credentials("api.pingdom.com:443", "Pingdom API", $ENV{PINGDOM_USERNAME}, $ENV{PINGDOM_PASSWORD});
  83
  84     foreach my $server (@servers)
  85     {
  86         if (my $checkid = $server->{pingdom})
  87         {
  88             my $response = $ua->get("https://api.pingdom.com/api/2.0/checks/${checkid}");
  89
  90             if ($response->is_success)
  91             {
  92                 my $check = decode_json($response->content);
  93
  94                 $server->{status} = $check->{check}->{status};
  95
  96                 if ($server->{status} eq "up")
  97                 {
  98                     $server->{cluster}->{status} = "up";
  99                 }
 100                 else
 101                 {
 102                     $server->{cluster}->{bandwidth} = $server->{cluster}->{bandwidth} - $server->{bandwidth};
 103                 }
 104             }
 105         }
 106     }
 107 }
 108
 109 # Create target origins object
 110 my $targetorigins = {};
 111
 112 # Initialise cluster details
 113 while (my($name,$cluster) = each %$clusters)
 114 {
 115     $cluster->{bandwidth_limit} = $cluster->{bandwidth} * 1024 * 1024;
 116     $cluster->{bandwidth_used} = 0;
 117
 118     $targetorigins->{$cluster->{name}} = {
 119         code => $cluster->{name},
 120         name => $cluster->{name},
 121         lat => $cluster->{lat},
 122         lon => $cluster->{lon},
 123         bandwidth => 0
 124     };
 125 }
 126
 127 my @mappings = ();
 128
 129 # Scan origins and work out which clusters each can use
 130 foreach my $origin (values %$origins)
 131 {
 132     foreach my $cluster (values %$clusters)
 133     {
 134         my $match = match_origin($cluster, $origin);
 135
 136         if ($cluster->{status} eq "up" && $match ne "denied")
 137         {
 138             my $priority = $match eq "preferred" ? 20 : 10;
 139             my $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 140
 141             push @mappings, {
 142                 origin => $origin, cluster => $cluster,
 143                 priority => $priority, distance => $distance
 144             };
 145         }
 146     }
 147 }
 148
 149 # Allocate each country to a cluster
 150 allocate_clusters(@mappings);
 151
 152 # If we failed to allocate every origin then loop, increasing
 153 # the bandwidth for each cluster by a little and retrying until
 154 # we manage to allocate everything
 155 while (grep { !exists($_->{cluster}) } values %$origins)
 156 {
 157     # Clear any existing mappings of countries to clusters
 158     foreach my $origin (values %$origins)
 159     {
 160         delete $origin->{cluster};
 161     }
 162
 163     # Reset bandwidth usage for clusters and increase limits by 10%
 164     foreach my $cluster (values %$clusters)
 165     {
 166         $cluster->{bandwidth_used} = 0;
 167         $cluster->{bandwidth_limit} = $cluster->{bandwidth_limit} * 1.1;
 168     }
 169
 170     # Try the allocate again
 171     allocate_clusters(@mappings);
 172 }
 173
 174 # Create JSON collection object
 175 my @json;
 176
 177 # Open output files
 178 my $zonefile = IO::File->new("> data/${zone}") || die "$!";
 179 my $jsonfile = IO::File->new("> json/${zone}.json") || die "$!";
 180
 181 # Output details for each country
 182 foreach my $origin (values %$origins)
 183 {
 184     my $cluster = $origin->{cluster};
 185     my $clon = $origin->{lon};
 186     my $clat = $origin->{lat};
 187     my $slon = $cluster->{lon};
 188     my $slat = $cluster->{lat};
 189
 190     if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 191     {
 192         $slon = $slon + 360;
 193     }
 194     elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 195     {
 196         $clon = $clon + 360;
 197     }
 198
 199     $zonefile->print("# $origin->{name}\n");
 200     $zonefile->print("C\L$origin->{code}\E.${zone}:$cluster->{name}.${zone}:600\n");
 201
 202     push @json, {
 203         type => "Feature",
 204         geometry => {
 205             type => "LineString",
 206             coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 207         },
 208         properties => {
 209             origin => $origin->{name},
 210             server => $cluster->{name},
 211             colour => $cluster->{colour}
 212         }
 213     };
 214
 215     $targetorigins->{$cluster->{name}}->{bandwidth} += $origin->{bandwidth};
 216 }
 217
 218 # Header for default records
 219 $zonefile->print("# Unknown origins\n");
 220
 221 # Output default records for IPs that can't be mapped to a country
 222 while (my($name,$cluster) = each %$clusters)
 223 {
 224     if (my $default = $cluster->{default})
 225     {
 226         output_server($zonefile, "${default}.${zone}", $cluster);
 227     }
 228     elsif (exists($cluster->{default}))
 229     {
 230         output_server($zonefile, "${zone}", $cluster);
 231     }
 232 }
 233
 234 # Header for underlying servers
 235 $zonefile->print("# Servers\n");
 236
 237 # Output A records for each cluster
 238 while (my($name,$cluster) = each %$clusters)
 239 {
 240     output_server($zonefile, "${name}.${zone}", $cluster);
 241 }
 242
 243 # Output the GeoJSON text
 244 $jsonfile->print(encode_json(\@json));
 245
 246 # Close the output files
 247 $jsonfile->close();
 248 $zonefile->close();
 249
 250 # Output the target details in origin format if required
 251 YAML::DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 252
 253 exit 0;
 254
 255 #
 256 # Match an origin against a cluster
 257 #
 258 sub match_origin
 259 {
 260     my $cluster = shift;
 261     my $origin = shift;
 262     my $match;
 263
 264     if ($cluster->{preferred} &&
 265         $cluster->{preferred}->{countries} &&
 266         grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 267     {
 268         $match = "preferred";
 269     }
 270     elsif ($cluster->{preferred} &&
 271            $cluster->{preferred}->{continents} &&
 272            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 273     {
 274         $match = "preferred";
 275     }
 276     elsif ($cluster->{allowed} &&
 277            $cluster->{allowed}->{countries} &&
 278            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 279     {
 280         $match = "allowed";
 281     }
 282     elsif ($cluster->{allowed} &&
 283            $cluster->{allowed}->{continents} &&
 284            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 285     {
 286         $match = "allowed";
 287     }
 288     elsif ($cluster->{denied} &&
 289            $cluster->{denied}->{countries} &&
 290            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 291     {
 292         $match = "denied";
 293     }
 294     elsif ($cluster->{denied} &&
 295            $cluster->{denied}->{continents} &&
 296            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 297     {
 298         $match = "denied";
 299     }
 300     elsif ($cluster->{allowed})
 301     {
 302         $match = "denied";
 303     }
 304     else
 305     {
 306         $match = "allowed";
 307     }
 308
 309     return $match;
 310 }
 311
 312 #
 313 # Compute the great circle distance between two points
 314 #
 315 sub distance
 316 {
 317     my $lat1 = deg2rad(shift);
 318     my $lon1 = deg2rad(shift);
 319     my $lat2 = deg2rad(shift);
 320     my $lon2 = deg2rad(shift);
 321
 322     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 323 }
 324
 325 #
 326 # Allocate each origin to a cluster
 327 #
 328 sub allocate_clusters
 329 {
 330     my @mappings = sort { compare_mappings($a, $b) } @_;
 331
 332     # Loop over the mappings, trying to assign each origin to the
 333     # nearest cluster, but subject to the bandwidth limits
 334     while (my $mapping = shift @mappings)
 335     {
 336         my @group;
 337
 338         push @group, $mapping;
 339
 340         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 341         {
 342             push @group, shift @mappings;
 343         }
 344
 345         for my $mapping (sort compare_bandwidth @group)
 346         {
 347             my $origin = $mapping->{origin};
 348             my $cluster = $mapping->{cluster};
 349
 350             if (!exists($origin->{cluster}) &&
 351                 $cluster->{bandwidth_used} + $origin->{bandwidth} <= $cluster->{bandwidth_limit})
 352             {
 353                 $origin->{cluster} = $cluster;
 354                 $cluster->{bandwidth_used} = $cluster->{bandwidth_used} + $origin->{bandwidth};
 355             }
 356         }
 357     }
 358
 359     return;
 360 }
 361
 362 #
 363 # Compare two mappings to decide which to use
 364 #
 365 sub compare_mappings
 366 {
 367     my $a = shift;
 368     my $b = shift;
 369
 370     return $b->{priority} <=> $a->{priority} ||
 371            $a->{distance} <=> $b->{distance};
 372 }
 373
 374 #
 375 # Compare two mappings to decide which to try first
 376 #
 377 sub compare_bandwidth
 378 {
 379     my $a_used = ( $a->{cluster}->{bandwidth_used} * 100.0 ) / ( $a->{cluster}->{bandwidth_limit} * 1.0 );
 380     my $b_used = ( $b->{cluster}->{bandwidth_used} * 100.0 ) / ( $b->{cluster}->{bandwidth_limit} * 1.0 );
 381
 382     return $a_used <=> $b_used;
 383 }
 384
 385 #
 386 # Output DNS records for a server
 387 #
 388 sub output_server
 389 {
 390     my $zonefile = shift;
 391     my $name = shift;
 392     my $cluster = shift;
 393
 394     foreach my $server (@{$cluster->{servers}})
 395     {
 396         if ($server->{status} eq "up")
 397         {
 398             $zonefile->print("+${name}:$server->{ipv4}:3600\n");
 399
 400             if ($server->{ipv6})
 401             {
 402 #                $zonefile->print("3${name}:$server->{ipv6}:3600\n");
 403             }
 404         }
 405     }
 406
 407     return;
 408 }