bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use Math::Trig qw(deg2rad pip2 great_circle_distance);
   8 use JSON::XS;
   9 use LWP::UserAgent;
  10 use YAML;
  11
  12 my $originfile = shift @ARGV;
  13 my $clusterfile = shift @ARGV;
  14 my $zone = shift @ARGV;
  15 my $targetoriginfile = shift @ARGV;
  16 my $origins = YAML::LoadFile($originfile);
  17 my $clusters = YAML::LoadFile($clusterfile);
  18 my @servers;
  19
  20 # Initialise cluster details
  21 while (my($name,$cluster) = each %$clusters)
  22 {
  23     if ($cluster->{servers})
  24     {
  25         $cluster->{bandwidth} = 0;
  26
  27         foreach my $server (@{$cluster->{servers}})
  28         {
  29             $server->{cluster} = $cluster;
  30             $cluster->{bandwidth} = $cluster->{bandwidth} + $server->{bandwidth};
  31
  32             push @servers, $server;
  33         }
  34     }
  35     else
  36     {
  37         my $server = {
  38             cluster => $cluster,
  39             pingdom => $cluster->{pingdom},
  40             bandwidth => $cluster->{bandwidth},
  41             ipv4 => $cluster->{ipv4},
  42             ipv6 => $cluster->{ipv6}
  43         };
  44
  45         $cluster->{servers} = [ $server ];
  46
  47         push @servers, $server;
  48     }
  49
  50     $cluster->{name} = $name;
  51
  52     if ($ENV{PINGDOM_USERNAME} && $ENV{PINGDOM_PASSWORD})
  53     {
  54         $cluster->{status} = "down";
  55     }
  56     else
  57     {
  58         $cluster->{status} = "up";
  59     }
  60 }
  61
  62 # Initialise server details
  63 foreach my $server (@servers)
  64 {
  65     if ($ENV{PINGDOM_USERNAME} && $ENV{PINGDOM_PASSWORD})
  66     {
  67         $server->{status} = "down";
  68     }
  69     else
  70     {
  71         $server->{status} = "up";
  72     }
  73 }
  74
  75 # If pingdom support is enabled then check which servers are up
  76 if ($ENV{PINGDOM_USERNAME} && $ENV{PINGDOM_PASSWORD})
  77 {
  78     my $ua = LWP::UserAgent->new;
  79
  80     $ua->default_header("App-Key", "2cohi62u5haxvqmypk3ljqqrze1jufrh");
  81     $ua->credentials("api.pingdom.com:443", "Pingdom API", $ENV{PINGDOM_USERNAME}, $ENV{PINGDOM_PASSWORD});
  82
  83     foreach my $server (@servers)
  84     {
  85         if (my $checkid = $server->{pingdom})
  86         {
  87             my $response = $ua->get("https://api.pingdom.com/api/2.0/checks/${checkid}");
  88
  89             if ($response->is_success)
  90             {
  91                 my $check = decode_json($response->content);
  92
  93                 $server->{status} = $check->{check}->{status};
  94
  95                 if ($server->{status} eq "up")
  96                 {
  97                     $server->{cluster}->{status} = "up";
  98                 }
  99                 else
 100                 {
 101                     $server->{cluster}->{bandwidth} = $server->{cluster}->{bandwidth} - $server->{bandwidth};
 102                 }
 103             }
 104         }
 105     }
 106 }
 107
 108 # Create target origins object
 109 my $targetorigins = {};
 110
 111 # Initialise cluster details
 112 while (my($name,$cluster) = each %$clusters)
 113 {
 114     $cluster->{bandwidth_limit} = $cluster->{bandwidth} * 1024 * 1024;
 115     $cluster->{bandwidth_used} = 0;
 116
 117     $targetorigins->{$cluster->{name}} = {
 118         code => $cluster->{name},
 119         name => $cluster->{name},
 120         lat => $cluster->{lat},
 121         lon => $cluster->{lon},
 122         bandwidth => 0
 123     };
 124 }
 125
 126 my @mappings = ();
 127
 128 # Scan origins and work out which clusters each can use
 129 foreach my $origin (values %$origins)
 130 {
 131     foreach my $cluster (values %$clusters)
 132     {
 133         my $match = match_origin($cluster, $origin);
 134
 135         if ($cluster->{status} eq "up" && $match ne "denied")
 136         {
 137             my $priority = $match eq "preferred" ? 20 : 10;
 138             my $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 139
 140             push @mappings, {
 141                 origin => $origin, cluster => $cluster,
 142                 priority => $priority, distance => $distance
 143             };
 144         }
 145     }
 146 }
 147
 148 # Allocate each country to a cluster
 149 allocate_clusters(@mappings);
 150
 151 # If we failed to allocate every origin then loop, increasing
 152 # the bandwidth for each cluster by a little and retrying until
 153 # we manage to allocate everything
 154 while (grep { !exists($_->{cluster}) } values %$origins)
 155 {
 156     # Clear any existing mappings of countries to clusters
 157     foreach my $origin (values %$origins)
 158     {
 159         delete $origin->{cluster};
 160     }
 161
 162     # Reset bandwidth usage for clusters and increase limits by 10%
 163     foreach my $cluster (values %$clusters)
 164     {
 165         $cluster->{bandwidth_used} = 0;
 166         $cluster->{bandwidth_limit} = $cluster->{bandwidth_limit} * 1.1;
 167     }
 168
 169     # Try the allocate again
 170     allocate_clusters(@mappings);
 171 }
 172
 173 # Create JSON collection object
 174 my @json;
 175
 176 # Open output files
 177 my $zonefile = IO::File->new("> data/${zone}") || die "$!";
 178 my $jsonfile = IO::File->new("> json/${zone}.json") || die "$!";
 179
 180 # Output details for each country
 181 foreach my $origin (values %$origins)
 182 {
 183     my $cluster = $origin->{cluster};
 184     my $clon = $origin->{lon};
 185     my $clat = $origin->{lat};
 186     my $slon = $cluster->{lon};
 187     my $slat = $cluster->{lat};
 188
 189     if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 190     {
 191         $slon = $slon + 360;
 192     }
 193     elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 194     {
 195         $clon = $clon + 360;
 196     }
 197
 198     $zonefile->print("# $origin->{name}\n");
 199     $zonefile->print("C\L$origin->{code}\E.${zone}:$cluster->{name}.${zone}:600\n");
 200
 201     push @json, {
 202         type => "Feature",
 203         geometry => {
 204             type => "LineString",
 205             coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 206         },
 207         properties => {
 208             origin => $origin->{name},
 209             server => $cluster->{name},
 210             colour => $cluster->{colour}
 211         }
 212     };
 213
 214     $targetorigins->{$cluster->{name}}->{bandwidth} += $origin->{bandwidth};
 215 }
 216
 217 # Header for default records
 218 $zonefile->print("# Unknown origins\n");
 219
 220 # Output default records for IPs that can't be mapped to a country
 221 while (my($name,$cluster) = each %$clusters)
 222 {
 223     if (my $default = $cluster->{default})
 224     {
 225         output_server($zonefile, "${default}.${zone}", $cluster);
 226     }
 227     elsif (exists($cluster->{default}))
 228     {
 229         output_server($zonefile, "${zone}", $cluster);
 230     }
 231 }
 232
 233 # Header for underlying servers
 234 $zonefile->print("# Servers\n");
 235
 236 # Output A records for each cluster
 237 while (my($name,$cluster) = each %$clusters)
 238 {
 239     output_server($zonefile, "${name}.${zone}", $cluster);
 240 }
 241
 242 # Output the GeoJSON text
 243 $jsonfile->print(encode_json(\@json));
 244
 245 # Close the output files
 246 $jsonfile->close();
 247 $zonefile->close();
 248
 249 # Output the target details in origin format if required
 250 YAML::DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 251
 252 exit 0;
 253
 254 #
 255 # Match an origin against a cluster
 256 #
 257 sub match_origin
 258 {
 259     my $cluster = shift;
 260     my $origin = shift;
 261     my $match;
 262
 263     if ($cluster->{preferred} &&
 264         $cluster->{preferred}->{countries} &&
 265         grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 266     {
 267         $match = "preferred";
 268     }
 269     elsif ($cluster->{preferred} &&
 270            $cluster->{preferred}->{continents} &&
 271            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 272     {
 273         $match = "preferred";
 274     }
 275     elsif ($cluster->{allowed} &&
 276            $cluster->{allowed}->{countries} &&
 277            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 278     {
 279         $match = "allowed";
 280     }
 281     elsif ($cluster->{allowed} &&
 282            $cluster->{allowed}->{continents} &&
 283            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 284     {
 285         $match = "allowed";
 286     }
 287     elsif ($cluster->{denied} &&
 288            $cluster->{denied}->{countries} &&
 289            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 290     {
 291         $match = "denied";
 292     }
 293     elsif ($cluster->{denied} &&
 294            $cluster->{denied}->{continents} &&
 295            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 296     {
 297         $match = "denied";
 298     }
 299     elsif ($cluster->{allowed})
 300     {
 301         $match = "denied";
 302     }
 303     else
 304     {
 305         $match = "allowed";
 306     }
 307
 308     return $match;
 309 }
 310
 311 #
 312 # Compute the great circle distance between two points
 313 #
 314 sub distance
 315 {
 316     my $lat1 = deg2rad(shift);
 317     my $lon1 = deg2rad(shift);
 318     my $lat2 = deg2rad(shift);
 319     my $lon2 = deg2rad(shift);
 320
 321     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 322 }
 323
 324 #
 325 # Allocate each origin to a cluster
 326 #
 327 sub allocate_clusters
 328 {
 329     my @mappings = sort { compare_mappings($a, $b) } @_;
 330
 331     # Loop over the mappings, trying to assign each origin to the
 332     # nearest cluster, but subject to the bandwidth limits
 333     while (my $mapping = shift @mappings)
 334     {
 335         my @group;
 336
 337         push @group, $mapping;
 338
 339         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 340         {
 341             push @group, shift @mappings;
 342         }
 343
 344         for my $mapping (sort compare_bandwidth @group)
 345         {
 346             my $origin = $mapping->{origin};
 347             my $cluster = $mapping->{cluster};
 348
 349             if (!exists($origin->{cluster}) &&
 350                 $cluster->{bandwidth_used} + $origin->{bandwidth} <= $cluster->{bandwidth_limit})
 351             {
 352                 $origin->{cluster} = $cluster;
 353                 $cluster->{bandwidth_used} = $cluster->{bandwidth_used} + $origin->{bandwidth};
 354             }
 355         }
 356     }
 357
 358     return;
 359 }
 360
 361 #
 362 # Compare two mappings to decide which to use
 363 #
 364 sub compare_mappings
 365 {
 366     my $a = shift;
 367     my $b = shift;
 368
 369     return $b->{priority} <=> $a->{priority} ||
 370            $a->{distance} <=> $b->{distance};
 371 }
 372
 373 #
 374 # Compare two mappings to decide which to try first
 375 #
 376 sub compare_bandwidth
 377 {
 378     my $a_used = ( $a->{cluster}->{bandwidth_used} * 100.0 ) / ( $a->{cluster}->{bandwidth_limit} * 1.0 );
 379     my $b_used = ( $b->{cluster}->{bandwidth_used} * 100.0 ) / ( $b->{cluster}->{bandwidth_limit} * 1.0 );
 380
 381     return $a_used <=> $b_used;
 382 }
 383
 384 #
 385 # Output DNS records for a server
 386 #
 387 sub output_server
 388 {
 389     my $zonefile = shift;
 390     my $name = shift;
 391     my $cluster = shift;
 392
 393     foreach my $server (@{$cluster->{servers}})
 394     {
 395         if ($server->{status} eq "up")
 396         {
 397             $zonefile->print("+${name}:$server->{ipv4}:3600\n");
 398
 399             if ($server->{ipv6})
 400             {
 401 #                $zonefile->print("3${name}:$server->{ipv6}:3600\n");
 402             }
 403         }
 404     }
 405
 406     return;
 407 }