script/misc/update-wiki-pages

   1 #!/usr/bin/env perl
   2 use 5.010;
   3 use strict;
   4 use warnings;
   5
   6 use Getopt::Long;
   7 use Pod::Usage;
   8 use MediaWiki::API;
   9 use Test::More qw(no_plan);
  10 use YAML::XS qw(Dump);
  11
  12 =head1 NAME
  13
  14 update-wiki-pages - Scrape the wiki for key/value wiki description pages
  15
  16 =head1 SYNOPSIS
  17
  18     perl script/misc/update-wiki-pages config/wiki_pages.yml
  19
  20 Or with prove(1):
  21
  22     prove -e 'perl script/misc/update-wiki-pages' config/wiki_pages.yml
  23
  24 =cut
  25
  26 # Get the command-line options
  27 Getopt::Long::Parser->new(
  28     config => [ qw< bundling no_ignore_case no_require_order pass_through > ],
  29 )->getoptions(
  30     'h|help' => \my $help,
  31 ) or help();
  32
  33 # On --help
  34 help() if $help;
  35
  36 my $out_file = $ARGV[0];
  37 $out_file //= 'config/wiki_pages.yml';
  38
  39 help() unless -f $out_file;
  40
  41 # Get a API interface
  42 my $mw = MediaWiki::API->new();
  43 ok($mw, "Got a MediaWiki API");
  44 $mw->{config}->{api_url} = 'https://wiki.openstreetmap.org/w/api.php';
  45 $mw->{config}->{retries} = 5;
  46 $mw->{config}->{retry_delay} = 30;
  47
  48 # All our goodies
  49 my (%feature, %count);
  50
  51 # This is what you get on:
  52 ## http://wiki.openstreetmap.org/w/index.php?search=Template:KeyDescription&fulltext=Search&fulltext=Search
  53 for my $lang ('', map { "${_}:" } qw[ Pt Fi De It HU Cz Fr RU Pl ]) {
  54     ok(1, "  Templates for language '$lang'");
  55
  56     # Key pages
  57     ok(1, "    Getting key pages");
  58     my $cnt = stick_content_in_hash("key", "Template:${lang}KeyDescription", \%feature);
  59     $cnt += stick_content_in_hash("key", "Template:${lang}Feature", \%feature);
  60     ok(1, "    Got $cnt key pages");
  61     $count{key} += $cnt;
  62
  63     # Key prefix pages
  64     ok(1, "    Getting key prefix pages");
  65     $cnt = stick_content_in_hash("key", "Template:${lang}KeyPrefixDescription", \%feature);
  66     ok(1, "    Got $cnt key prefix pages");
  67     $count{keyprefix} += $cnt;
  68
  69     # Value pages
  70     ok(1, "    Getting value pages");
  71     $cnt = stick_content_in_hash("tag", "Template:${lang}ValueDescription", \%feature);
  72     ok(1, "    Got $cnt value pages");
  73     $count{value} += $cnt;
  74 }
  75
  76 ok(1, "Got a total of $count{$_} ${_}s") for qw[ key keyprefix value ];
  77
  78 # Dump to .yml file
  79 open my $out, ">", $out_file or die "Can't open file '$out_file' supplied on the command line";
  80 say $out "# THIS FILE IS AUTOGENERATED WITH THE script/misc/update-wiki-pages";
  81 say $out "# PROGRAM DO NOT MANUALLY EDIT IT";
  82 say $out "";
  83 say $out Dump(\%feature);
  84 close $out;
  85
  86 exit 0;
  87
  88 sub stick_content_in_hash
  89 {
  90     my ($key, $title, $hash) = @_;
  91     my $ukey = ucfirst $key;
  92
  93     my $space_to_underscore = sub {
  94         my $txt = shift;
  95         $txt =~ s/ /_/g;
  96         $txt;
  97     };
  98
  99     my $count = 0;
 100
 101     my $process_link = sub {
 102         my $link = shift;
 103         $count++;
 104         ok(1, "    ... got $count links") if $count % 200 == 0;
 105         my $title = $link->{title};
 106         my $lang;
 107         my $key_name;
 108         if ($title =~ /^$ukey:(?<key_name>.*?)$/) {
 109             # English by default
 110             $lang = "en";
 111             $key_name = $space_to_underscore->($+{key_name});
 112         } elsif ($title =~ /^(?<lang>[^:]+):$ukey:(?<key_name>.*?)$/) {
 113             $lang = lc $+{lang};
 114             $key_name = $space_to_underscore->($+{key_name});
 115         }
 116         if ($lang && !exists($hash->{$lang}->{$key}->{$key_name})) {
 117             $hash->{$lang}->{$key}->{$key_name} = $title;
 118         }
 119     };
 120
 121     get_embeddedin(
 122         $title,
 123         sub {
 124             my $link = shift;
 125             $process_link->($link);
 126             get_redirects(
 127                 $link->{title},
 128                 sub {
 129                     my $link = shift;
 130                     $process_link->($link) if exists($link->{redirect});
 131                 }
 132             );
 133         }
 134     );
 135
 136     return $count;
 137 }
 138
 139 sub process_list
 140 {
 141     my $callback = shift;
 142     my $links = shift;
 143     for my $link (@$links) {
 144         $callback->($link);
 145     }
 146 }
 147
 148 sub get_embeddedin
 149 {
 150     my ($title, $callback) = @_;
 151     my $articles = $mw->list(
 152         {
 153             action => 'query',
 154             list => 'embeddedin',
 155             eititle => $title,
 156             eifilterredir => 'nonredirects',
 157             # Doesn't work for De:* and anything non-en. Odd.
 158             # einamespace => '0|8',
 159             eilimit => '200',
 160         },
 161         {
 162             max => '0',
 163             hook => sub { process_list($callback, @_) },
 164             skip_encoding => 1,
 165         }
 166     ) || die $mw->{error}->{code} . ': ' . $mw->{error}->{details};
 167 }
 168
 169 sub get_redirects
 170 {
 171     my ($title, $callback) = @_;
 172     my $articles = $mw->list(
 173         {
 174             action => 'query',
 175             list => 'backlinks',
 176             bltitle => $title,
 177             blfilterredir => 'redirects',
 178             # Doesn't work for De:* and anything non-en. Odd.
 179             # einamespace => '0|8',
 180             bllimit => '200',
 181         },
 182         {
 183             max => '0',
 184             hook => sub { process_list($callback, @_) },
 185             skip_encoding => 1,
 186         }
 187     ) || die $mw->{error}->{code} . ': ' . $mw->{error}->{details};
 188 }
 189
 190 sub help
 191 {
 192     my %arg = @_;
 193
 194     Pod::Usage::pod2usage(
 195         -verbose => $arg{ verbose },
 196         -exitval => $arg{ exitval } || 0,
 197     );
 198 }