bin/mkgeo

   1 #!/usr/bin/perl
   2
   3 use v5.12;
   4
   5 use strict;
   6 use warnings;
   7
   8 use IO::File;
   9 use Math::Trig qw(deg2rad pip2 great_circle_distance);
  10 use JSON::XS;
  11 use LWP::UserAgent;
  12 use YAML;
  13
  14 my $originfile = shift @ARGV;
  15 my $clusterfile = shift @ARGV;
  16 my $zone = shift @ARGV;
  17 my $targetoriginfile = shift @ARGV;
  18 my $origins = YAML::LoadFile($originfile);
  19 my $clusters = YAML::LoadFile($clusterfile);
  20 my $gdnsname = shift @ARGV;
  21 my @servers;
  22
  23 # Initialise cluster details
  24 while (my($name,$cluster) = each %$clusters)
  25 {
  26     if ($cluster->{servers})
  27     {
  28         $cluster->{bandwidth} = 0;
  29
  30         foreach my $server (@{$cluster->{servers}})
  31         {
  32             $server->{cluster} = $cluster;
  33             $cluster->{bandwidth} = $cluster->{bandwidth} + $server->{bandwidth};
  34
  35             push @servers, $server;
  36         }
  37     }
  38     else
  39     {
  40         my $server = {
  41             cluster => $cluster,
  42             statuscake => $cluster->{statuscake},
  43             bandwidth => $cluster->{bandwidth},
  44             ipv4 => $cluster->{ipv4},
  45             ipv6 => $cluster->{ipv6}
  46         };
  47
  48         $cluster->{servers} = [ $server ];
  49
  50         push @servers, $server;
  51     }
  52
  53     $cluster->{name} = $name;
  54     $cluster->{status} = "down";
  55 }
  56
  57 # Initialise server details
  58 foreach my $server (@servers)
  59 {
  60     $server->{status} = "up";
  61 }
  62
  63 # If statuscake support is enabled then check which servers are up
  64 if ($ENV{STATUSCAKE_USERNAME} && $ENV{STATUSCAKE_APIKEY})
  65 {
  66     my $ua = LWP::UserAgent->new;
  67     my $cache;
  68
  69     $ua->agent("mkgeo/1.0");
  70     $ua->default_header("Username", $ENV{STATUSCAKE_USERNAME});
  71     $ua->default_header("API", $ENV{STATUSCAKE_APIKEY});
  72
  73     if (-f "statuscake.yml")
  74     {
  75         $cache = YAML::LoadFile("statuscake.yml");
  76     }
  77     else
  78     {
  79         $cache = {};
  80     }
  81
  82     my $response = $ua->get("https://app.statuscake.com/API/Tests/");
  83
  84     if ($response->is_success)
  85     {
  86         my $tests = decode_json($response->content);
  87
  88         foreach my $test (@$tests)
  89         {
  90             my $testid = $test->{TestID};
  91
  92             if ($test->{Status} eq "Up" && !$test->{Paused})
  93             {
  94                 $cache->{$testid} = "up";
  95             }
  96             else
  97             {
  98                 $cache->{$testid} = "down";
  99             }
 100         }
 101     }
 102
 103     foreach my $server (@servers)
 104     {
 105         if (my $testids = $server->{statuscake})
 106         {
 107             $server->{status} = "up";
 108
 109             for my $testid (@$testids)
 110             {
 111                 my $testresult = $cache->{$testid} || "down";
 112
 113                 $server->{status} = "down" if $testresult eq "down";
 114             }
 115         }
 116         else
 117         {
 118             $server->{status} = "down";
 119         }
 120     }
 121
 122     YAML::DumpFile("statuscake.yml", $cache);
 123 }
 124
 125 # Mark a cluster as up if any servers are up
 126 foreach my $server (@servers)
 127 {
 128     if ($server->{status} eq "up")
 129     {
 130         $server->{cluster}->{status} = "up";
 131     }
 132     else
 133     {
 134         $server->{cluster}->{bandwidth} = $server->{cluster}->{bandwidth} - $server->{bandwidth};
 135     }
 136 }
 137
 138 # Create target origins object
 139 my $targetorigins = {};
 140
 141 # Initialise cluster details
 142 while (my($name,$cluster) = each %$clusters)
 143 {
 144     $cluster->{bandwidth_limit} = $cluster->{bandwidth} * 1024 * 1024;
 145     $cluster->{bandwidth_used} = 0;
 146
 147     $targetorigins->{$cluster->{name}} = {
 148         code => $cluster->{name},
 149         name => $cluster->{name},
 150         lat => $cluster->{lat},
 151         lon => $cluster->{lon},
 152         bandwidth => 0
 153     };
 154 }
 155
 156 my @mappings = ();
 157
 158 # Scan origins and work out which clusters each can use
 159 foreach my $origin (values %$origins)
 160 {
 161     foreach my $cluster (values %$clusters)
 162     {
 163         my $match = match_origin($cluster, $origin);
 164
 165         if ($cluster->{status} eq "up" && $match ne "denied")
 166         {
 167             my $priority = $match eq "preferred" ? 20 : 10;
 168             my $distance = distance($origin->{lat}, $origin->{lon}, $cluster->{lat}, $cluster->{lon});
 169
 170             push @mappings, {
 171                 origin => $origin, cluster => $cluster,
 172                 priority => $priority, distance => $distance
 173             };
 174         }
 175     }
 176 }
 177
 178 # Allocate each country to a cluster
 179 allocate_clusters(@mappings);
 180
 181 # If we failed to allocate every origin then loop, increasing
 182 # the bandwidth for each cluster by a little and retrying until
 183 # we manage to allocate everything
 184 while (grep { !exists($_->{cluster}) } values %$origins)
 185 {
 186     # Clear any existing mappings of countries to clusters
 187     foreach my $origin (values %$origins)
 188     {
 189         delete $origin->{cluster};
 190     }
 191
 192     # Reset bandwidth usage for clusters and increase limits by 10%
 193     foreach my $cluster (values %$clusters)
 194     {
 195         $cluster->{bandwidth_used} = 0;
 196         $cluster->{bandwidth_limit} = $cluster->{bandwidth_limit} * 1.1;
 197     }
 198
 199     # Try the allocate again
 200     allocate_clusters(@mappings);
 201 }
 202
 203 # Create JSON collection object
 204 my @json;
 205
 206 # Open output files
 207 my $zonefile = IO::File->new("> data/${zone}") || die "$!";
 208 my $jsonfile = IO::File->new("> json/${zone}.json") || die "$!";
 209
 210 # Output details for each country
 211 foreach my $origin (sort { $a->{name} cmp $b->{name} } values %$origins)
 212 {
 213     my $cluster = $origin->{cluster};
 214     my $clon = $origin->{lon};
 215     my $clat = $origin->{lat};
 216     my $slon = $cluster->{lon};
 217     my $slat = $cluster->{lat};
 218
 219     if ($clon > 0 && $slon < 0 && 360 + $slon - $clon < $clon - $slon)
 220     {
 221         $slon = $slon + 360;
 222     }
 223     elsif ($slon > 0 && $clon < 0 && 360 + $clon - $slon < $slon - $clon)
 224     {
 225         $clon = $clon + 360;
 226     }
 227
 228     $zonefile->print("# $origin->{name}\n");
 229     $zonefile->print("C\L$origin->{code}\E.${zone}:$cluster->{name}.${zone}:600\n");
 230
 231     push @json, {
 232         type => "Feature",
 233         geometry => {
 234             type => "LineString",
 235             coordinates => [ [ $clon, $clat ], [ $slon, $slat ] ]
 236         },
 237         properties => {
 238             origin => $origin->{name},
 239             server => $cluster->{name},
 240             colour => $cluster->{colour}
 241         }
 242     };
 243
 244     $targetorigins->{$cluster->{name}}->{bandwidth} += $origin->{bandwidth};
 245 }
 246
 247 # Header for default records
 248 $zonefile->print("# Unknown origins\n");
 249
 250 # Output default records for IPs that can't be mapped to a country
 251 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 252 {
 253     my $name = $cluster->{name};
 254
 255     if (my $default = $cluster->{default})
 256     {
 257         output_server($zonefile, "${default}.${zone}", $cluster);
 258     }
 259     elsif (exists($cluster->{default}))
 260     {
 261         output_server($zonefile, "${zone}", $cluster);
 262     }
 263 }
 264
 265 # Header for underlying servers
 266 $zonefile->print("# Servers\n");
 267
 268 # Output A records for each cluster
 269 foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 270 {
 271     my $name = $cluster->{name};
 272
 273     output_server($zonefile, "${name}.${zone}", $cluster);
 274
 275     if (@{$cluster->{servers}} > 1)
 276     {
 277         output_server($zonefile, "${name}-%02d.${zone}", $cluster);
 278     }
 279 }
 280
 281 # Output the GeoJSON text
 282 $jsonfile->print(encode_json(\@json));
 283
 284 # Close the output files
 285 $jsonfile->close();
 286 $zonefile->close();
 287
 288 # Output gdnsd configuration
 289 if (defined($gdnsname))
 290 {
 291     my $gdnsmapfile = IO::File->new("> gdns/${gdnsname}.map") || die "$!";
 292     my $gdnsresourcefile = IO::File->new("> gdns/${gdnsname}.resource") || die "$!";
 293     my $gdnsweightedfile = IO::File->new("> gdns/${gdnsname}.weighted") || die "$!";
 294     my $continent = "";
 295
 296     $gdnsmapfile->print("${gdnsname} => {\n");
 297     $gdnsmapfile->print("  geoip2_db => /var/lib/GeoIP/GeoLite2-Country.mmdb\n");
 298     $gdnsmapfile->print("  datacenters => [" . join(",", sort(keys(%$clusters))) . "]\n");
 299     $gdnsmapfile->print("  map => {\n");
 300     $gdnsmapfile->print("    default => [" . join(",", sort(map { $_->{name} } grep { $_->{default} } values(%$clusters))) . "]\n");
 301
 302     foreach my $origin (sort { $a->{continent} cmp $b->{continent} || $a->{code} cmp $b->{code} } values %$origins)
 303     {
 304         my $code = $origin->{code};
 305         my $cluster = $origin->{cluster}->{name};
 306
 307         next if $code eq "XK";
 308
 309         if ($continent ne $origin->{continent})
 310         {
 311             $gdnsmapfile->print("    }\n") if $continent;
 312
 313             $continent = $origin->{continent};
 314
 315             $gdnsmapfile->print("    ${continent} => {\n");
 316         }
 317
 318         $gdnsmapfile->print("      ${code} => [${cluster}]\n");
 319     }
 320
 321     $gdnsmapfile->print("    }\n") if $continent;
 322
 323     $gdnsmapfile->print("  }\n");
 324     $gdnsmapfile->print("}\n");
 325
 326     $gdnsresourcefile->print("${gdnsname} => {\n");
 327     $gdnsresourcefile->print("  map => ${gdnsname}\n");
 328     $gdnsresourcefile->print("  dcmap => {\n");
 329
 330     foreach my $cluster (sort { $a->{name} cmp $b->{name} } values %$clusters)
 331     {
 332         my $name = $cluster->{name};
 333
 334         $gdnsresourcefile->print("    ${name} => ${name}.${zone}.\n");
 335
 336         if (@{$cluster->{servers}} > 1)
 337         {
 338             $gdnsweightedfile->print("${name} => {\n");
 339
 340             while (my($index,$server) = each @{$cluster->{servers}})
 341             {
 342                 if ($server->{status} eq "up")
 343                 {
 344                     my $number = sprintf("%02d", $index + 1);
 345                     my $bandwidth = $server->{bandwidth};
 346
 347                     $gdnsweightedfile->print("  ${name}-${number} = [ ${name}-${number}.${zone}., ${bandwidth} ]\n");
 348                 }
 349             }
 350
 351             $gdnsweightedfile->print("}\n");
 352         }
 353     }
 354
 355     $gdnsresourcefile->print("  }\n");
 356     $gdnsresourcefile->print("}\n");
 357
 358     $gdnsweightedfile->close();
 359     $gdnsresourcefile->close();
 360     $gdnsmapfile->close();
 361 }
 362
 363 # Output the target details in origin format if required
 364 YAML::DumpFile($targetoriginfile, $targetorigins) if $targetoriginfile;
 365
 366 exit 0;
 367
 368 #
 369 # Match an origin against a cluster
 370 #
 371 sub match_origin
 372 {
 373     my $cluster = shift;
 374     my $origin = shift;
 375     my $match;
 376
 377     if ($cluster->{preferred} &&
 378         $cluster->{preferred}->{origins} &&
 379         grep { $_ eq $origin->{name} } @{$cluster->{preferred}->{origins}})
 380     {
 381         $match = "preferred";
 382     }
 383     elsif ($cluster->{allowed} &&
 384            $cluster->{allowed}->{origins} &&
 385            grep { $_ eq $origin->{name} } @{$cluster->{allowed}->{origins}})
 386     {
 387         $match = "allowed";
 388     }
 389     elsif ($cluster->{preferred} &&
 390            $cluster->{preferred}->{countries} &&
 391            grep { $_ eq $origin->{country} } @{$cluster->{preferred}->{countries}})
 392     {
 393         $match = "preferred";
 394     }
 395     elsif ($cluster->{allowed} &&
 396            $cluster->{allowed}->{countries} &&
 397            grep { $_ eq $origin->{country} } @{$cluster->{allowed}->{countries}})
 398     {
 399         $match = "allowed";
 400     }
 401     elsif ($cluster->{denied} &&
 402            $cluster->{denied}->{countries} &&
 403            grep { $_ eq $origin->{country} } @{$cluster->{denied}->{countries}})
 404     {
 405         $match = "denied";
 406     }
 407     elsif ($cluster->{preferred} &&
 408            $cluster->{preferred}->{continents} &&
 409            grep { $_ eq $origin->{continent} } @{$cluster->{preferred}->{continents}})
 410     {
 411         $match = "preferred";
 412     }
 413     elsif ($cluster->{allowed} &&
 414            $cluster->{allowed}->{continents} &&
 415            grep { $_ eq $origin->{continent} } @{$cluster->{allowed}->{continents}})
 416     {
 417         $match = "allowed";
 418     }
 419     elsif ($cluster->{denied} &&
 420            $cluster->{denied}->{continents} &&
 421            grep { $_ eq $origin->{continent} } @{$cluster->{denied}->{continents}})
 422     {
 423         $match = "denied";
 424     }
 425     elsif ($cluster->{allowed})
 426     {
 427         $match = "denied";
 428     }
 429     else
 430     {
 431         $match = "allowed";
 432     }
 433
 434     return $match;
 435 }
 436
 437 #
 438 # Compute the great circle distance between two points
 439 #
 440 sub distance
 441 {
 442     my $lat1 = deg2rad(shift);
 443     my $lon1 = deg2rad(shift);
 444     my $lat2 = deg2rad(shift);
 445     my $lon2 = deg2rad(shift);
 446
 447     return great_circle_distance($lon1, pip2 - $lat1, $lon2, pip2 - $lat2);
 448 }
 449
 450 #
 451 # Allocate each origin to a cluster
 452 #
 453 sub allocate_clusters
 454 {
 455     my @mappings = sort { compare_mappings($a, $b) } @_;
 456
 457     # Loop over the mappings, trying to assign each origin to the
 458     # nearest cluster, but subject to the bandwidth limits
 459     while (my $mapping = shift @mappings)
 460     {
 461         my @group;
 462
 463         push @group, $mapping;
 464
 465         while (@mappings && compare_mappings($mapping, $mappings[0]) == 0)
 466         {
 467             push @group, shift @mappings;
 468         }
 469
 470         for my $mapping (sort compare_bandwidth @group)
 471         {
 472             my $origin = $mapping->{origin};
 473             my $cluster = $mapping->{cluster};
 474
 475             if (!exists($origin->{cluster}) &&
 476                 $cluster->{bandwidth_used} + $origin->{bandwidth} <= $cluster->{bandwidth_limit})
 477             {
 478                 $origin->{cluster} = $cluster;
 479                 $cluster->{bandwidth_used} = $cluster->{bandwidth_used} + $origin->{bandwidth};
 480             }
 481         }
 482     }
 483
 484     return;
 485 }
 486
 487 #
 488 # Compare two mappings to decide which to use
 489 #
 490 sub compare_mappings
 491 {
 492     my $a = shift;
 493     my $b = shift;
 494
 495     return $b->{priority} <=> $a->{priority} ||
 496            $a->{distance} <=> $b->{distance};
 497 }
 498
 499 #
 500 # Compare two mappings to decide which to try first
 501 #
 502 sub compare_bandwidth
 503 {
 504     my $a_used = ( $a->{cluster}->{bandwidth_used} * 100.0 ) / ( $a->{cluster}->{bandwidth_limit} * 1.0 );
 505     my $b_used = ( $b->{cluster}->{bandwidth_used} * 100.0 ) / ( $b->{cluster}->{bandwidth_limit} * 1.0 );
 506
 507     return $a_used <=> $b_used;
 508 }
 509
 510 #
 511 # Output DNS records for a server
 512 #
 513 sub output_server
 514 {
 515     my $zonefile = shift;
 516     my $name = shift;
 517     my $cluster = shift;
 518
 519     while (my($index,$server) = each @{$cluster->{servers}})
 520     {
 521         if ($server->{status} eq "up")
 522         {
 523             $zonefile->printf("+${name}:$server->{ipv4}:600\n", $index + 1);
 524
 525             if ($server->{ipv6})
 526             {
 527 #                $zonefile->printf("3${name}:$server->{ipv6}:600\n", $index + 1);
 528             }
 529         }
 530     }
 531
 532     return;
 533 }