bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use Math::Trig qw(deg2rad pip2 great_circle_distance);
   8 use JSON::XS;
   9 use LWP::UserAgent;
  10 use YAML;
  11
  12 my $originfile = shift @ARGV;
  13 my $clusterfile = shift @ARGV;
  14 my $zone = shift @ARGV;
  15 my $targetoriginfile = shift @ARGV;
  16 my $origins = YAML::LoadFile($originfile);
  17 my $clusters = YAML::LoadFile($clusterfile);
  18 my @servers;
  19
  20 # Initialise cluster details
  21 while (my($name,$cluster) = each %$clusters)
  22 {
  23     if ($cluster->{servers})
  24     {
  25         $cluster->{bandwidth} = 0;
  26
  27         foreach my $server (@{$cluster->{servers}})
  28         {
  29             $server->{cluster} = $cluster;
  30             $cluster->{bandwidth} = $cluster->{bandwidth} + $server->{bandwidth};
  31
  32             push @servers, $server;
  33         }
  34     }
  35     else
  36     {
  37         my $server = {
  38             cluster => $cluster,
  39             pingdom => $cluster->{pingdom},
  40             bandwidth => $cluster->{bandwidth},
  41             ipv4 => $cluster->{ipv4},
  42             ipv6 => $cluster->{ipv6}
  43         };
  44
  45         $cluster->{servers} = [ $server ];
  46
  47         push @servers, $server;
  48     }
  49
  50     $cluster->{name} = $name;
  51
  52     if ($ENV{PINGDOM_USERNAME} && $ENV{PINGDOM_PASSWORD})
  53     {
  54         $cluster->{status} = "down";
  55     }
  56     else
  57     {
  58         $cluster->{status} = "up";
  59     }
  60 }
  61
  62 # Initialise server details
  63 foreach my $server (@servers)
  64 {
  65     if ($ENV{PINGDOM_USERNAME} && $ENV{PINGDOM_PASSWORD})
  66     {
  67         $server->{status} = "down";
  68     }
  69     else
  70     {
  71         $server->{status} = "up";
  72     }
  73 }
  74
  75 # If pingdom support is enabled then check which servers are up
  76 if ($ENV{PINGDOM_USERNAME} && $ENV{PINGDOM_PASSWORD})
  77 {
  78     my $ua = LWP::UserAgent->new;
  79
  80     $ua->default_header("App-Key", "2cohi62u5haxvqmypk3ljqqrze1jufrh");
  81     $ua->credentials("api.pingdom.com:443", "Pingdom API", $ENV{PINGDOM_USERNAME}, $ENV{PINGDOM_PASSWORD});
  82
  83     foreach my $server (@servers)
  84     {
  85         if (my $checkid = $server->{pingdom})
  86         {
  87             my $response = $ua->get("https://api.pingdom.com/api/2.0/checks/${checkid}");
  88
  89             if ($response->is_success)
  90             {
  91                 my $check = decode_json($response->content);
  92
  93                 $server->{status} = $check->{check}->{status};
  94
  95                 if ($server->{status} eq "up")
  96                 {
  97                     $server->{cluster}->{status} = "up";
  98                 }
  99                 else
 100                 {
 101                     $server->{cluster}->{bandwidth} = $server->{cluster}->{bandwidth} - $server->{bandwidth};
 102                 }
 103             }
 104         }
 105     }
 106 }
 107
 108 # Initialise cluster details
 109 while (my($name,$cluster) = each %$clusters)
 110 {
 111     $cluster->{bandwidth_limit} = $cluster->{bandwidth} * 1024 * 1024;
 112     $cluster->{bandwidth_used} = 0;
 113 }
 114
 115 my @mappings = ();
 116
 117 # Scan origins and work out which clusters each can use
 118 foreach my $origin (values %$origins)
 119 {
 120     foreach my $cluster (values %$clusters)
 121     {
 122         my $match = match_origin($cluster, $origin);
 123
 124         if ($cluster->{status} eq "up" && $match ne "denied")
 125         {
 126             my $priority = $match eq "preferred" ? 20 : 10;
 127             my $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 128
 129             push @mappings, {
 130                 origin => $origin, cluster => $cluster,
 131                 priority => $priority, distance => $distance
 132             };
 133         }
 134     }
 135 }
 136
 137 # Allocate each country to a cluster
 138 allocate_clusters(@mappings);
 139
 140 # If we failed to allocate every origin then loop, increasing
 141 # the bandwidth for each cluster by a little and retrying until
 142 # we manage to allocate everything
 143 while (grep { !exists($_->{cluster}) } values %$origins)
 144 {
 145     # Clear any existing mappings of countries to clusters
 146     foreach my $origin (values %$origins)
 147     {
 148         delete $origin->{cluster};
 149     }
 150
 151     # Reset bandwidth usage for clusters and increase limits by 10%
 152     foreach my $cluster (values %$clusters)
 153     {
 154         $cluster->{bandwidth_used} = 0;
 155         $cluster->{bandwidth_limit} = $cluster->{bandwidth_limit} * 1.1;
 156     }
 157
 158     # Try the allocate again
 159     allocate_clusters(@mappings);
 160 }
 161
 162 # Create JSON collection object
 163 my @json;
 164
 165 # Create target origins object
 166 my $targetorigins = {};
 167
 168 # Open output files
 169 my $zonefile = IO::File->new("> data/${zone}") || die "$!";
 170 my $jsonfile = IO::File->new("> json/${zone}.json") || die "$!";
 171
 172 # Output details for each country
 173 foreach my $origin (values %$origins)
 174 {
 175     my $cluster = $origin->{cluster};
 176     my $clon = $origin->{lon};
 177     my $clat = $origin->{lat};
 178     my $slon = $cluster->{lon};
 179     my $slat = $cluster->{lat};
 180
 181     if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 182     {
 183         $slon = $slon + 360;
 184     }
 185     elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 186     {
 187         $clon = $clon + 360;
 188     }
 189
 190     $zonefile->print("# $origin->{name}\n");
 191     $zonefile->print("C\L$origin->{code}\E.${zone}:$cluster->{name}.${zone}:600\n");
 192
 193     push @json, {
 194         type => "Feature",
 195         geometry => {
 196             type => "LineString",
 197             coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 198         },
 199         properties => {
 200             origin => $origin->{name},
 201             server => $cluster->{name},
 202             colour => $cluster->{colour}
 203         }
 204     };
 205
 206     unless (exists($targetorigins->{$cluster->{name}}))
 207     {
 208         $targetorigins->{$cluster->{name}} = {
 209             code => $cluster->{name},
 210             name => $cluster->{name},
 211             lat => $cluster->{lat},
 212             lon => $cluster->{lon},
 213             bandwidth => 0
 214         };
 215     }
 216
 217     $targetorigins->{$cluster->{name}}->{bandwidth} += $origin->{bandwidth};
 218 }
 219
 220 # Header for default records
 221 $zonefile->print("# Unknown origins\n");
 222
 223 # Output default records for IPs that can't be mapped to a country
 224 while (my($name,$cluster) = each %$clusters)
 225 {
 226     if (my $default = $cluster->{default})
 227     {
 228         output_server($zonefile, "${default}.${zone}", $cluster);
 229     }
 230     elsif (exists($cluster->{default}))
 231     {
 232         output_server($zonefile, "${zone}", $cluster);
 233     }
 234 }
 235
 236 # Header for underlying servers
 237 $zonefile->print("# Servers\n");
 238
 239 # Output A records for each cluster
 240 while (my($name,$cluster) = each %$clusters)
 241 {
 242     output_server($zonefile, "${name}.${zone}", $cluster);
 243 }
 244
 245 # Output the GeoJSON text
 246 $jsonfile->print(encode_json(\@json));
 247
 248 # Close the output files
 249 $jsonfile->close();
 250 $zonefile->close();
 251
 252 # Output the target details in origin format if required
 253 YAML::DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 254
 255 exit 0;
 256
 257 #
 258 # Match an origin against a cluster
 259 #
 260 sub match_origin
 261 {
 262     my $cluster = shift;
 263     my $origin = shift;
 264     my $match;
 265
 266     if ($cluster->{preferred} &&
 267         $cluster->{preferred}->{countries} &&
 268         grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 269     {
 270         $match = "preferred";
 271     }
 272     elsif ($cluster->{preferred} &&
 273            $cluster->{preferred}->{continents} &&
 274            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 275     {
 276         $match = "preferred";
 277     }
 278     elsif ($cluster->{allowed} &&
 279            $cluster->{allowed}->{countries} &&
 280            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 281     {
 282         $match = "allowed";
 283     }
 284     elsif ($cluster->{allowed} &&
 285            $cluster->{allowed}->{continents} &&
 286            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 287     {
 288         $match = "allowed";
 289     }
 290     elsif ($cluster->{denied} &&
 291            $cluster->{denied}->{countries} &&
 292            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 293     {
 294         $match = "denied";
 295     }
 296     elsif ($cluster->{denied} &&
 297            $cluster->{denied}->{continents} &&
 298            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 299     {
 300         $match = "denied";
 301     }
 302     elsif ($cluster->{allowed})
 303     {
 304         $match = "denied";
 305     }
 306     else
 307     {
 308         $match = "allowed";
 309     }
 310
 311     return $match;
 312 }
 313
 314 #
 315 # Compute the great circle distance between two points
 316 #
 317 sub distance
 318 {
 319     my $lat1 = deg2rad(shift);
 320     my $lon1 = deg2rad(shift);
 321     my $lat2 = deg2rad(shift);
 322     my $lon2 = deg2rad(shift);
 323
 324     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 325 }
 326
 327 #
 328 # Allocate each origin to a cluster
 329 #
 330 sub allocate_clusters
 331 {
 332     my @mappings = sort { compare_mappings($a, $b) } @_;
 333
 334     # Loop over the mappings, trying to assign each origin to the
 335     # nearest cluster, but subject to the bandwidth limits
 336     while (my $mapping = shift @mappings)
 337     {
 338         my @group;
 339
 340         push @group, $mapping;
 341
 342         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 343         {
 344             push @group, shift @mappings;
 345         }
 346
 347         for my $mapping (sort compare_bandwidth @group)
 348         {
 349             my $origin = $mapping->{origin};
 350             my $cluster = $mapping->{cluster};
 351
 352             if (!exists($origin->{cluster}) &&
 353                 $cluster->{bandwidth_used} + $origin->{bandwidth} <= $cluster->{bandwidth_limit})
 354             {
 355                 $origin->{cluster} = $cluster;
 356                 $cluster->{bandwidth_used} = $cluster->{bandwidth_used} + $origin->{bandwidth};
 357             }
 358         }
 359     }
 360
 361     return;
 362 }
 363
 364 #
 365 # Compare two mappings to decide which to use
 366 #
 367 sub compare_mappings
 368 {
 369     my $a = shift;
 370     my $b = shift;
 371
 372     return $b->{priority} <=> $a->{priority} ||
 373            $a->{distance} <=> $b->{distance};
 374 }
 375
 376 #
 377 # Compare two mappings to decide which to try first
 378 #
 379 sub compare_bandwidth
 380 {
 381     my $a_used = ( $a->{cluster}->{bandwidth_used} * 100.0 ) / ( $a->{cluster}->{bandwidth_limit} * 1.0 );
 382     my $b_used = ( $b->{cluster}->{bandwidth_used} * 100.0 ) / ( $b->{cluster}->{bandwidth_limit} * 1.0 );
 383
 384     return $a_used <=> $b_used;
 385 }
 386
 387 #
 388 # Output DNS records for a server
 389 #
 390 sub output_server
 391 {
 392     my $zonefile = shift;
 393     my $name = shift;
 394     my $cluster = shift;
 395
 396     foreach my $server (@{$cluster->{servers}})
 397     {
 398         if ($server->{status} eq "up")
 399         {
 400             $zonefile->print("+${name}:$server->{ipv4}:3600\n");
 401
 402             if ($server->{ipv6})
 403             {
 404 #                $zonefile->print("3${name}:$server->{ipv6}:3600\n");
 405             }
 406         }
 407     }
 408
 409     return;
 410 }